Что такое пакетный эквивалент Windows для команды оболочки Linux, echo -nкоторая подавляет символ новой строки в конце вывода?

Идея состоит в том, чтобы писать в одной строке внутри цикла.

Используя setи /pпараметр, вы можете отображать без новой строки:

C:\> echo Hello World
Hello World

C:\> echo|set /p="Hello World"
Hello World
C:\>

Источник

Использование: echo | set /p=или <NUL set /p=оба будут работать для подавления новой строки.

Однако это может быть очень опасно, когда написание более сложных сценариев, когда проверка ERRORLEVEL становится важной, так как установка set /p=без указания имени переменной установит для ERRORLEVEL значение 1.

Лучшим подходом было бы просто использовать фиктивное имя переменной следующим образом:
echo | set /p dummyName=Hello World

Это произведет именно то, что вы хотите, без каких-либо подлых вещей, происходящих в фоновом режиме, так как мне пришлось выяснить трудный путь, но это работает только с конвейерной версией; <NUL set /p dummyName=Helloвсе равно поднимет ОШИБКУ до 1.

Простой метод SET / P имеет ограничения, которые немного различаются в разных версиях Windows.

• Ведущие цитаты могут быть удалены

• Ведущие пробелы могут быть удалены

• Ведущий =вызывает синтаксическую ошибку.

См. Http://www.dostips.com/forum/viewtopic.php?f=3&t=4209 для получения дополнительной информации.

Джеб опубликовал умное решение, которое решает большинство проблем в тексте вывода без перевода строки, даже с начальным пробелом или = я усовершенствовал метод, чтобы он мог безопасно печатать абсолютно любую допустимую строку пакета без новой строки в любой версии Windows от XP и далее. Обратите внимание, что :writeInitializeметод содержит строковый литерал, который может плохо размещаться на сайте. Включено примечание, описывающее, какой должна быть последовательность символов.

:writeИ :writeVarметоды оптимизированы таким образом, что только строки , содержащие хлопотно ведущие символы записываются с помощью моей модифицированной версии метода COPY Джеба. Беспроблемные строки пишутся с использованием более простого и быстрого метода SET / P.

@echo off
setlocal disableDelayedExpansion
call :writeInitialize
call :write "=hello"
call :write " world!%$write.sub%OK!"
echo(
setlocal enableDelayedExpansion
set lf=^


set "str= hello!lf!world^!!!$write.sub!hello!lf!world"
echo(
echo str=!str!
echo(
call :write "str="
call :writeVar str
echo(
exit /b

:write  Str
::
:: Write the literal string Str to stdout without a terminating
:: carriage return or line feed. Enclosing quotes are stripped.
::
:: This routine works by calling :writeVar
::
setlocal disableDelayedExpansion
set "str=%~1"
call :writeVar str
exit /b


:writeVar  StrVar
::
:: Writes the value of variable StrVar to stdout without a terminating
:: carriage return or line feed.
::
:: The routine relies on variables defined by :writeInitialize. If the
:: variables are not yet defined, then it calls :writeInitialize to
:: temporarily define them. Performance can be improved by explicitly
:: calling :writeInitialize once before the first call to :writeVar
::
if not defined %~1 exit /b
setlocal enableDelayedExpansion
if not defined $write.sub call :writeInitialize
set $write.special=1
if "!%~1:~0,1!" equ "^!" set "$write.special="
for /f delims^=^ eol^= %%A in ("!%~1:~0,1!") do (
  if "%%A" neq "=" if "!$write.problemChars:%%A=!" equ "!$write.problemChars!" set "$write.special="
)
if not defined $write.special (
  <nul set /p "=!%~1!"
  exit /b
)
>"%$write.temp%_1.txt" (echo !str!!$write.sub!)
copy "%$write.temp%_1.txt" /a "%$write.temp%_2.txt" /b >nul
type "%$write.temp%_2.txt"
del "%$write.temp%_1.txt" "%$write.temp%_2.txt"
set "str2=!str:*%$write.sub%=%$write.sub%!"
if "!str2!" neq "!str!" <nul set /p "=!str2!"
exit /b


:writeInitialize
::
:: Defines 3 variables needed by the :write and :writeVar routines
::
::   $write.temp - specifies a base path for temporary files
::
::   $write.sub  - contains the SUB character, also known as <CTRL-Z> or 0x1A
::
::   $write.problemChars - list of characters that cause problems for SET /P
::      <carriageReturn> <formFeed> <space> <tab> <0xFF> <equal> <quote>
::      Note that <lineFeed> and <equal> also causes problems, but are handled elsewhere
::
set "$write.temp=%temp%\writeTemp%random%"
copy nul "%$write.temp%.txt" /a >nul
for /f "usebackq" %%A in ("%$write.temp%.txt") do set "$write.sub=%%A"
del "%$write.temp%.txt"
for /f %%A in ('copy /z "%~f0" nul') do for /f %%B in ('cls') do (
  set "$write.problemChars=%%A%%B    ""
  REM the characters after %%B above should be <space> <tab> <0xFF>
)
exit /b

В качестве дополнения к ответу @ xmechanix я заметил, записав содержимое в файл:

echo | set /p dummyName=Hello World > somefile.txt

Это добавит дополнительный пробел в конце напечатанной строки , что может быть неудобно, особенно если учесть, что мы пытаемся избежать добавления новой строки (другого символа пробела) в конец строки.

К счастью, цитирование строки для печати, то есть с помощью:

echo | set /p dummyName="Hello World" > somefile.txt

Напечатает строку без символа перевода строки или пробела в конце.

Решение для очищенного белого пространства в SET / P:

хитрость заключается в том символе возврата, который вы можете вызвать в текстовом редакторе EDIT для DOS. Чтобы создать его в режиме EDIT, нажмите Ctrl + CtrlH . Я вставил бы это здесь, но эта веб-страница не может отобразить это. Хотя он виден в блокноте (он странный, как маленький черный прямоугольник с белым кружком в центре)

Итак, вы пишете это:

<nul set /p=.9    Hello everyone

Точка может быть любым символом, это только там, чтобы сказать SET / P, что текст начинается там, перед пробелами, а не в " Hello ». « 9 » - это представление символа возврата, которое я не могу отобразить здесь. Вы должны поставить его вместо 9, и он удалит « . », После чего вы получите это:

    Hello Everyone

вместо того:

Hello Everyone

Я надеюсь, что это помогает

Вы можете удалить новую строку, используя "tr" из gnuwin32 ( пакет coreutils )

@echo off
set L=First line
echo %L% | tr -d "\r\n"
echo Second line
pause

Кстати, если вы делаете много сценариев, gnuwin32 - это золотая жила.

Вот еще один метод, он использует Powershell Write-Host, у которого есть параметр -NoNewLine, объедините его с start /b и предлагает те же функциональные возможности из пакета.

NoNewLines.cmd

@ECHO OFF
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 1 - ';Write-Host -NoNewLine 'Result 2 - ';Write-Host -NoNewLine 'Result 3 - '"
PAUSE

Вывод

Result 1 - Result 2 - Result 3 - Press any key to continue . . .

Это ниже немного отличается, не работает точно так, как хочет OP, но интересно, потому что каждый результат перезаписывает предыдущий результат, эмулирующий счетчик.

@ECHO OFF
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 1 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 2 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 3 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 4 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 5 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 6 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 7 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 8 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 9 - '"
PAUSE

От сюда

<nul set /p =Testing testing

а также повторить, начиная с использования пробелов

echo.Message goes here

Может быть, это то, что вы ищете, это сценарий старой школы ...: P

set nl=^& echo. 
echo %nl%The%nl%new%nl%line%nl%is%nl%not%nl%apparent%nl%throughout%nl%text%nl%
echo only in prompt.
pause

или, может быть, вы пытаетесь заменить текущую строку вместо записи в новую строку? Вы можете поэкспериментировать с этим, удалив «% bs%» после «.» знак, а также через интервал между "% bs%" после "Пример сообщения".

for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "bs=%%a"
<nul set /p=.%bs%         Example message         %bs%
pause

Я нахожу это действительно интересным, потому что он использует переменную не для той цели, для которой он предназначен. как вы можете видеть, "% bs%" представляет собой забой. Второй «% bs%» использует пробел для добавления пробелов после «Пример сообщения» для разделения «Вывод команды Пауза» без фактического добавления видимого символа после «Пример сообщения». Однако это также возможно с обычным знаком процента.

DIY cw.exe (консольная запись) утилита

Если вы не найдете его готовым, готовым, вы можете сделать это самостоятельно. С этимcw утилиты вы можете использовать любые символы. По крайней мере, мне бы хотелось так думать. Пожалуйста, стресс-тест и дайте мне знать.

инструменты

Все, что вам нужно, это установить .NET , что очень распространено в наши дни.

материалы

Некоторые символы напечатаны / скопированы.

меры

1. Создайте .batфайл со следующим содержанием.

/* >nul 2>&1

@echo off
setlocal

set exe=cw
for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*csc.exe"') do set "csc=%%v"

"%csc%" -nologo -out:"%exe%.exe" "%~f0"

endlocal
exit /b %errorlevel%

*/

using System;

namespace cw {
    class Program {
        static void Main() {
            var exe = Environment.GetCommandLineArgs()[0];
            var rawCmd = Environment.CommandLine;
            var line = rawCmd.Remove(rawCmd.IndexOf(exe),exe.Length).TrimStart('"');
            line = line.Length < 2 ? "\r" : line.Substring(2) ;
            Console.Write(line);
        }
    }
}

2. Запустить его.

3. Теперь у вас есть хорошая утилита 4KB, поэтому вы можете удалить .bat.

Кроме того , вы можете вставить этот код в качестве подпрограммы в любой партии, отправить в результате .exeк %temp%, использовать его в своей партии и удалить его , когда вы закончите.

Как пользоваться

Если вы хотите написать что-то без новой строки:
cw Whatever you want, even with "", but remember to escape ^|, ^^, ^&, etc. unless double-quoted, like in "| ^ &".

Если вы хотите возврат каретки (переход к началу строки), просто запустите
cw

Так что попробуйте это из командной строки:

for /l %a in (1,1,1000) do @(cw ^|&cw&cw /&cw&cw -&cw&cw \&cw)

Я сделал функцию из идеи @arnep:

echo | set / p = "Hello World"

вот:

:SL (sameline)
echo|set /p=%1
exit /b

Используйте это с, call :SL "Hello There"
я знаю, что в этом нет ничего особенного, но я так долго думал об этом, что я решил опубликовать это здесь.

Пример 1: Это работает и производит код выхода = 0. Это хорошо. Обратите внимание "." сразу после эха.

C: \ Users \ phife.dog \ gitrepos \ 1 \ repo_abc \ scripts #
@echo. | set / p JUNK_VAR = Это сообщение отображается как Linux echo -n будет отображать его ... & echo% ERRORLEVEL%

Это сообщение отображается как Linux echo -n будет отображать его ... 0

Пример 2: это работает, но выдает код выхода = 1. Это плохо. Обратите внимание на отсутствие "." После эха. Похоже, что это разница.

C: \ Users \ phife.dog \ gitrepos \ 1 \ repo_abc \ scripts #
@echo | set / p JUNK_VAR = Это сообщение отображается как Linux echo -n будет отображать его ... & echo% ERRORLEVEL%

Это сообщение отображается как Linux эхо -n будет отображать его ... 1

Вдохновленный ответами на этот вопрос, я сделал простой пакетный скрипт счетчика, который продолжает печатать значение прогресса (0-100%) в той же строке (перезаписывая предыдущий). Возможно, это также будет полезно для других, ищущих подобное решение.

Примечание : *это непечатаемые символы, их следует вводить с помощью комбинации клавиш [ Alt+ Numpad 0+ Numpad 8], которая является backspaceсимволом.

@ECHO OFF

FOR /L %%A in (0, 10, 100) DO (     
    ECHO|SET /P="****%%A%%"    
    CALL:Wait 1
)

GOTO:EOF

:Wait
SET /A "delay=%~1+1"
CALL PING 127.0.0.1 -n %delay% > NUL
GOTO:EOF

Я считаю, что нет такой возможности. Или вы можете попробовать это

set text=Hello
set text=%text% world
echo %text%

Вы можете подавить новую строку, используя команду set / p. Команда set / p не распознает пробел, для этого вы можете использовать точку и символ возврата, чтобы она его распознала. Вы также можете использовать переменную в качестве памяти и сохранить то, что вы хотите напечатать в ней, чтобы вы могли напечатать переменную вместо предложения. Например:

@echo off
setlocal enabledelayedexpansion
for /f %%a in ('"prompt $H & for %%b in (1) do rem"') do (set "bs=%%a")
cls
set "var=Hello World! :)"
set "x=0"

:loop
set "display=!var:~%x%,1!"
<nul set /p "print=.%bs%%display%"
ping -n 1 localhost >nul
set /a "x=%x% + 1"
if "!var:~%x%,1!" == "" goto end
goto loop

:end
echo.
pause
exit

Таким образом, вы можете напечатать что-нибудь без новой строки. Я сделал программу для печати символов один за другим, но вы также можете использовать слова вместо символов, изменив цикл.

В приведенном выше примере я использовал «enabledelayedexpansion», поэтому команда set / p не распознает «!» символ и печатает точку вместо этого. Я надеюсь, что вы не используете восклицательный знак "!" ;)

Поздний ответ здесь, но для тех, кому нужно написать специальные символы в одной строке, для которых ответ dbenham слишком длинный, примерно на 80 строк и чьи сценарии могут ломаться (возможно, из-за ввода данных пользователем) из-за ограничений простого использования set /p, вероятно, проще всего связать ваш .bat или .cmd с скомпилированным исполняемым файлом на C ++ или языке C, а затем просто coutили printfс символами. Это также позволит вам легко писать несколько раз в одну строку, если вы показываете какой-то индикатор выполнения или что-то с использованием символов, как, очевидно, было в OP.