Изменить имя по умолчанию для новой папки

Когда мы создаем «новую папку» в поисковике, она автоматически получает имя «папка без названия».

Можно ли изменить имя папки по умолчанию на имя текущей даты, например «20151223»?

С помощью AppleScript вы можете сделать это.

Откройте редактор AppleScript, создайте новый документ и вставьте следующие украденные строки:

tell application "Finder"
    try
        if exists Finder window 1 then
            set thisPath to (the target of the front window) as alias
        else
            set thisPath to (path to desktop)
        end if
    on error
        return
    end try
end tell
set x to my the_perfect_datestring()
if x is not "-ERROR" then
    set fullPath to thisPath & x as text
    tell application "Finder"
        try
            --activate
            if not (exists fullPath) then
                set y to make new folder at thisPath with properties {name:x}
            end if
            activate
            open y
        end try
    end tell
end if
on the_perfect_datestring()
    try
        set cd to (the current date)
        set the_year to year of (cd) as number
        set the_month to month of (cd) as number
        set the_day to day of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        return ((the_year & the_month & the_day) as string)
    on error
        return "-ERROR"
    end try
end the_perfect_datestring

Сохраните файл как приложение AppleScript (например, DateFolder.app) где-нибудь (например, ~ / Applications).

Откройте папку и поместите DateFolder.app на панель инструментов:

Чтобы создать папку в открытой папке, просто нажмите значок приложения на панели инструментов. Новая папка откроется автоматически. Удалите строку 22 в скрипте ( open y), если вы не хотите, чтобы новая папка была открыта. Если вы добавите приложение в Dock и откроете его, оно создаст новую папку в самой передней папке или на рабочем столе (если папка не открыта).

Проверено только в Mac OS X 10.7.5. Лев!

Чтобы добавить дефис и текущее время, добавьте следующие строки (вместо строки 32-34 в приведенном выше сценарии):

        set the_hour to hours of (cd) as number
        set the_minute to minutes of (cd) as number
        set the_second to seconds of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        if the_hour < 10 then set the_hour to "0" & the_hour
        if the_minute < 10 then set the_minute to "0" & the_minute
        if the_second < 10 then set the_second to "0" & the_second
        return ((the_year & the_month & the_day & "-" & the_hour & the_minute & the_second) as string)