Объединить блоки путем чередования строк

Существует ли специальный способ объединения двух блоков текста путем чередования строк, например, переходя от этого:

a1
a2
a3
a4
  b1
  b2
  b3
  b4

к тому, что:

a1
  b1
a2
  b2
a3
  b3
a4
  b4

в нескольких командах?

РЕДАКТИРОВАТЬ : Мне очень нравится решение Сато Кацура , вот как я его реализовал:

function! Interleave()
    " retrieve last selected area position and size
    let start = line(".")
    execute "normal! gvo\<esc>"
    let end = line(".")
    let [start, end] = sort([start, end], "n")
    let size = (end - start + 1) / 2
    " and interleave!
    for i in range(size - 1)
        execute (start + size + i). 'm' .(start + 2 * i)
    endfor
endfunction

" Select your two contiguous, same-sized blocks, and use it to Interleave ;)
vnoremap <pickYourMap> <esc>:call Interleave()<CR>

Нет специального способа сделать это (насколько я знаю), но да, это можно сделать с помощью нескольких команд:

function! Interleave(start, end, where)
    if a:start < a:where
        for i in range(0, a:end - a:start)
            execute a:start . 'm' . (a:where + i)
        endfor
    else
        for i in range(a:end - a:start, 0, -1)
            execute a:end . 'm' . (a:where + i)
        endfor
    endif
endfunction

Вы можете запустить его с :call Interleave(5, 8, 1). Первый параметр - это первая строка для перемещения, вторая - последняя строка, а третий - куда их перемещать. Вы, вероятно, хотите включить номера строк, чтобы увидеть, что вы делаете ( :set number).

Это предполагает, что блоки не перекрываются. Смотрите :help :moveи :help range()понимайте, как работает функция.

Вероятно, есть более эффективные способы подобрать два блока. Вокруг плавающего плагина, который должен поменять местами два блока. Я не могу вспомнить название плагина, но автор (возможно, знаменитый доктор Чип?) Уделил больше внимания поиску интерфейса, чем я. :)

Вот еще одна альтернатива:

:g/^a/+4t .
:+,+5d 

Сначала скопируйте строки, расположенные на 4 строки ниже, после текущей строки ( :h :t), затем удалите последовательные строки b ( :h :d)

Еще лучше эта команда:

 :g/^a//^\s*b/m .

Это означает, что для каждой строки, начинающейся с поиска, найдите следующую строку, начинающуюся с 'b', и переместите ее ниже текущей строки.

Если вы хотите немного повеселиться с макросами и метками, вы можете попробовать что-то вроде этого:

• Сначала поставить знак (здесь a) на строке , содержащей a1сma

• Перейти к строке, содержащей b1и пометить ееmb

• Начните запись макроса в регистр, который вы хотите (здесь регистр q) сqq

• Вставьте следующее в ваш макрос: ddmb'apjma'b

• Прекратить запись макроса с q

• Играйте в нее столько раз, сколько необходимо, с X@qуказанием Xколичества времени, которое вы можете воспроизвести.

Чтобы детализировать макрос:

dd mb 'a p j ma 'b
 |  |  | | |    |
 |  |  | | |    go back to line marked `b`
 |  |  | | |
 |  |  | | move of one line and replace the mark `a`
 |  |  | insert the deleted line under the line marked `a`
 |  |  go to line marked `a`
 |  mark the future line to move with `b`
 delete the line to move

Редактировать Как упоминал Лаго-Лито в комментариях, этот метод будет перезаписывать метки и буферы.

• Что касается отметок, я не думаю, что это реальная проблема: я редко использую все 26 отметок в буфере, и я думаю, что большую часть времени можно найти 2 свободных отметки.

• Для буфера можно сохранить его во временной переменной: перед записью макроса используйте :let saveReg=getreg('"')для сохранения регистра, а после завершения действия используйте :call setreg('"', saveReg)для возврата регистра в его предыдущее состояние.

В любом случае я должен признать, что это решение является быстрым обходным путем и не оптимальным: по моему мнению , ответ Кристана является лучшим и должен быть принят, потому что он не мешает с буферами и метками, не заставляет пользователя создавать функция и показывает силу глобальной команды.

Я только что видел другой подобный вопрос, и решение состоит из:

Перейти к середине плюс один:

Mj

И запустить:

:,$g/./exe 'm' 2*line('.')-line('$')-1