Я фанат способа, которым Atom и Sublime Text обрабатывают сгибание строк, когда первая строка каждого сгиба видима (завершена подсветкой синтаксиса), и к концу строки, указывающей сгиб, добавляется маркер.

См. Скриншот ниже, сравнивающий отступ в Vim (вверху) и Atom (внизу):

Vim посвящает две строки для каждого сгиба. Первая строка служит заголовком, а вторая строка описывает некоторую информацию о сгибе (количество строк и текст внутри сгиба).

Atom использует только одну строку и использует маленький маркер в конце строки для обозначения сгиба вместе с цветом, добавленным к номерам строк слева. Складной стиль Atom использует меньше экранного пространства, но все же передает всю информацию, которая мне действительно нужна.

Я неравнодушен к складному стилю Atom. На мой взгляд, он выглядит чище и последовательнее, особенно при перечислении нескольких методов или атрибутов подряд (как на скриншоте выше).

Есть ли способ примерно приблизить стиль складывания Atom в Vim?

Две линии против одной линии

В Vim все строки в сгибе будут свернуты в одну строку, и 'foldtext'затем параметр определяет синопсис этих строк (обычно штрихи, количество сложенных строк и содержимое из первых (или всех) строк).

В вашем примере, в Vim {...}свернут только сам блок параметров; строка выше (которая использует параметры) не является частью сгиба. Напротив, в другом редакторе эта строка, использующая параметры, принадлежит к сгибу, а ее сгибный текст (если использовать терминологию Vim) - это содержимое этой строки плюс добавленный маркер.

адаптация

В Vim складки могут генерироваться различными способами (см. :help fold-methods) И зависят 'filetype'от буфера. Сложность включения вышеупомянутой линии в сгиб зависит от этого; проверить с :setlocal foldmethod?. При складывании отступа вы не можете повлиять; Вы должны переключиться на другой метод. Для свертывания синтаксиса это означало бы адаптацию определений синтаксиса и может быть очень сложным. Вам повезет больше, если использовать выражение , но это все равно будет означать понимание и изменение логики. (Маловероятно, что автор плагина filetype предоставил конфигурацию, чтобы повлиять на это.)

Подсветка синтаксиса согнутой строки

К сожалению, это невозможно вообще. Vim всегда использует группу Foldedвыделения для всей сложенной строки. Вы можете настроить это с помощью своих :highlightкоманд ~/.vimrc, но индивидуальная дифференциация синтаксиса будет потеряна.

Vim уже отображает сгибы одной строкой. Однако при indentсворачивании Vim все линии с одинаковым отступом включаются в сгиб. Таким образом, на скриншоте строки, которые вы называете «заголовками» (например, начинающими collection_base_url), не находятся в пределах сгиба.

Вы можете добиться чего-то похожего на свертывание Atom, используя Vim foldexpr foldmethod:

" Finds the indent of a line. The indent of a blank line is the indent of the
" first non-blank line above it.
function! FindIndent(line_number, indent_width)
    " Regular expression for a "blank" line
    let regexp_blank = "^\s*$"

    let non_blank_line = a:line_number
    while non_blank_line > 0 && getline(non_blank_line) =~ regexp_blank
        let non_blank_line = non_blank_line - 1
    endwhile
    return indent(non_blank_line) / a:indent_width
endfunction

" 'foldexpr' for Atom-style indent folding
function! AtomStyleFolding(line_number)
    let indent_width = &shiftwidth

    " Find current indent
    let indent = FindIndent(a:line_number, indent_width)

    " Now find the indent of the next line
    let indent_below = FindIndent(a:line_number + 1, indent_width)

    " Calculate indent level
    if indent_below > indent
        return indent_below
    elseif indent_below < indent
        return "<" . indent
    else
        return indent
    endif
endfunction

set foldexpr=AtomStyleFolding(v:lnum)
set foldmethod=expr

Это определяет выражение сгиба (см. :help fold-expr) Следующим образом:

• Для строк, непосредственно предшествующих отступам, он возвращает отступ следующего блока.
• Для строк с отступом возвращает отступ. (Делится на ширину смещения, поэтому каждый уровень отступа увеличивает возвращаемое значение на 1)
• Для строк в конце блока с отступом возвращает строку "<N", в которой для N задан отступ. Это говорит Vim, что сгиб уровня N заканчивается на этой линии.

Обновить

@alxndr спрашивает в комментариях, возможно ли расширить это, чтобы включить устаревшие ends Руби в сгибы. Вы можете начать с замены " Calculate indent levelраздела следующим:

if indent_below > indent
    return indent_below
elseif getline(a:line_number) =~ '^\s*end\s*$'
    return "<" . (indent + 1)
else
    return indent
endif

На самом деле это не самое надежное решение (например, оно потерпит неудачу, если endоператор находится в той же строке после точки с запятой). Вы можете настроить регулярное выражение и окружающий код для решения этой проблемы, но, поскольку вы сейчас находитесь в сфере анализа фактического синтаксиса файла, я подозреваю, что все может стать намного сложнее, прежде чем у вас будет хорошее решение.