Тестирование LS_COLORS в Zsh

Несколько лет назад я нашел интересный фрагмент кода, который печатает каждый тип файла в соответствующем цвете в соответствии с цветами, установленными в LS_COLORS. К сожалению, я не могу вспомнить ссылку больше.

Вот фрагмент кода test_colors.shв вопросе

eval $(echo "no:global default;fi:normal file;di:directory;ln:symbolic link;pi:named pipe;so:socket;do:door;bd:block device;cd:character device;or:orphan symlink;mi:missing file;su:set uid;sg:set gid;tw:sticky other writable;ow:other w\
ritable;st:sticky;ex:executable;"|sed -e 's/:/="/g; s/\;/"\n/g')                                                                                                                                                                            
{                                                                                                                                                                                                                                           
  IFS=:                                                                                                                                                                                                                                     
  for i in $LS_COLORS                                                                                                                                                                                                                       
  do                                                                                                                                                                                                                                        
    echo -e "\e[${i#*=}m$( x=${i%=*}; [ "${!x}" ] && echo "${!x}" || echo "$x" )\e[m"                                                                                                                                                       
  done                                                                                                                                                                                                                                      
}   

Фрагмент отлично работает в bash, но не в zsh, и я не могу сказать, почему. Когда я запускаю его, zshя получаю следующую ошибку:

> sh .test_colors.sh
.eval_colors:1: * not found
[00:fi=00:di=01;34:ln=01;36:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:su=37;41:sg=30;43:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arj=01;31:*.taz=01;31:*.lzh=01;31:*.zip=01;31:*.z=01;31:*.Z=01;31:*.gz=01;31:*.bz2=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.jpg=01;35:*.jpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.flac=01;35:*.mp3=01;35:*.mpc=01;35:*.ogg=01;35:*.wav=01;35:m

Обновление (1 ноября 2011 г.)

Я проверил сценарий @ Стефана Гименеса ниже. Я заметил, что некоторые персонажи, похоже, не сбежали правильно Есть мысли почему?

Ответ. См. Комментарии к ответу @ Stéphane Gimenez.

То же самое написано для Zsh гораздо чище:

#!/bin/zsh

typeset -A names
names[no]="global default"
names[fi]="normal file"
names[di]="directory"
names[ln]="symbolic link"
names[pi]="named pipe"
names[so]="socket"
names[do]="door"
names[bd]="block device"
names[cd]="character device"
names[or]="orphan symlink"
names[mi]="missing file"
names[su]="set uid"
names[sg]="set gid"
names[tw]="sticky other writable"
names[ow]="other writable"
names[st]="sticky"
names[ex]="executable"

for i in ${(s.:.)LS_COLORS}
do
    key=${i%\=*}
    color=${i#*\=}
    name=${names[(e)$key]-$key}
    printf '\e[%sm%s\e[m\n' $color $name
done

Вы должны спасаясь от =в , ${i%=*}потому что в противном случае шаблон суффикс =*подвергается =расширению , так =интерпретируется как имя команды. Это причина * not foundошибки.

По умолчанию Zsh не разбивает слова на подстановки переменных, поэтому $LS_COLORSрасширяется до одного слова. Чтобы forцикл работал с разделенными двоеточиями частями $LS_COLORS, используйте for i in $=LS_COLORS. Или более идиоматически в Zsh, не использовать , IFSно вместо того, чтобы явно указать , как разделить: for i in ${(s.:.)LS_COLORS}.

Синтаксис ${!x}для обозначения «значения переменной, имя которой является $x» специфичен для bash. Zsh имеет эквивалентную конструкцию, то P флаг расширения параметра : ${(P)x}.