Передать переменную оболочки как / pattern / в awk

Имея следующее в одной из моих функций оболочки:

function _process () {
  awk -v l="$line" '
  BEGIN {p=0}
  /'"$1"'/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '
}

, Так что, когда называется _process $arg, $argполучает прошло , как $1и используется в качестве шаблона поиска. Это работает так, потому что оболочка расширяется $1вместо шаблона awk! Также lможет использоваться внутри программы awk, будучи объявленным с помощью -v l="$line". Все хорошо.

Можно ли таким же образом задать шаблон для поиска в качестве переменной?

Следующее не сработает,

awk -v l="$line" -v search="$pattern" '
  BEGIN {p=0}
  /search/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '

, поскольку awk не будет интерпретироваться /search/как переменная, а будет буквально.

Используйте ~оператор awk , и вам не нужно предоставлять буквальное регулярное выражение в правой части:

function _process () {
    awk -v l="$line" -v pattern="$1" '
        $0 ~ pattern {p=1} 
        END {if(p) print l >> "outfile.txt"}
    '  
}

Хотя это было бы более эффективно (не нужно читать весь файл)

function _process () {
    grep -q "$1" && echo "$line"
}

В зависимости от шаблона, может потребоваться grep -Eq "$1"

awk  -v pattern="$1" '$0 ~ pattern'

Имеет проблему с awkрасширением escape-последовательностей ANSI C (например, \nдля новой строки, \fдля подачи формы, \\для обратной косой черты и т. Д.) $1. Таким образом, это становится проблемой, если $1содержит символы обратной косой черты, которые являются общими в регулярных выражениях (в GNU awk4.2 или выше значения, начинающиеся с @/и заканчивающиеся /, также являются проблемой ). Другой подход, который не страдает от этой проблемы, это написать:

PATTERN=$1 awk '$0 ~ ENVIRON["PATTERN"]'

Насколько плохо это будет, будет зависеть от awkреализации.

$ nawk -v 'a=\.' 'BEGIN {print a}'
.
$ mawk -v 'a=\.' 'BEGIN {print a}'
\.
$ gawk -v 'a=\.' 'BEGIN {print a}'
gawk: warning: escape sequence `\.' treated as plain `.'
.
$ gawk5.0.1 -v 'a=@/foo/' BEGIN {print a}'
foo

Все они awkработают одинаково для корректных escape-последовательностей:

$ a='\\-\b' awk 'BEGIN {print ENVIRON["a"]}' | od -tc
0000000   \   \   -   \   b  \n
0000006

(содержание $aпередано как есть)

$ awk -v a='\\-\b' 'BEGIN {print a}' | od -tc
0000000   \   -  \b  \n
0000004

( \\изменено \и \bизменено на символ возврата).

Попробуйте что-то вроде:

awk -v l="$line" -v search="$pattern" 'BEGIN {p=0}; { if ( match( $0, search )) {p=1}}; END{ if(p) print l >> "outfile.txt" }'

Нет, но вы можете просто вставить шаблон в строку в двойных кавычках, которую передаете в awk:

awk -v l="$line" "BEGIN {p=0}; /$pattern/ {p=1}; END{ if(p) print l >> \"outfile.txt\" }"

Обратите внимание, что теперь вы должны избегать двойных кавычек, но это все еще самый простой способ сделать это.

Вы можете использовать функцию eval, которая разрешает в этом примере переменную nets перед запуском awk.

nets="searchtext"
eval "awk '/"${nets}"/'" file.txt