Как использовать сортировку по команде awk print?

У меня есть пара команд в сценарии awk, который я пишу:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

Какие выводы:

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

Как я могу использовать sortкоманду в своем скрипте awk для сортировки ТОЛЬКО игроков и их чисел?

Вы можете добавить | sort -k2к своей команде. Это будет сортировать в алфавитном порядке на основе второго столбца.

Пример:

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

результаты в

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Хотя я бы не рекомендовал это (учитывая относительную простоту передачи результата через внешнюю sortкоманду), вы можете сделать это по крайней мере с последними версиями GNU awk (по крайней мере, 4.0 IIRC), как описано в Сортировке значений и индексов массива с gawk

Вот как вы могли бы реализовать это, предполагая, что у вас есть данные в ассоциативном массиве, в котором находится индекс Firstname Lastname. Сначала вам нужно определить пользовательскую функцию сравнения, которая разделяет индекс, сравнивает сначала с Lastnameпоследующим (в качестве прерывателя связей), Firstnameнапример,

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

Теперь вы можете использовать PROCINFO["sorted_in"]метод сортировки массива, упомянутый в комментариях @zwets

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

Положить его вместе

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

Тестирование:

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

В более ранних или более старых версиях awk лучше всего хранить индексированные данные Lastname Firstnameвместо этого, сортировать с обычными asorti, а затем разбивать и менять поля индексов при прохождении массива для его печати:

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

Чтобы sortтолько через пробел отделить второе поле, используйте ключ -k2,2:

... | sort -k2,2

по умолчанию sortсортировка выполняется лексикографически.

Обратите внимание, что если вы не упомянете последнее поле для ключа сортировки, т.е. если вы просто используете его, -k2вы можете не получить желаемый результат, как это будет sortпо всем полям, начиная со второго.

Также проверьте man sort.

Пытаться

awk -f myscript.awk | sort -k2

Где myscript.awk содержит чисто команды awk.

Если ваш настоящий сценарий является сценарием оболочки, у вас есть несколько вариантов, включая

• Труба выводится через сортировку. ./myscript.bash | sort -k2

• Переписать код как функцию внутри скрипта
  вместо

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  Делать

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

Но обратите внимание, что вы можете также применить сортировку к структуре do ... done вместо создания функции.

    do
       echo $i
    done | sort

Чтобы отсортировать данные для печати:

• Предположим, что вы хотите напечатать 2-е поле (через пробел), используйте это:

  awk '{print $2}' data.txt | sort
  

  например:

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• Если вы хотите распечатать все свои, data.txtно отсортированные по столбцу 2, то:

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

Используйте эту логику в ваших требованиях.

Вы можете использовать man sortдля более интересных функций sort.

как насчет ниже:

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

это работает, когда я проверил.

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

Чтобы отсортировать вывод в файл:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}