Вот способ сделать это в awk(весь вывод, как сделано кодом в вашем ответе).
Когда вы заканчиваете тем, что обрабатываете тот же самый ввод снова и снова, это обычно указывает, что другой подход мог бы быть лучше.
awkидеально подходит для обработки ввода текста, как это. awkпрограммы намного длиннее, чем выполняемые sed, но их гораздо легче читать, и вы можете добавить к ним операторы печати, чтобы сделать отладку намного проще.
Я оставил свои отладочные заявления в (закомментированный). Вы можете раскомментировать их, чтобы посмотреть, как работает скрипт.
Вы должны поместить awkпрограмму куда-нибудь, и самое простое место в одном случае использования - это поместить все это в одну строку в кавычках в awkкомандной строке.
Таким образом, вам не нужно хранить его в отдельном файле или во временном файле, поэтому управление файлами не требуется, и скрипт будет работать сам по себе.
Эта программа выглядит долго, но это почти все комментарии, операторы отладки и пробелы.
#!/bin/bash
## Whole awk program is one single quoted string
## on the awk command line
## so we don't need to put it in a separate file
## and so bash doesn't expand any of it
## Debugging statements were left in, but commented out
/usr/bin/cpuid | awk '
BEGIN { ## initialize variables - probably unnecessary
em = ""
ef = ""
fa = ""
mo = ""
si = ""
ps = ""
}
## get each value only once
## extended model is in field 4 starting at the third character
## of a line which contains "extended model"
/extended model/ && em == "" {
em = substr($4, 3)
##print "EM " em
}
## extended family is in field 4 starting at the third character
## of a line which contains "extended family"
/extended family/ && ef == "" {
ef = substr($4, 3)
##print "EF " ef
}
## family is in the last field, starting at the second character
## and is two characters shorter than the field "()"
## of a line which starts with "family"
## (so it does not match "extended family")
$1 == "family" && fa == "" {
##print NF " [" $NF "]"
##print "[" substr($NF, 2) "]"
l = length($NF) - 2
fa = substr($NF, 2, l)
##print "FA " fa
}
## model is in the third field, starting at the third character
## of a line which starts with "model"
## (so it does not match "extended model")
$1 == "model" && mo == "" {
mo = substr($3, 3)
##print "MO " mo
}
## stepping id is in field 4 starting at the third character
## of a line which contains "stepping id"
/stepping id/ && si == "" {
si = substr($4, 3)
##print "SI " si
}
## processor serial number is in field 4 starting at the third character
## of a line which contains "processor serial number:"
/processor serial number:/ && ps == "" {
ps = $4
##print "PS " ps
}
## Quit when we have all the values we need
em != "" && ef != "" && fa != "" && mo != "" && si != "" && ps != "" {
exit
}
END {
print em ef fa mo si " " ps
}
'