Есть ли способ контролировать, в каком окне Emacs открывает новые буферы?

Я использую sr-speedbar с emacs, и я часто делю фрейм на 2-3 разных окна, и всякий раз, когда я нажимаю на файл в sr-speedbar, он всегда открывает новый буфер в самом нижнем окне. Я пытаюсь сохранить крайнее правое окно в качестве относительно небольшого анси-термина, и emacs настаивает на открытии новых буферов в небольшом окне, а не в гораздо большей области, которую я хотел бы использовать для редактирования буферов.

Есть ли способ, которым я могу настроить логику создания буфера, чтобы предпочесть более высокие окна над более низкими окнами?

Я уже пытался взять мое самое низкое окно и пометить его как защищенное, и это просто заставило emacs разделить его на две неоправданно маленькие части. Затем я попытался включить window-size-fixed и вместо того, чтобы emacs открывал буфер над этим окном, он просто выдал ошибку, что окно было слишком маленьким, чтобы его можно было разделить. Хорошо, я думаю, что это перестало забивать мое самое нижнее окно, но глупо, что оно мешает мне открывать новые буферы.

В идеале я хотел бы иметь возможность заставить emacs выбирать самое верхнее правое окно для отображения вновь созданных буферов, а не пытаться разбить самое нижнее правое окно.

Я предполагаю, что вы используете Emacs 24; Я не проверял этот ответ ни в одной более ранней версии и не знаю, когда в Emacs была добавлена ​​концепция выделенных окон. Я видел упоминания о его использовании, которые датируются 2011 годом, поэтому я предполагаю, что Emacs 23 (по крайней мере) также имеет такую ​​возможность.

Вы можете запретить Emacs открывать новый буфер в данном окне, выделив окно его буферу .

В простейшем случае вы можете сделать это, выбрав окно, которое вы хотите выделить, убедившись, что оно в данный момент отображает буфер, которому вы хотите выделить его, и затем выполнить M-: (set-window-dedicated-p (selected-window) t). Это предотвратит Emacs, учитывая, что окно было изменено при принятии решения, в каком окне показывать буфер. Чтобы удалить посвящение, оцените то же выражение, заменив второй аргумент на nil.

Вы можете запретить Emacs пытаться разбить окно, в котором отображается заданный буфер, устанавливая для локальной переменной буфера window-size-fixed значение, отличное от nil.

В простейшем случае вы можете сделать это, выбрав окно и выполнив M-: (setq window-size-fixed t). Чтобы зафиксировать только высоту или ширину окон, отображающих буфер, оцените то же выражение, передавая 'heightили 'widthв качестве второго аргумента; чтобы снять ограничение, замените второй аргумент на nil.

В общем случае я нашел вашу проблему достаточно интересной, чтобы найти решение , которое вы можете добавить в свой путь загрузки (require), и использовать:

;;; dedicate-windows-manually.el --- Manually (un)dedicate windows

;; Copyright (C) 2013 Aaron Miller
;; <me@aaron-miller.me>

;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2 of
;; the License, or (at your option) any later version.

;; This program is distributed in the hope that it will be
;; useful, but WITHOUT ANY WARRANTY; without even the implied
;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
;; PURPOSE.  See the GNU General Public License for more details.

;; You should have received a copy of the GNU General Public
;; License along with this program; if not, write to the Free
;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
;; MA 02111-1307 USA

;;; Commentary:

;; Introduction
;; ============

;; The functions here defined allow you to manually dedicate and
;; undedicate windows, that is, prevent `set-window-buffer' from
;; considering them when selecting a window in which to display a
;; given buffer.

;; Windows dedicated in this fashion will also be protected from
;; splitting by setting `window-size-fixed'.

;; Installation
;; ============

;; Place this file in your load path; then, place the following
;; command somewhere in your initialization file:

;; (require 'dedicate-windows-manually)

;; Now you can use M-x dedicate-window to dedicate the selected window
;; to its currently displayed buffer, M-x undedicate-window to release
;; a dedication so applied, and M-x dedicate-window-toggle to switch
;; between the states.

;; These functions will operate only on manually dedicated or
;; undedicated windows; that is, M-x dedicate-window will not dedicate
;; a window which is already dedicated (i.e. "(window-dedicated-p
;; window) -> t", and M-x undedicate-window will not undedicate a
;; window which was not dedicated by way of M-x dedicate-window.

;; If you find yourself frequently doing M-x dedicate-window-toggle,
;; you might wish to place something like this in your init file:

;; (global-set-key (kbd "C-x 4 C-d") 'dedicate-window-toggle)

;; Bugs:
;; * Changing the lighter string while you have windows dedicated is
;;   probably not a good idea.
;; * I should certainly find a better way to change the mode line.

;;; Code:

(defcustom dedicated-window-lighter-string " [D]"
  "A string, propertized with `dedicated-window-lighter-face', prepended
to the mode line of manually dedicated windows.")

(defvar dedicated-windows-by-hand nil
  "A list of windows known to have been manually dedicated. Windows not
in this list will not be undedicated by `undedicate-window'.")

(defun dedicate-window-was-by-hand-p (window)
  (let ((result nil))
    (loop for w in dedicated-windows-by-hand
          collect (if (eq w window) (setq result t)))
    result))

(defun dedicate-window (&optional window flag)
  "Dedicate a window to its buffer, and prevent it from being split.

Optional argument WINDOW, if non-nil, should specify a window. Otherwise,
or when called interactively, the currently selected window is used.

Optional argument FLAG, if non-nil, will be passed verbatim to
`set-window-dedicated-p'."
  (interactive nil)
  (if (eq nil window) (setq window (selected-window)))
  (if (eq nil flag) (setq flag t))
  (if (window-dedicated-p window)
      (message "Window is already dedicated.")
    (progn
      (add-to-list 'dedicated-windows-by-hand window)
      (setq mode-line-format
            (append `(,dedicated-window-lighter-string) mode-line-format))
      (setq window-size-fixed t)
      (set-window-dedicated-p window flag))))

(defun undedicate-window (&optional window)
  "Un-dedicate a window from its buffer.

Optional argument WINDOW, if non-nil, should specify a window listed in
`dedicated-windows-by-hand'. Otherwise, or when called interactively,
the currently selected window is used.

If WINDOW is not in `dedicated-windows-by-hand', a complaint will be
issued and nothing will be done."
  (interactive nil)
  (if (eq nil window) (setq window (selected-window)))
  (if (not (window-dedicated-p window))
      (message "Window is not dedicated.")
    (if (not (dedicate-window-was-by-hand-p window))
        (message "Window is not dedicated by hand.")
      (progn
        (setq dedicated-windows-by-hand
              (remove window dedicated-windows-by-hand))
        (setq mode-line-format
              (remove dedicated-window-lighter-string mode-line-format))
        (setq window-size-fixed nil)
        (set-window-dedicated-p window nil)))))

(defun dedicate-window-toggle (&optional window)
  "Toggle a window's manual buffer dedication state.

Optional argument WINDOW, if non-nil, should specify a window. Otherwise,
or when called interactively, the value of `selected-window' is used."
  (interactive nil)
  (if (eq nil window) (setq window (selected-window)))
  (if (window-dedicated-p window)
      (undedicate-window window)
    (dedicate-window window)))

(provide 'dedicate-windows-manually)

;;; dedicate-windows-manually.el ends here

В последних выпусках Emacs display-buffer-alistбыла добавлена опция . Он обеспечивает детальный контроль над отображением в буфере, используемыми окнами и т. Д. Однако, поскольку он позволяет вам делать так много вещей, он также довольно сложен и труден для описания. Обратитесь к документации: C-h v display-buffer-alist.