Ярлык или макрос для изменения типа шрифта в Microsoft Outlook

Есть ли сочетание клавиш для изменения шрифта в Outlook в Windows? Мне приходится постоянно переключаться между Calibri и Courier по техническим причинам, и каждый раз нажимать на диалоги шрифтов становится очень утомительно. Я знаю, что могу использовать Ctrl + Space, чтобы изменить что-либо на шрифт по умолчанию (Calibri).

Если ярлыка нет, кто-нибудь может помочь мне создать макрос для переключения шрифтов? Я полагаю, я могу назначить любой ярлык для макроса?

(Ответ от techie007 не работал для меня в Outlook 2010)

Этот макрос (адаптированный с http://www.slipstick.com/developer/word-macro-apply-formatting-outlook-email/ ) делает:

Sub SetCodeFont()
    Dim objItem As Object
    Dim objInsp As Outlook.Inspector

    Dim objWord As Word.Application
    Dim objDoc As Word.Document
    Dim objSel As Word.Selection
    On Error Resume Next

    Set objItem = Application.ActiveInspector.CurrentItem
    If Not objItem Is Nothing Then
        If objItem.Class = olMail Then
            Set objInsp = objItem.GetInspector
            If objInsp.EditorType = olEditorWord Then
                Set objDoc = objInsp.WordEditor
                Set objWord = objDoc.Application
                Set objSel = objWord.Selection
                objSel.Font.Name = "Consolas"
            End If
        End If
    End If

    Set objItem = Nothing
    Set objWord = Nothing
    Set objSel = Nothing
    Set objInsp = Nothing
End Sub

Далее в редакторе VBA перейдите Tools > Referencesи выберите Microsoft Word 14.0 Object Library.

Теперь, чтобы создать сочетание клавиш для макроса, добавьте его на панель быстрого доступа следующим образом:

1. Откройте новое почтовое сообщение
2. Нажмите на маленькую стрелку выпадающего меню на панели быстрого доступа (обычно расположенную в верхней части окна) и выберите «Больше команд ...»

3. Откроется диалоговое окно «Параметры Outlook», затем выберите «Макросы» в раскрывающемся списке «Выбрать команды из:».

4. Выберите макрос SetCodeFont из списка и нажмите «Добавить >>»
5. Кнопка макроса теперь появится на панели быстрого доступа

Для запуска макроса выделите текст в своем электронном письме и нажмите, Alt + <Num>где <Num>находится позиция макроса на панели быстрого доступа. Например, если макрос является первой кнопкой на панели инструментов, используйте ее Alt + 1для вызова.

Просто FYI, это последовательность клавиш , чтобы сфокусировать селектор шрифта: Alt, H, F,F