Можно ли установить Internet Explorer в качестве браузера по умолчанию для запуска из командной строки?

У меня есть веб-приложение, которое работает только под Internet Explorer, но если случается, что Firefox является браузером по умолчанию, оно не работает. Пользователи находятся в доменной среде, и хотя я пытаюсь запустить наше приложение из пакета следующим образом:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

приложение не запускается, если я не изменю браузер вручную.

Эта команда установит IE в качестве браузера по умолчанию:

shmgrate.exe OcinstallreinstallIE

Эта политика не должна позволять людям определять браузер по умолчанию.

Вы можете попробовать это, это будет работать

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

ошибка в вашей команде заключалась в том, startчто первая строка в кавычках ожидает название приложения, которое в этом случае вы можете оставить пустым.

для установки в iexplorer.exeкачестве веб - браузера системы по умолчанию, вы можете использовать assocи ftypeкоманды, которые ассоциируются расширения с типами файлов и типов файлов с исполняемыми файлами, например , так:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 это аргумент здесь - это URL или файл, который вы можете отправить в программу в качестве ввода

Windows Vista и более поздние версии, IE 7+

Следующий пакетный скрипт имитирует нажатие кнопки « Установить эти программы по умолчанию» в апплете панели управления «Программы по умолчанию». Протестировано с Vista / 7 и IE 7 / IE 11.

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

замечания

Любое приложение веб-браузера может зарегистрироваться в качестве интернет-клиента в меню «Пуск». Эта видимость в сочетании с правильной регистрацией файлов приложения и типов протоколов дает статус браузера приложения по умолчанию. Веб-браузер по умолчанию используется для запуска произвольных URL-адресов из любой точки системы.

Примечание. Существующие регистрации [ссылка меню Пуск] игнорируются в Windows 7 и более поздних версиях. Эта регистрация устарела с Windows 7.

_{Источник: Как зарегистрировать интернет-браузер или почтовый клиент в меню «Пуск» Windows}

­­

Иерархическая структура реестра для сопоставлений файлов и протоколов отдает предпочтение настройкам по умолчанию для каждого пользователя по сравнению с настройками на уровне компьютера.

_{Источник: Программы по умолчанию}

Вы можете добавить ниже две строки в файле bat

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

После запуска bat перезагрузите компьютер / выйдите из системы и снова войдите в систему, так как две вышеуказанные командные строки предназначены для изменения значений реестра.

Подробности можно найти здесь

(Исправлено) -Не могу установить Internet Explorer в качестве браузера по умолчанию! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

Я не знаю о настройке браузера по умолчанию из командной строки, но вы можете установить и применить его для домена через групповую политику.

Вот кое-что, чтобы вы начали:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

Просто бросьте, startчтобы заставить команду или командный файл работать.

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Для Windows 8 (IE 10+) это простой сценарий VBS:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

Будет запущена страница IE для изменения IE по умолчанию и симуляции нажатия на кнопку для подтверждения.