Windows Vista: как выполнить программу .exe в cmd «Как администратор»

11

Да это оно. Мне нужно запустить программу .exe в строке dos cmd, и она должна работать как при нажатии правой кнопки мыши и выборе «Запуск от имени администратора»

windows-vista shell command-line

— BinaryMisfit
источник

Я тоже думал об этом. Моим решением было либо создать командный файл с командой и позволить ему всегда запускаться от имени администратора, либо открыть cmd от имени администратора. Но такое ощущение, что должно быть какое-то элегантное решение.

— OregonGhost

15

В Windows есть команда «runas», которая немного похожа на sudo в системах Unix-y. Попробуйте набрать "runas /?" в вашей командной строке.

— Neall
источник

Или посмотрите здесь: technet.microsoft.com/en-us/library/cc771525.aspx

— Asaf R

Это не правильный ответ, если у вас есть с поддержкой непустого паролем пользователя администратора.

— jiggunjer

7

Если вы запускаете cmd сам как администратор, все остальное, что вы запускаете оттуда, также будет. Я просто настроил ярлык для командной строки, которая открывается как администратор. Все оттуда хорошо идти.

— Kilhoffer
источник

5

Я использовал дуэт сценария .cmd & .vbs под названием elevate, он отлично работает для моих нужд. Все, что вам нужно, это набрать

поднять [команду]

из Пуск> Выполнить или из командной строки, и он будет запускать команду с правами администратора. Надеюсь, это поможет!

Вот elevate.cmd:

:: //***************************************************************************
:: // ***** Script Header *****
:: //
:: // File:      Elevate.cmd
:: //
:: // Additional files required:  Elevate.vbs
:: //
:: // Purpose:   To provide a command line method of launching applications that
:: //            prompt for elevation (Run as Administrator) on Windows Vista.
:: //
:: // Usage:     elevate.cmd application <application arguments>
:: //
:: // Version:   1.0.0
:: // Date :     01/02/2007
:: //
:: // History:
:: // 1.0.0   01/02/2007  Created initial version.
:: //
:: // ***** End Header *****
:: //***************************************************************************


@echo off

:: Pass raw command line agruments and first argument to Elevate.vbs
:: through environment variables.
set ELEVATE_CMDLINE=%*
set ELEVATE_APP=%1

start wscript //nologo "%~dpn0.vbs" %*

и elevate.vbs:

' //***************************************************************************
' // ***** Script Header *****
' //
' // File:      Elevate.vbs
' //
' // Additional files required:  Elevate.cmd
' //
' // Purpose:   To provide a command line method of launching applications that
' //            prompt for elevation (Run as Administrator) on Windows Vista.
' //
' // Usage:     (Not used directly.  Launched from Elevate.cmd.)
' //
' // Version:   1.0.1
' // Date :     01/03/2007
' //
' // History:
' // 1.0.0   01/02/2007  Created initial version.
' // 1.0.1   01/03/2007  Added detailed usage output.
' //
' // ***** End Header *****
' //***************************************************************************


Set objShell = CreateObject("Shell.Application")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWshProcessEnv = objWshShell.Environment("PROCESS")

' Get raw command line agruments and first argument from Elevate.cmd passed
' in through environment variables.
strCommandLine = objWshProcessEnv("ELEVATE_CMDLINE")
strApplication = objWshProcessEnv("ELEVATE_APP")
strArguments = Right(strCommandLine, (Len(strCommandLine) - Len(strApplication)))

If (WScript.Arguments.Count >= 1) Then
    strFlag = WScript.Arguments(0)
    If (strFlag = "") OR (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
        OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "-?") OR (strFlag="h") _
        OR (strFlag = "?") Then
        DisplayUsage
        WScript.Quit
    Else
        objShell.ShellExecute strApplication, strArguments, "", "runas"
    End If
Else
    DisplayUsage
    WScript.Quit
End If


Sub DisplayUsage

    WScript.Echo "Elevate - Elevation Command Line Tool for Windows Vista" & vbCrLf & _
                 "" & vbCrLf & _
                 "Purpose:" & vbCrLf & _
                 "--------" & vbCrLf & _
                 "To launch applications that prompt for elevation (i.e. Run as Administrator)" & vbCrLf & _
                 "from the command line, a script, or the Run box." & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage:   " & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate application <arguments>" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate notepad ""C:\Windows\win.ini""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate cmd /k cd ""C:\Program Files""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command Set-Location 'C:\Windows'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage with scripts: When using the elevate command with scripts such as" & vbCrLf & _
                 "Windows Script Host or Windows PowerShell scripts, you should specify" & vbCrLf & _
                 "the script host executable (i.e., wscript, cscript, powershell) as the " & vbCrLf & _
                 "application." & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage with scripts:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate wscript ""C:\windows\system32\slmgr.vbs"" –dli" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command & 'C:\Temp\Test.ps1'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "The elevate command consists of the following files:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate.cmd" & vbCrLf & _
                 "    elevate.vbs" & vbCrLf

End Sub

— kolrie
источник

Просто любопытно, в чем преимущество этого по сравнению с рунами?

— tfinniga

Duh! Ты поймал меня! :) Я бы не знал преимущества над рунами, но когда вы не знаете руны, это единственная альтернатива. Я определенно смущен :)

Я думаю, что было бы полезно, если бы мы однажды прочитали, что мы используем в качестве сценария!

1

Этот дуэт описан по адресу technet.microsoft.com/en-us/magazine/…

2

Очевидным преимуществом сценария elevate является то, что он позволяет повысить уровень пользователя до администратора под UAC без необходимости предоставления имени пользователя и пароля администратора (при условии, что вы вошли в систему как пользователь с правами администратора). Может ли runas.exe это сделать?

3

Вы должны использовать команду RunAs.exe.

Вот несколько инструкций: http://www.softtreetech.com/24x7/archive/53.htm

— Gthompson83
источник

RunAs неверен. Это не повышает команду.

— Surfasb

2

Вы также можете нажать клавишу Windows, введите CMD, это будет список cmd в программах, щелкните правой кнопкой мыши по нему -> Свойства -> Совместимость -> Запустите эту программу от имени администратора

Это всегда будет работать от имени администратора.

— Почтальон
источник

Вы также можете использовать Ctrl + Shift + Enter.

— Джои

1

Так как кто-то опубликовал эквивалент VBS, вот функция Invoke-Admin для PowerShell

function Invoke-Admin() {
param ( [string]$program = $(throw "Please specify a program" ),
        [string]$argumentString = "",
        [switch]$waitForExit )

$psi = new-object "Diagnostics.ProcessStartInfo"
$psi.FileName = $program 
$psi.Arguments = $argumentString
$psi.Verb = "runas"
$proc = [Diagnostics.Process]::Start($psi)
if ( $waitForExit ) {
    $proc.WaitForExit();
}

}

— JaredPar
источник

0

Короче говоря:

Нажмите / нажмите Пуск, затем нажмите CTRL + SHIFT и ENTER. Confirm.

В деталях:

Нажмите кнопку Пуск. Введите «cmd» (без кавычек) сразу (1)
Удерживайте CTRL и SHIFT
Нажмите Ввод
Подтвердите диалоговое окно Windows Vista UAC

(1) Немедленно означает ввести его в поле поиска, а не в поле «Выполнить».

— Mackaaij
источник

0

Вы можете использовать VBScript как таковой. Создайте .vbsфайл, например ambika.vbs:

Set objShell = CreateObject(“Shell.Application”)
Set objWshShell = WScript.CreateObject(“WScript.Shell”)
Set objWshProcessEnv = objWshShell.Environment(“PROCESS”)

objShell.ShellExecute “C:\Windows\system32\cmd.exe”, “/k”, “”, “runas”

— Амбика Сингх
источник