Может ли командный файл Windows определять собственное имя файла?

Может ли командный файл Windows определять собственное имя файла?

Например, если я запустил командный файл C: \ Temp \ myScript.bat, есть ли в myScript.bat команда, которая может определить строку «myScript.bat»?

Да.

Используйте специальную %0переменную, чтобы получить путь к текущему файлу.

Напишите, %~n0чтобы получить только имя файла без расширения.

Напишите, %~n0%~x0чтобы получить имя файла и расширение.

Также можно написать, %~nx0чтобы получить имя файла и расширение.

Вы можете получить имя файла, но вы также можете получить полный путь, в зависимости от того, что вы поместите между "% ~" и "0". Сделайте свой выбор из

d -- drive
p -- path
n -- file name
x -- extension
f -- full path

Например, изнутри c: \ tmp \ foo.bat %~nx0выдает "foo.bat", а %~dpnx0дает "c: \ tmp \ foo.bat". Обратите внимание, что части всегда собираются в каноническом порядке, поэтому, если вы проявите симпатию и попытаетесь %~xnpd0, вы все равно получите "c: \ tmp \ foo.bat"

Используя следующий сценарий, основанный на ответе SLaks, я определил, что правильный ответ:

echo The name of this file is: %~n0%~x0
echo The name of this file is: %~nx0

А вот и мой тестовый сценарий:

@echo off
echo %0
echo %~0
echo %n0
echo %x0
echo %~n0
echo %dp0
echo %~dp0
pause

Что мне интересно, так это то, что % nx0 не будет работать, учитывая, что мы знаем, что символ '~' обычно используется для удаления / обрезки кавычек из переменной.

Имейте в виду, что 0это особый случай номеров параметров внутри командного файла, где 0означает этот файл, указанный в командной строке .

Итак, если это файл myfile.bat, вы можете вызвать его несколькими способами, как показано ниже, каждый из которых даст вам другой результат использования %0или %~0:

myfile

myfile.bat

mydir\myfile.bat

c:\mydir\myfile.bat

"c:\mydir\myfile.bat"

Все вышеперечисленное является законным вызовом, если вы вызываете его из правильного относительного места в каталог, в котором он существует. %~0удаляет кавычки из последнего примера, тогда как%0 нет.

Потому что все они дают разные результаты, %0 и %~0вряд ли вы действительно захотите использовать.

Вот командный файл для иллюстрации:

@echo Full path and filename: %~f0
@echo Drive: %~d0
@echo Path: %~p0
@echo Drive and path: %~dp0
@echo Filename without extension: %~n0
@echo Filename with    extension: %~nx0
@echo Extension: %~x0
@echo Filename as given on command line: %0
@echo Filename as given on command line minus quotes: %~0
@REM Build from parts
@SETLOCAL
@SET drv=%~d0
@SET pth=%~p0
@SET fpath=%~dp0
@SET fname=%~n0
@SET ext=%~x0
@echo Simply Constructed name: %fpath%%fname%%ext%
@echo Fully  Constructed name: %drv%%pth%%fname%%ext%
@ENDLOCAL
pause

Попробуйте запустить пример ниже, чтобы почувствовать, как работают магические переменные.

@echo off

SETLOCAL EnableDelayedExpansion

echo Full path and filename: %~f0
echo Drive: %~d0
echo Path: %~p0
echo Drive and path: %~dp0
echo Filename without extension: %~n0
echo Filename with    extension: %~nx0
echo Extension: %~x0

echo date time : %~t0
echo file size: %~z0

ENDLOCAL

Соответствующие правила следующие.

%~I         - expands %I removing any surrounding quotes ("")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Ниже мой исходный код:

@echo off
Set z=%%
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.

Я заметил, что имя файла, заданное% ~ 0 и% 0, - это то, как оно было введено в командной оболочке, а не то, как этот файл фактически назван. Поэтому, если вы хотите использовать буквальный регистр для имени файла, вы должны использовать% ~ n0. Однако при этом не будет учитываться расширение файла. Но если вы знаете имя файла, вы можете добавить следующий код.

set b=%~0
echo %~n0%b:~8,4%

Я узнал, что ": ~ 8,4%" означает начало с 9-го символа переменной, а затем показать следующие 4 символа. Диапазон составляет от 0 до конца переменной строки. Так что% Path% будет очень длинным!

fIlEnAmE.bat
012345678901

Однако это не так хорошо, как решение Джула (% ~ x0) выше.

Мои доказательства:

C:\bin>filename.bat

%0.......filename.bat
%~0......filename.bat
. . .

C:\bin>fIlEnAmE.bat

%0.......fIlEnAmE.bat
%~0......fIlEnAmE.bat
%n0......n0
%x0......x0
%~n0.....FileName
%dp0.....dp0
%~dp0....C:\bin\

%~n0%b:~8,4%...FileName.bat

Press any key to continue . . .

C:\bin>dir
 Volume in drive C has no label.
 Volume Serial Number is CE18-5BD0

 Directory of C:\bin
. . .
05/02/2018  11:22 PM               208 FileName.bat

Вот окончательный код

@echo off
Set z=%%
set b=%~0
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.
echo A complex solution:
echo ===================================
echo %z%~n0%z%b:~8,4%z%...%~n0%b:~8,4%
echo ===================================
echo.
echo The preferred solution:
echo ===================================
echo %z%~n0%z%~x0.......%~n0%~x0
echo ===================================
pause