Комментирование нескольких строк в пакетном файле DOS

Question 1

Я написал огромный пакетный файл MS DOS. Чтобы протестировать этот командный файл, мне нужно выполнить только несколько строк и я хочу скрыть / закомментировать оставшиеся.

У меня есть некоторые существующие строки комментариев, начинающиеся с, ::поэтому я больше не могу их использовать ::, так как он скремблирует все комментарии.

Как я могу решить эту проблему?

Question 2

Вы можете использовать a, gotoчтобы пропустить код.

goto comment
...skip this...
:comment

Question 3

Если вы хотите добавить REM в начале каждой строки вместо использования GOTO, вы можете использовать Notepad ++, чтобы сделать это легко, выполнив следующие действия:

Выберите блок линий
нажмите Ctrl-Q

Повторите шаги, чтобы раскомментировать

Question 4

break||(
 code that cannot contain non paired closing bracket
)

Хотя это gotoрешение является хорошим вариантом, оно не будет работать в квадратных скобках (включая команды FOR и IF), но это будет. Хотя вы должны быть осторожны закрывающих скобок и неправильного синтаксиса для FORи IFкоманд , так как они будут обрабатываться.

Обновить

Обновление в ответе dbenham дало мне несколько идей. Во-первых, есть два разных случая, когда нам могут понадобиться многострочные комментарии - в контексте скобок, где GOTO нельзя использовать, и вне его. Внутри скобок контекста мы можем использовать другие скобки , если есть условие , которое предотвращает код будет executed.Though код thede по- прежнему будет проанализирован и будут обнаружены некоторые синтаксические ошибки ( FOR, IF, неправильно закрытые скобки, неправильное расширение параметра ..). Таким образом , если есть возможность, лучше использовать GOTO.

Хотя невозможно создать макрос / переменную, используемую в качестве метки, но можно использовать макросы для комментариев в скобках. Тем не менее, можно использовать два трюка, чтобы сделать комментарии GOTO более симметричными и более приятными (по крайней мере, для меня). Для этого я использую два трюка: 1) вы можете поместить один символ перед меткой, и goto все равно сможет его найти (я понятия не имею, почему это так. Я думаю, он ищет диск). 2) вы можете поставить одиночный : символ в конце имени переменной, и функция замены / подстановки не будет активирована (даже при включенных расширениях). Это в сочетании с макросами для комментариев в скобках может сделать оба случая почти одинаковыми.

Итак, вот примеры (в том порядке, в котором они мне нравятся больше всего):

С прямоугольными скобками :

@echo off

::GOTO comment macro
set "[:=goto :]%%"
::brackets comment macros
set "[=rem/||(" & set "]=)"

::testing
echo not commented 1

%[:%
  multi 
  line
  comment outside of brackets
%:]%

echo not commented 2

%[:%
  second multi 
  line
  comment outside of brackets
%:]%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %[%
        multi line
        comment
    %]%
    echo second not commented line of the %%a execution
)

С фигурными скобками :

@echo off

::GOTO comment macro
set "{:=goto :}%%"
::brackets comment macros
set "{=rem/||(" & set "}=)"

::testing
echo not commented 1

%{:%
  multi 
  line
  comment outside of brackets
%:}%

echo not commented 2

%{:%
  second multi 
  line
  comment outside of brackets
%:}%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %{%
        multi line
        comment
    %}%
    echo second not commented line of the %%a execution
)

В скобках :

@echo off

::GOTO comment macro
set "(:=goto :)%%"
::brackets comment macros
set "(=rem/||(" & set ")=)"

::testing
echo not commented 1

%(:%
  multi 
  line
  comment outside of brackets
%:)%

echo not commented 2

%(:%
  second multi 
  line
  comment outside of brackets
%:)%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %(%
        multi line
        comment
    %)%
    echo second not commented line of the %%a execution
)

Смесь между стилями powershell и C ( <не может использоваться, потому что перенаправление с более высоким приоритетом. *Не может использоваться из-за %*):

@echo off

::GOTO comment macro
set "/#:=goto :#/%%"
::brackets comment macros
set "/#=rem/||(" & set "#/=)"

::testing
echo not commented 1

%/#:%
  multi 
  line
  comment outside of brackets
%:#/%

echo not commented 2

%/#:%
  second multi 
  line
  comment outside of brackets
%:#/%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %/#%
        multi line
        comment
    %#/%
    echo second not commented line of the %%a execution
)

Чтобы emphase это комментарий (мысль не так коротка):

@echo off

::GOTO comment macro
set "REM{:=goto :}REM%%"
::brackets comment macros
set "REM{=rem/||(" & set "}REM=)"

::testing
echo not commented 1

%REM{:%
  multi 
  line
  comment outside of brackets
%:}REM%

echo not commented 2

%REM{:%
  second multi 
  line
  comment outside of brackets
%:}REM%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %REM{%
        multi line
        comment
    %}REM%
    echo second not commented line of the %%a execution
)

Question 5

Другой вариант - заключить нежелательные строки в блок IF, который никогда не может быть истинным.

if 1==0 (
...
)

Конечно, внутри блока if ничего не будет выполнено, но будет проанализировано. Таким образом, у вас не может быть недопустимого синтаксиса внутри. Кроме того, комментарий не может содержать, )если он не экранирован или не заключен в кавычки. По этим причинам принятое решение GOTO более надежно. (Решение GOTO также может быть быстрее)

Обновление 2017-09-19

Вот косметическое усовершенствование решения GOTO от pdub . Я определяю простой «макрос» переменной среды, который делает синтаксис комментариев GOTO немного лучше самодокументированным. Хотя обычно рекомендуется, чтобы метки: были уникальными в рамках пакетного сценария, действительно допустимо встраивать несколько комментариев, подобных этому, в один пакетный сценарий.

@echo off
setlocal

set "beginComment=goto :endComment"

%beginComment%
Multi-line comment 1
goes here
:endComment

echo This code executes

%beginComment%
Multi-line comment 2
goes here
:endComment

echo Done

Или вы можете использовать один из этих вариантов решения npocmaka . Использование REM вместо BREAK немного проясняет замысел.

rem.||(
   remarks
   go here
)

rem^ ||(
   The space after the caret
   is critical
)

Question 6

Просто хочу отметить, что решение GOTO от pdub не совсем корректно в случае: метка комментария появляется несколько раз. Я изменяю код из этого вопроса в качестве примера.

@ECHO OFF
SET FLAG=1
IF [%FLAG%]==[1] (
    ECHO IN THE FIRST IF...
    GOTO comment
    ECHO "COMMENT PART 1"
:comment
    ECHO HERE AT TD_NEXT IN THE FIRST BLOCK
)

IF [%FLAG%]==[1] (
    ECHO IN THE SECOND IF...
    GOTO comment
    ECHO "COMMENT PART"
:comment
    ECHO HERE AT TD_NEXT IN THE SECOND BLOCK
)

Выход будет

IN THE FIRST IF...
HERE AT TD_NEXT IN THE SECOND BLOCK

Команда ECHO HERE HERE AT TD_NEXT В ПЕРВОМ БЛОКЕ пропускается.

Question 7

@jeb

И после этого stderr кажется недоступным

Нет, попробуйте это:

@echo off 2>Nul 3>Nul 4>Nul

   ben ali  
   mubarak 2>&1
   gadeffi
   ..next ?

   echo hello Tunisia

  pause

Но почему это работает?

извините, я отвечаю на вопрос по-французски:

(перенаправление из пункта 3> есть специальный автомобиль elle persiste, on va l'utiliser pour capturer le flux des erreurs 2> is on va le transformer en un flux persistant à l'ade de 3> ceci va nous permettre d'avoir une gestion des erreur pour tout notre environement de script..par la suite si on veux recuperer le flux 'stderr' il faut faire une autre redirection du handle 2> au handle 1> qui n'est autre que la console ..)

Question 8

попробуй это:

   @echo off 2>Nul 3>Nul 4>Nul

   ben ali
   mubarak
   gadeffi
   ..next ?

   echo hello Tunisia

  pause