В чем разница между бэкстиками Perl, системой и exec?

Может кто-нибудь, пожалуйста, помогите мне? В Perl какая разница между:

exec "command";

и

system("command");

и

print `command`;

Есть ли другие способы запуска команд оболочки?

Exec

выполняет команду и никогда не возвращается . Это как returnутверждение в функции.

Если команда не найдена, execвозвращается false. Он никогда не возвращает true, потому что, если команда найдена, она никогда не возвращается вообще. Там также нет смысла возвращаться STDOUT, STDERRили статус завершения команды. Вы можете найти документацию об этом perlfunc, потому что это функция.

система

выполняет команду, и ваш Perl-скрипт продолжается после ее завершения.

Возвращаемое значение является состоянием выхода команды. Вы можете найти документацию об этом в perlfunc.

обратные кавычки

Like systemвыполняет команду, и ваш Perl-скрипт продолжается после ее завершения.

В отличие systemот возвращаемого значения STDOUTкоманды. qx//эквивалентно тэгам Вы можете найти документацию об этом в perlop, потому что в отличие от systemи execон является оператором.

Другие способы

Чего не хватает в вышесказанном, так это способа выполнить команду асинхронно. Это означает, что ваш Perl-скрипт и ваша команда выполняются одновременно. Это может быть достигнуто с open. Это позволяет вам читать STDOUT/ STDERRи писать в STDINвашей команды. Это зависит от платформы, хотя.

Есть также несколько модулей, которые могут облегчить эту задачу. Есть IPC::Open2и IPC::Open3и IPC::Run, а также Win32::Process::Createесли вы находитесь на окнах.

В общем использовании I system, open, IPC::Open2или в IPC::Open3зависимости от того, что я хочу сделать. qx//Оператор, в то время как простые, слишком сдерживая в своей функциональности будет очень полезен вне быстрых взломов. Я считаю, openчто гораздо удобнее.

system: запустите команду и дождитесь ее возвращения

Используется, systemкогда вы хотите запустить команду, не заботитесь о ее выводе и не хотите, чтобы скрипт Perl делал что-либо, пока команда не завершится.

#doesn't spawn a shell, arguments are passed as they are
system("command", "arg1", "arg2", "arg3");

или

#spawns a shell, arguments are interpreted by the shell, use only if you
#want the shell to do globbing (e.g. *.txt) for you or you want to redirect
#output
system("command arg1 arg2 arg3");

qx//или `` : запустить команду и перехватить ее STDOUT

Используется, qx//когда вы хотите запустить команду, записать то, что она пишет в STDOUT, и не хотите, чтобы скрипт Perl делал что-либо, пока команда не завершится.

#arguments are always processed by the shell

#in list context it returns the output as a list of lines
my @lines = qx/command arg1 arg2 arg3/;

#in scalar context it returns the output as one string
my $output = qx/command arg1 arg2 arg3/;

exec: заменить текущий процесс другим процессом.

Используйте execвместе с тем, forkкогда вы хотите запустить команду, не заботитесь о ее выводе и не хотите ждать ее возвращения. systemдействительно просто

sub my_system {
    die "could not fork\n" unless defined(my $pid = fork);
    return waitpid $pid, 0 if $pid; #parent waits for child
    exec @_; #replace child with new process
}

Вы также можете прочитать waitpidи perlipcруководства.

open: запустить процесс и создать канал для его STDIN или STDERR

Используется, openкогда вы хотите записать данные в STDIN процесса или прочитать данные из STDOUT процесса (но не одновременно в оба).

#read from a gzip file as if it were a normal file
open my $read_fh, "-|", "gzip", "-d", $filename
    or die "could not open $filename: $!";

#write to a gzip compressed file as if were a normal file
open my $write_fh, "|-", "gzip", $filename
    or die "could not open $filename: $!";

IPC :: Open2 : запустить процесс и создать канал для STDIN и STDOUT

Используйте, IPC::Open2когда вам нужно читать и писать в STDIN и STDOUT процесса.

use IPC::Open2;

open2 my $out, my $in, "/usr/bin/bc"
    or die "could not run bc";

print $in "5+6\n";

my $answer = <$out>;

IPC :: Open3 : запустить процесс и создать канал для STDIN, STDOUT и STDERR

используйте, IPC::Open3когда вам нужно захватить все три стандартных файловых дескриптора процесса. Я бы написал пример, но он работает в основном так же, как IPC :: Open2, но с несколько другим порядком аргументов и дескриптором третьего файла.

Позвольте мне сначала процитировать руководства:

perldoc exec () :

Функция exec выполняет системную команду и никогда не возвращается - используйте system вместо exec, если хотите, чтобы она вернулась

система perldoc () :

Выполняет те же действия, что и exec LIST, за исключением того, что сначала выполняется форк , а родительский процесс ожидает завершения дочернего процесса.

В отличие от exec и system , обратные кавычки дают не возвращаемое значение, а собранный STDOUT.

perldoc `String` :

Строка, которая (возможно) интерполируется и затем выполняется как системная команда с / bin / sh или ее эквивалентом. Подстановочные знаки оболочки, каналы и перенаправления будут выполнены. Собранный стандартный вывод команды возвращается ; стандартная ошибка не изменяется

Альтернативы:

В более сложных сценариях, когда вы хотите получить STDOUT, STDERR или код возврата, вы можете использовать хорошо известные стандартные модули, такие как IPC :: Open2 и IPC :: Open3 .

Пример:

use IPC::Open2;
my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'some', 'cmd', 'and', 'args');
waitpid( $pid, 0 );
my $child_exit_status = $? >> 8;

И наконец, IPC :: Run from CPAN также стоит посмотреть…

В чем разница между бэксиками Perl ( `) systemи exec?

exec -> exec "command"; ,
system -> system("command"); and 
backticks -> print `command`;

exec

execвыполняет команду и никогда не возобновляет сценарий Perl. Это для сценария, как returnутверждение для функции.

Если команда не найдена, execвозвращает false. Он никогда не возвращает true, потому что, если команда найдена, она никогда не возвращается вообще. Там также нет смысла возвращаться STDOUT, STDERRили статус завершения команды. Вы можете найти документацию об этом в perlfunc , потому что это функция.

Например:

#!/usr/bin/perl
print "Need to start exec command";
my $data2 = exec('ls');
print "Now END exec command";
print "Hello $data2\n\n";

В приведенном выше коде есть три printоператора, но из-за execвыхода из сценария выполняется только первый оператор печати. Кроме того, execвывод команды не присваивается какой-либо переменной.

Здесь только вы получаете вывод только первого printоператора и выполнения lsкоманды на стандартном выходе.

system

systemвыполняет команду, и ваш Perl-скрипт возобновляется после ее завершения. Возвращаемое значение является состоянием выхода команды. Вы можете найти документацию об этом в perlfunc .

Например:

#!/usr/bin/perl
print "Need to start system command";
my $data2 = system('ls');
print "Now END system command";
print "Hello $data2\n\n";

В приведенном выше коде есть три printутверждения. Когда сценарий возобновляется после systemкоманды, все три оператора печати выполняются.

Кроме того , результат работы system будет назначен data2, но присвоенное значение 0(выход код из ls).

Здесь вы получаете выходные данные первого printоператора, затем lsкоманды, а затем выходные данные двух последних printоператоров стандартного вывода.

backticks ( `)

Например system, включение команды в backticks выполняет эту команду, и ваш Perl-скрипт возобновляется после ее завершения. В отличие от system, возвращаемое значение имеет STDOUTкоманду. qx//эквивалентно тэгам Вы можете найти документацию об этом в perlop , потому что, в отличие от системы exec, она является оператором.

Например:

#!/usr/bin/perl
print "Need to start backticks command";
my $data2 = `ls`;
print "Now END system command";
print "Hello $data2\n\n";

В приведенном выше коде есть три printоператора, и все три выполняются. Выходные данные lsне собираются напрямую стандартизироваться, а присваиваются переменной data2и затем печатаются в последнем операторе печати.

Разница между «exec» и «system» заключается в том, что exec заменяет вашу текущую программу на «command», и НИКОГДА не возвращается в вашу программу. Система, с другой стороны, разветвляется и запускает «команду» и возвращает вам состояние завершения «команды», когда она завершена. Обратный тик запускает «команду», а затем возвращает строку, представляющую его стандарт (что бы оно ни выводило на экран)

Вы также можете использовать popen для запуска команд оболочки, и я думаю, что есть модуль оболочки - 'use shell', который дает вам прозрачный доступ к типичным командам оболочки.

Надеюсь, это прояснит это для вас.