Как написать ожидаемый скрипт для установки mariadb?

Окружающая среда: centos7 + mariadb5.5.64.
Позвольте мне показать информацию об установке на экране, когда запустить mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Я пишу сценарий ожидания автоматизации для установки mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Чтобы выполнить /usr/bin/expect secure.exp, я сталкиваюсь с ошибкой:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Бесполезно писать как ниже:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Та же ошибка:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Как исправить мой скрипт exp тогда?

Эти сценарии ожидают получения необязательного вывода ( timeout -1означает «нет тайм-аута»), и они могут отличать разные ответы, как этого требуют yum installи mysql_secure_installation. С помощью #!/bin/expect -fshebang сценарии могут выполняться, когда для них установлено значение chmod +x.

A) Для начала mariadb_yum.exp(требуется suили sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

Б) А потом mariadb_sec.exp(не требуется sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

В целях отладки - или для проверки ответа, можно запустить expectс уровнем журнала strace 4. Это, вероятно, настолько авторитетно, насколько это возможно для источника, когда речь идет о написании expectсценариев, так как оно хорошо отображает происходящее и, что наиболее важно, в каком порядке все происходит:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

Инструкция set exp_internal 1может использоваться, чтобы получить выходные данные для соответствия регулярному выражению.

Возможный источник путаницы может быть, когда вы порождаете процессы - как можно порождать несколько процессов на разных хостах, например. sshлокально, а затем yumи mysql_secure_installationудаленно. Добавлен $spawn_idв скрипт; нижний один closeвызов может быть излишним, так как это уже EOF(просто , чтобы показать , как spawnи closeпроцессы):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Вывод: mariadb_sec.expсценарий, вероятно, может быть улучшен в дальнейшем, например. когда сначала не посылают пароль и видят, что происходит, - затем отправляют пароль ERROR 1045(когда пароль уже был установлен ранее). Можно предположить, что необходимо установить пароль, когда сервер только что был установлен (за исключением того, что он yum reinstallдает тот же результат). Просто не было пустого контейнера CentOS для тестирования всех случаев. Если не запускать в rootоболочке, то для автоматизации этого процесса от установки до после установки потребуется передача обоих типов паролей в один сценарий.

Вероятно, стоит отметить, что на GCE sudoне будет запрашивать пароль; действительно, существуют незначительные различия в зависимости от среды, поскольку эти изображения контейнеров CentOS ведут себя по-разному. В этом случае (так как нет suобнаружения контейнера или изображения на месте), mariadb_yum.expсценарий может застрять на 30несколько секунд, а затем продолжить.

Наиболее авторитетными источниками, которые я могу предложить, являются expectруководство, написанное Don Libes @ NIST и руководство TCL / TK expect, а также проект SourceForge, который по совпадению называется expect.

Мало того, что квадратные скобки используются для подстановки команд, они также являются специальными для шаблонов глобуса .

Вы можете использовать -exactпереключатель, избегая квадратных скобок в кавычках:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Или используйте фигурные скобки вместо кавычек:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

К вашему сведению, вы можете сгенерировать сценарий ожидания, используя autoexpect:

autoexpect ./mysql_secure_installation

Это сгенерирует ожидаемый скрипт, вызываемый script.expв вашем текущем рабочем каталоге.