Выражение последовательности двойного суммирования в раку

Как выразить последовательность двойного суммирования двойной переменной в Perl 6?

Для примера двойной переменной последовательности двойного суммирования смотрите это

Он должен быть выражен как есть, то есть без математического сведения двойного суммирования в одно суммирование. Спасибо.

X(Кросс - оператор) и [+](уменьшение metaoperator [ ]с аддитивным оператором +) делают это на удивление легко:

Чтобы представить ¹ двойное суммирование x³ _{x  = 1} ∑⁵ _{y  = 1} 2x + y , вы можете сделать следующее:

  [+] do for 1..3 X 1..5 -> ($x, $y) { 2 * $x + $y }
#        for 1..3 X 1..5                             # loop cross values
#                        -> ($x, $y)                 # plug into x/y
#                                    { 2 * $x + $y } # calculate each iteration
#     do                                             # collect loop return vals 
# [+]                                                # sum them all

Если вы хотите создать subдля этого, вы можете написать его следующим образом ²

sub ΣΣ (
    Int $aₒ, Int $aₙ,     # to / from for the outer
    Int $bₒ, Int $bₙ,     # to / from for the inner
    &f where .arity = 2   # 'where' clause guarantees only two params
) {
  [+] do for $aₒ..$aₙ X $bₒ..$bₙ -> ($a, $b) { &f(a,b) }
}

say ΣΣ 1,3, 1,5, { 2 * $^x + $^y }

Или даже упростить вещи больше

sub ΣΣ (
    Iterable \a,            # outer values
    Iterable \b,            # inner values
    &f where .arity = 2) {  # ensure only two parameters
  [+] do f(|$_) for a X b
}

# All of the following are equivalent
say ΣΣ 1..3, 1..5, -> $x, $y { 2 * $x  + $y  }; # Anonymous block
say ΣΣ 1..3, 1..5,           { 2 * $^x + $^y }; # Alphabetic args
say ΣΣ 1..3, 1..5,             2 *  *  +  *   ; # Overkill, but Whatever ;-) 

Обратите внимание, что, набрав его, мы можем гарантировать, что диапазоны будут переданы, но, введя его Iterableвместо того, Rangeчтобы допустить более интересные последовательности суммирования, например, ΣΣ (1..∞).grep(*.is-prime)[^99], 1..10, { … }которые позволят нам использовать последовательность первых 100 простых чисел.

На самом деле, если бы мы действительно хотели, мы могли бы пойти за борт и разрешить произвольный оператор суммирования глубины, который проще всего сделать, переместив функцию влево:

sub ΣΣ (
    &function, 
    **@ranges where                # slurp in the ranges
        .all   ~~ Iterable &&      # make sure they're Iterables 
        .elems == &function.arity  # one per argument in the function
) {
  [+] do function(|$_) for [X] @ranges;
};

Точно так же, как [+]суммирует все значения нашей f()функции, [X]итеративно вычисляет кросс, например, [X] 0..1, 3..4, 5..6сначала делает 0..1 X 3..4или (0,3),(0,4),(1,3),(1,4), а затем делает (0,3),(0,4),(1,3),(1,4) X 5..6или (0,3,5),(0,4,5),(1,3,5),(1,4,5),(0,3,6),(0,4,6),(1,3,6),(1,4,6).

^{1. Извините, ТАК не позволяет мне делать LaTeX, но вы должны понять. 2. Да, я знаю, что это буква O, а не ноль, номера индексов обычно не являются допустимыми идентификаторами, но вы можете использовать Slang :: Subscripts, чтобы включить их.}