Как разбить строку в Haskell?

Есть ли стандартный способ разбить строку в Haskell?

linesи wordsотлично работает от разделения на пробел или новую строку, но наверняка есть стандартный способ разделения на запятую?

Я не смог найти его в Google.

Чтобы быть конкретным, я ищу что-то, где split "," "my,comma,separated,list"возвращается ["my","comma","separated","list"].

Существует пакет для этого, который называется сплит .

cabal install split

Используйте это так:

ghci> import Data.List.Split
ghci> splitOn "," "my,comma,separated,list"
["my","comma","separated","list"]

Он поставляется с множеством других функций для разделения на совпадающие разделители или с несколькими разделителями.

Помните, что вы можете посмотреть определение функций Prelude!

http://www.haskell.org/onlinereport/standard-prelude.html

Глядя там, определение wordsесть,

words   :: String -> [String]
words s =  case dropWhile Char.isSpace s of
                      "" -> []
                      s' -> w : words s''
                            where (w, s'') = break Char.isSpace s'

Итак, измените его на функцию, которая принимает предикат:

wordsWhen     :: (Char -> Bool) -> String -> [String]
wordsWhen p s =  case dropWhile p s of
                      "" -> []
                      s' -> w : wordsWhen p s''
                            where (w, s'') = break p s'

Тогда назовите это с любым предикатом, который вы хотите!

main = print $ wordsWhen (==',') "break,this,string,at,commas"

Если вы используете Data.Text, есть splitOn:

http://hackage.haskell.org/packages/archive/text/0.11.2.0/doc/html/Data-Text.html#v:splitOn

Это встроено в платформу Haskell.

Так, например:

import qualified Data.Text as T
main = print $ T.splitOn (T.pack " ") (T.pack "this is a test")

или:

{-# LANGUAGE OverloadedStrings #-}

import qualified Data.Text as T
main = print $ T.splitOn " " "this is a test"

В модуле Text.Regex (часть платформы Haskell) есть функция:

splitRegex :: Regex -> String -> [String]

которая разбивает строку на основе регулярного выражения. API можно найти на сайте Hackage .

Использование Data.List.Split, которое использует split:

[me@localhost]$ ghci
Prelude> import Data.List.Split
Prelude Data.List.Split> let l = splitOn "," "1,2,3,4"
Prelude Data.List.Split> :t l
l :: [[Char]]
Prelude Data.List.Split> l
["1","2","3","4"]
Prelude Data.List.Split> let { convert :: [String] -> [Integer]; convert = map read }
Prelude Data.List.Split> let l2 = convert l
Prelude Data.List.Split> :t l2
l2 :: [Integer]
Prelude Data.List.Split> l2
[1,2,3,4]

Попробуй это:

import Data.List (unfoldr)

separateBy :: Eq a => a -> [a] -> [[a]]
separateBy chr = unfoldr sep where
  sep [] = Nothing
  sep l  = Just . fmap (drop 1) . break (== chr) $ l

Работает только для одного символа, но должен легко расширяться.

Не импортируя ничего в качестве прямой замены одного символа на пробел, целевым разделителем wordsявляется пробел. Что-то вроде:

words [if c == ',' then ' ' else c|c <- "my,comma,separated,list"]

или

words let f ',' = ' '; f c = c in map f "my,comma,separated,list"

Вы можете превратить это в функцию с параметрами. Вы можете исключить параметр символьного соответствия для моего соответствия многим, как в:

 [if elem c ";,.:-+@!$#?" then ' ' else c|c <-"my,comma;separated!list"]

split :: Eq a => a -> [a] -> [[a]]
split d [] = []
split d s = x : split d (drop 1 y) where (x,y) = span (/= d) s

Например

split ';' "a;bb;ccc;;d"
> ["a","bb","ccc","","d"]

Один конечный разделитель будет удален:

split ';' "a;bb;ccc;;d;"
> ["a","bb","ccc","","d"]

Я начал изучать Haskell вчера, так что поправьте меня, если я ошибаюсь, но:

split :: Eq a => a -> [a] -> [[a]]
split x y = func x y [[]]
    where
        func x [] z = reverse $ map (reverse) z
        func x (y:ys) (z:zs) = if y==x then 
            func x ys ([]:(z:zs)) 
        else 
            func x ys ((y:z):zs)

дает:

*Main> split ' ' "this is a test"
["this","is","a","test"]

или, может быть, вы хотели

*Main> splitWithStr  " and " "this and is and a and test"
["this","is","a","test"]

который будет:

splitWithStr :: Eq a => [a] -> [a] -> [[a]]
splitWithStr x y = func x y [[]]
    where
        func x [] z = reverse $ map (reverse) z
        func x (y:ys) (z:zs) = if (take (length x) (y:ys)) == x then
            func x (drop (length x) (y:ys)) ([]:(z:zs))
        else
            func x ys ((y:z):zs)

Я не знаю, как добавить комментарий к ответу Стива, но я бы хотел порекомендовать
  документацию по библиотекам GHC ,
и там, в
  частности, функции Sublist в Data.List

Что гораздо лучше в качестве справки, чем просто чтение простого отчета на Haskell.

Как правило, ее следует решить также с помощью правила о том, когда создавать новый подсписок для подачи.

В дополнение к эффективным и заранее созданным функциям, приведенным в ответах, я добавлю свои собственные, которые просто являются частью моего набора функций Haskell, которые я писал для изучения языка в свое свободное время:

-- Correct but inefficient implementation
wordsBy :: String -> Char -> [String]
wordsBy s c = reverse (go s []) where
    go s' ws = case (dropWhile (\c' -> c' == c) s') of
        "" -> ws
        rem -> go ((dropWhile (\c' -> c' /= c) rem)) ((takeWhile (\c' -> c' /= c) rem) : ws)

-- Breaks up by predicate function to allow for more complex conditions (\c -> c == ',' || c == ';')
wordsByF :: String -> (Char -> Bool) -> [String]
wordsByF s f = reverse (go s []) where
    go s' ws = case ((dropWhile (\c' -> f c')) s') of
        "" -> ws
        rem -> go ((dropWhile (\c' -> (f c') == False)) rem) (((takeWhile (\c' -> (f c') == False)) rem) : ws)

Решения по крайней мере рекурсивные, поэтому они не повлекут за собой переполнение стека.

Пример в ghci:

>  import qualified Text.Regex as R
>  R.splitRegex (R.mkRegex "x") "2x3x777"
>  ["2","3","777"]

Я нахожу это проще для понимания:

split :: Char -> String -> [String]
split c xs = case break (==c) xs of 
  (ls, "") -> [ls]
  (ls, x:rs) -> ls : split c rs