Как проверить параметр командной строки в файле «.bat»?

Моя ОС - Windows Vista. Мне нужен файл «.bat», в котором мне нужно проверить, вводит ли пользователь какой-либо параметр командной строки или нет. Если да, то если параметр равен, -bто я что-то сделаю, в противном случае я отмечу «Недействительный ввод». Если пользователь не вводит никаких параметров командной строки, я что-то сделаю. Я создал следующий файл .bat. Он работает для случаев -bи не равнозначен -b- но не работает, когда пользователь не передает какой-либо параметр командной строки.

Я всегда получаю ошибку:

GOTO was unexpected at this time.

Может ли кто-нибудь сказать мне, что я здесь делаю не так?

ECHO OFF
CLS
ECHO.

IF [%1]==[/?] GOTO BLANK

IF %1=="-b" GOTO SPECIFIC

IF NOT %1=="-b" GOTO UNKNOWN

:SPECIFIC

ECHO SPECIFIC

GOTO DONE

:BLANK

ECHO No Parameter

GOTO DONE

:UNKNOWN

ECHO Unknown Option

GOTO DONE

:DONE

ECHO Done!

Вам нужно проверить, не заполнен ли параметр: if "%~1"=="" goto blank

Как только вы это сделаете, включите if / else -b: if "%~1"=="-b" (goto specific) else goto unknown

Заключение параметров в кавычки упрощает проверку таких вещей, как пустые / пустые / отсутствующие параметры. «~» гарантирует удаление двойных кавычек, если они были в аргументе командной строки.

Посмотрите http://ss64.com/nt/if.html для ответа; команда такая IF [%1]==[] GOTO NO_ARGUMENTили похожая.

Короткий ответ - используйте квадратные скобки:

if [%1]==[] goto :blank

или (если вам нужно обработать аргументы в кавычках, см. Правка ниже):

if [%~1]==[] goto :blank

Зачем? вы можете спросить. Ну, как сказал Джереми Уиллкок: http://ss64.com/nt/if.html - они это используют! Хорошо, а что не так с цитатами?

И снова короткий ответ: они «волшебные» - иногда двойные (двойные) кавычки преобразуются в одинарные (двойные) кавычки. И для начала они должны совпадать.

Рассмотрим этот небольшой сценарий:

@rem argq.bat
@echo off

:loop 
if "%1"=="" goto :done
echo %1
shift
goto :loop

:done
echo Done.

Давайте протестируем это:

C:\> argq bla bla
bla
bla
Done.

Кажется, работает. А теперь перейдем на вторую передачу:

C:\> argq "bla bla"
bla""=="" was unexpected at this time.

Boom This не оценивается как истина, ни как не оценивается как ложь. Сценарий УМЕР. Если вы должны были выключить реактор где-нибудь в будущем, ну - не повезло. Теперь ты умрешь, как Гарри Даглиан.

Вы можете подумать - хорошо, аргументы не могут содержать кавычек. Если они это сделают, это произойдет. Неправильно Вот какое утешение:

C:\> argq ""bla bla""
""bla
bla""
Done.

О да. Не волнуйтесь - иногда это будет работать.

Попробуем другой сценарий:

@rem args.bat
@echo off

:loop 
if [%1]==[] goto :done
echo %1
shift
goto :loop

:done
echo Done.

Вы можете проверить себя, что он работает нормально для вышеуказанных случаев. Это логично - кавычки не имеют отношения к скобкам, так что никакой магии здесь нет. Но как насчет того, чтобы приправить аргументы скобками?

D:\>args ]bla bla[
]bla
bla[
Done.

D:\>args [bla bla]
[bla
bla]
Done.

Не повезло. Скобки просто не могут заглушить cmd.exeпарсер.

Вернемся на минутку к злым цитатам. Проблема была там, когда спор закончился цитатой:

D:\>argq "bla1 bla2"
bla2""=="" was unexpected at this time.

Что, если я пройду только:

D:\>argq bla2"
The syntax of the command is incorrect.

Скрипт вообще не запускается. То же самое для args.bat:

D:\>args bla2"
The syntax of the command is incorrect.

Но что я получаю, когда количество "-символов "совпадает" (то есть - четно), в таком случае:

D:\>args bla2" "bla3
bla2" "bla3
Done.

ПРИЯТНО - Надеюсь, вы узнали кое-что о том, как .batфайлы разделяют аргументы командной строки (ПОДСКАЗКА: * Это не совсем так, как в bash). Приведенный выше аргумент содержит пробел. Но кавычки не удаляются автоматически.

А argq? Как он на это реагирует? Как и ожидалось:

D:\>argq bla2" "bla3
"bla3"=="" was unexpected at this time.

Так что подумайте, прежде чем говорить: «Знаете что? Просто используйте кавычки. [Потому что, на мой взгляд, это выглядит лучше]».

редактировать

Недавно были комментарии по поводу этого ответа - ну, квадратные скобки «не могут обрабатывать» передачу цитируемых аргументов и обработку их так, как если бы они не цитировались.

Синтаксис:

if "%~1"=="" (...)

Это не недавно обнаруженное достоинство двойных кавычек, а отображение изящной функции удаления кавычек из переменной аргумента, если первый и последний символы являются двойными кавычками.

Эта «технология» работает и с квадратными скобками:

if [%~1]==[] (...)

Было полезно указать на это, поэтому я также поддержал новый ответ.

Наконец, любители двойных кавычек, ""существует ли в вашей книге аргумент такой формы или он пустой? Просто спрашиваю;)

В дополнение к другим ответам, на которые я подписываюсь, вы можете рассмотреть возможность использования /Iпереключателя IFкоманды.

... переключатель / I, если он указан, говорит о необходимости сравнения строк без учета регистра.

это может быть полезно, если вы хотите дать пользователям гибкость при указании параметров без учета регистра.

IF /I "%1"=="-b" GOTO SPECIFIC

Вы сравниваете строки. Если аргументы опущены, %1расширяется до пустого значения, поэтому команды становятся, IF =="-b" GOTO SPECIFICнапример, (что является синтаксической ошибкой). Заключите строки в кавычки (или квадратные скобки).

REM this is ok
IF [%1]==[/?] GOTO BLANK

REM I'd recommend using quotes exclusively
IF "%1"=="-b" GOTO SPECIFIC

IF NOT "%1"=="-b" GOTO UNKNOWN

Собственно, во всех остальных ответах есть недостатки. Самый надежный способ:

IF "%~1"=="-b" (GOTO SPECIFIC) ELSE (GOTO UNKNOWN)

Детальное объяснение:

Использование "%1"=="-b"приведет к сбою, если передать аргумент с пробелами и кавычками. Это наименее надежный метод.

IF "%1"=="-b" (GOTO SPECIFIC) ELSE (GOTO UNKNOWN)

C:\> run.bat "a b"

b""=="-b" was unexpected at this time.

Использование [%1]==[-b]лучше, потому что оно не приведет к сбою из-за пробелов и кавычек, но не будет соответствовать, если аргумент заключен в кавычки.

IF [%1]==[-b] (GOTO SPECIFIC) ELSE (GOTO UNKNOWN)

C:\> run.bat "-b"

(does not match, and jumps to UNKNOWN instead of SPECIFIC)

Использование "%~1"=="-b"- самое надежное. %~1удалит окружающие кавычки, если они существуют. Таким образом, он работает с кавычками и без них, а также без аргументов.

IF "%~1"=="-b" (GOTO SPECIFIC) ELSE (GOTO UNKNOWN)

C:\> run.bat
C:\> run.bat -b
C:\> run.bat "-b"
C:\> run.bat "a b"

(all of the above tests work correctly)

В последнее время я боролся с реализацией сложных переключателей параметров в пакетном файле, поэтому вот результат моего исследования. Ни один из предоставленных ответов не является полностью безопасным, примеры:

"%1"=="-?" не будет соответствовать, если параметр заключен в кавычки (необходим для имен файлов и т. д.), или будет аварийно завершен, если параметр заключен в кавычки и имеет пробелы (снова часто встречается в именах файлов)

@ECHO OFF
SETLOCAL
echo.
echo starting parameter test...
echo.
rem echo First parameter is %1
if "%1"=="-?" (echo Condition is true, param=%1) else (echo Condition is false, param=%1)
C:\>test.bat -?

starting parameter test...

Condition is true, param=-?

C:\>test.bat "-?"

starting parameter test...

Condition is false, param="-?"

Любая комбинация с квадратными скобками [%1]==[-?]или [%~1]==[-?]не удастся, если в параметре есть пробелы в кавычках:

@ECHO OFF
SETLOCAL 
echo.
echo starting parameter test...
echo.
echo First parameter is %1
if [%~1]==[-?] (echo Condition is true, param=%1) else (echo Condition is false, param=%1)

C:\>test.bat "long file name"

starting parameter test...

First parameter is "long file name"
file was unexpected at this time.

Предлагаемое самое безопасное решение "%~1"=="-?"приведет к сбою со сложным параметром, который включает текст вне кавычек и текст с пробелами внутри кавычек:

@ECHO OFF
SETLOCAL 
echo.
echo starting parameter test...
echo.
echo First parameter is %1
if "%~1"=="-?" (echo Condition is true, param=%1) else (echo Condition is false, param=%1)

C:\>test.bat -source:"long file name"

starting parameter test...

First parameter is -source:"long file name"
file was unexpected at this time.

Единственный способ обеспечить охват всех вышеупомянутых сценариев - использовать EnableDelayedExpansion и передавать параметры по ссылке (а не по значению) с использованием переменных. Тогда даже самый сложный сценарий будет работать нормально:

@ECHO OFF
SETLOCAL EnableDelayedExpansion
echo.
echo starting parameter test...
echo.
echo First parameter is %1
:: we assign the parameter to a variable to pass by reference with delayed expansion
set "var1=%~1"
echo var1 is !var1!
:: we assign the value to compare with to a second variable to pass by reference with delayed expansion
set "var2=-source:"c:\app images"\image.png"
echo var2 is !var2!
if "!var1!"=="!var2!" (echo Condition is true, param=!var1!) else (echo Condition is false, param=!var1!)
C:\>test.bat -source:"c:\app images"\image.png

starting parameter test...

First parameter is -source:"c:\app images"\image.png
var1 is -source:"c:\app images"\image.png
var2 is -source:"c:\app images"\image.png
Condition is true, param=-source:"c:\app images"\image.png

C:\>test.bat -source:"c:\app images"\image1.png

starting parameter test...

First parameter is -source:"c:\app images"\image1.png
var1 is -source:"c:\app images"\image1.png
var2 is -source:"c:\app images"\image.png
Condition is false, param=-source:"c:\app images"\image1.png

C:\>test.bat -source:"c:\app images\image.png"

starting parameter test...

First parameter is -source:"c:\app images\image.png"
var1 is -source:"c:\app images\image.png"
var2 is -source:"c:\app images"\image.png
Condition is false, param=-source:"c:\app images\image.png"

В пакете Windows для этого есть ключевое слово DEFINED.

IF DEFINED %~1 foo
IF NOT DEFINED %~1 bar