Vim: создание родительских каталогов при сохранении

Если я вызываю, vim foo/bar/somefileно foo/barеще не существует, Vim отказывается сохранять.

Я знаю, что могу переключиться на оболочку или сделать это :!mkdir foo/barиз Vim, но я ленив :) Есть ли способ заставить Vim делать это автоматически при сохранении буфера?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Обратите внимание на условия: expand("<afile>")!~#'^\w\+:/'запретит vim создавать каталоги для файлов, таких как ftp://*и !isdirectoryпредотвратит дорогостоящий вызов mkdir.

Обновление : немного лучшее решение, которое также проверяет непустой тип буфера и использует mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Основываясь на предложениях по моему вопросу, вот что у меня получилось:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Это определяет :Wкоманду. В идеале я хотел бы иметь все :w!, :wq, :wq!, и :wallт.д. работаю так же, но я не уверен , если это возможно без в основном реализовав их все пользовательские функции.

Я добавил это в свой ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Если мне нужно создать каталог, в котором я нахожусь, я :mk.набираю текст, и он заменяет его на «! Mkdir -p / path / to / my / file /» и позволяет мне просмотреть команду перед ее вызовом.

Я :saveas!создал каталог, если он отсутствует: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Этот код предложит вам создать каталог :wили просто сделать это с помощью :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Думаю, мне удалось сделать это в трех строках, объединив то, что другие говорят по этому поводу.

Кажется, это помогает:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Он пытается автоматически создать папку при сохранении буфера. Если случится что-нибудь плохое (например, проблемы с правами доступа), он просто отключится и даст возможность записать файл не удастся.

Если кто-то видит очевидные недостатки, оставьте комментарий. Я не очень разбираюсь в vimscript.

РЕДАКТИРОВАТЬ: Заметки благодаря ZyX

• Это не сработает, если в ваших папках есть пробелы (по-видимому, они неправильно экранированы или что-то в этом роде)
• Или если вы делаете псевдофайлы.
• Или если вы используете vimrc.
• Но сынок, это недолго.