Замените табуляцию пробелами в vim

Я хотел бы преобразовать табуляцию в пробелы в gVim. Я добавил следующую строку в мой _vimrc:

set tabstop=2

Это работает, чтобы остановиться на двух пробелах, но все равно похоже, что вставлена ​​одна клавиша табуляции (я пытался использовать клавишу h для подсчета пробелов впоследствии).

Я не уверен, что мне нужно сделать, чтобы gVim преобразовывал табуляцию в пробелы?

IIRC, что-то вроде:

set tabstop=2 shiftwidth=2 expandtab

должен сделать свое дело. Если у вас уже есть вкладки, добавьте к ним хороший глобальный RE, чтобы заменить их на двойные пробелы.

После того, как вы получили расширение в соответствии с другими ответами, чрезвычайно удобный способ конвертировать существующие файлы в соответствии с вашими новыми настройками:

:retab

Он будет работать с текущим буфером.

Пытаться

set expandtab

для мягких вкладок.

Чтобы исправить уже существующие вкладки:

:%s/\t/  /g

Я использовал два пробела, так как вы уже установили табуляцию на 2 пробела.

Это сработало для меня:

вы можете увидеть вкладки с первым делом это:

:set list

затем, чтобы можно было заменить вкладки, сделайте это:

:set expandtab

тогда

:retab

теперь все вкладки заменены пробелами, после чего вы можете вернуться к обычному просмотру следующим образом:

:set nolist

gg=G переопределяет весь файл и удаляет большинство, если не все вкладки, которые я получаю в файлах от коллег.

Добавьте следующие строки в ваш .vimrc

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

Откройте файл в vim и нажмите F2. Вкладки будут преобразованы в 4 пробела, и файл будет сохранен автоматически.

Если вы хотите оставить \tравным 8 пробелов, подумайте об установке:

   set softtabstop=2 tabstop=8 shiftwidth=2

Это даст вам два пробела на одно <TAB>нажатие, но фактический \tв вашем коде все равно будет отображаться как 8 символов.

Это заставило меня работать:

:set tabstop=2 shiftwidth=2 expandtab | retab

первый поиск вкладок в вашем файле: / ^ I: установить expandtab: retab

будет работать.

В этой статье есть отличный скрипт vimrc для обработки вкладок + пробелов и преобразования между ними.

Эти команды предоставляются:

Space2Tab Преобразование пробелов во вкладки, только в отступах.

Tab2Space Преобразование вкладок в пробелы, только в отступах.

RetabIndent Выполнить Space2Tab (если установлено 'expandtab') или Tab2Space (в противном случае).

Каждая команда принимает аргумент, который определяет количество пробелов в столбце табуляции. По умолчанию используется настройка «tabstop».

Источник: http://vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

Это помогло мне немного больше, чем ответы здесь, когда я впервые начал искать решение.

expandутилита Unix для преобразования табуляции в пробелы Если вы не хотите setничего делать в vim, вы можете использовать команду оболочки из vim:

:!% expand -t8