Как связать программу C ++ с Boost с помощью CMake

Как должен выглядеть мой файл CMake для связывания моей программы с библиотекой Boost в Ubuntu?

Ошибки, отображаемые во время работы make:

main.cpp:(.text+0x3b): undefined reference to `boost::program_options::options_description::m_default_line_length'

Главный файл действительно прост:

#include <boost/program_options/options_description.hpp>
#include <boost/program_options/option.hpp>
using namespace std;
#include <iostream>

namespace po = boost::program_options;

int main(int argc, char** argv) {

    po::options_description desc("Allowed options");
    desc.add_options()
        ("help", "produce help message")
        ;

    return 0;
}

Мне это удалось. Единственные строки, которые я добавил в свои файлы CMake, были:

target_link_libraries(
my_target_file
${Boost_PROGRAM_OPTIONS_LIBRARY}
)

В CMake вы можете использовать find_packageдля поиска нужных вам библиотек. Обычно FindBoost.cmakeвместе с установкой CMake.

Насколько я помню, он будет установлен /usr/share/cmake/Modules/вместе с другими скриптами поиска для общих библиотек. Вы можете просто проверить документацию в этом файле для получения дополнительной информации о том, как это работает.

Пример из моей головы:

FIND_PACKAGE( Boost 1.40 COMPONENTS program_options REQUIRED )
INCLUDE_DIRECTORIES( ${Boost_INCLUDE_DIR} )

ADD_EXECUTABLE( anyExecutable myMain.cpp )

TARGET_LINK_LIBRARIES( anyExecutable LINK_PUBLIC ${Boost_LIBRARIES} )

Надеюсь, этот код поможет.

• Вот официальная документация по FindBoost.cmake .
• И собственно FindBoost.cmake (размещенный на GitHub)

Вот моя конфигурация:

cmake_minimum_required(VERSION 2.8)
set(Boost_INCLUDE_DIR /usr/local/src/boost_1_46_1)
set(Boost_LIBRARY_DIR /usr/local/src/boost_1_46_1/stage/lib)
find_package(Boost COMPONENTS system filesystem REQUIRED)
include_directories(${Boost_INCLUDE_DIR})
link_directories(${Boost_LIBRARY_DIR})

add_executable(main main.cpp)
target_link_libraries( main ${Boost_LIBRARIES} )

Адаптируя ответ @MOnsDaR для современного синтаксиса CMake с импортированными целями, это будет:

find_package(Boost 1.40 COMPONENTS program_options REQUIRED)

add_executable(anyExecutable myMain.cpp)

target_link_libraries(anyExecutable Boost::program_options)

Обратите внимание, что указывать подключаемые каталоги вручную не обязательно, поскольку об этом уже позаботились с помощью импортированной цели Boost::program_options.

Какая библиотека Boost? Многие из них являются чистыми шаблонами и не требуют привязки.

Теперь, когда на самом деле показан конкретный пример, который говорит нам, что вам нужны параметры программы Boost (и даже больше сообщило нам, что вы используете Ubuntu), вам нужно сделать две вещи:

1. Установите, libboost-program-options-devчтобы вы могли ссылаться на него.
2. Скажите cmakeссылку против libboost_program_options.

Я в основном использую Makefiles, так что вот прямое использование командной строки:

$ g++ boost_program_options_ex1.cpp -o bpo_ex1 -lboost_program_options
$ ./bpo_ex1
$ ./bpo_ex1 -h
$ ./bpo_ex1 --help
$ ./bpo_ex1 -help
$

Кажется, это не так уж много.

Для CMake вам нужно добавить boost_program_options в список библиотек, а IIRC это делается через SET(liblist boost_program_options)ваш CMakeLists.txt.

Двумя способами, используя системный путь установки по умолчанию, обычно /usr/lib/x86_64-linux-gnu/:

find_package(Boost REQUIRED regex date_time system filesystem thread graph)
include_directories(${BOOST_INCLUDE_DIRS})
message("boost lib: ${Boost_LIBRARIES}")
message("boost inc:${Boost_INCLUDE_DIR}")

add_executable(use_boost use_boost.cpp)
target_link_libraries(use_boost
        ${Boost_LIBRARIES}
        )

Если вы устанавливаете Boost в локальный каталог или выбираете локальную установку вместо системной, вы можете сделать это следующим образом:

set( BOOST_ROOT "/home/xy/boost_install/lib/" CACHE PATH "Boost library path" )
set( Boost_NO_SYSTEM_PATHS on CACHE BOOL "Do not search system for Boost" )

find_package(Boost REQUIRED regex date_time system filesystem thread graph)
include_directories(${BOOST_INCLUDE_DIRS})
message("boost lib: ${Boost_LIBRARIES}, inc:${Boost_INCLUDE_DIR}")

add_executable(use_boost use_boost.cpp)
target_link_libraries(use_boost
        ${Boost_LIBRARIES}
        )

Обратите внимание, что в приведенном выше каталоге /home/xy/boost_install/lib/я устанавливаю Boost:

xy@xy:~/boost_install/lib$ ll -th
total 16K
drwxrwxr-x 2 xy xy 4.0K May 28 19:23 lib/
drwxrwxr-x 3 xy xy 4.0K May 28 19:22 include/

xy@xy:~/boost_install/lib$ ll -th lib/
total 57M
drwxrwxr-x 2 xy xy 4.0K May 28 19:23 ./
-rw-rw-r-- 1 xy xy 2.3M May 28 19:23 libboost_test_exec_monitor.a
-rw-rw-r-- 1 xy xy 2.2M May 28 19:23 libboost_unit_test_framework.a
.......

xy@xy:~/boost_install/lib$ ll -th include/
total 20K
drwxrwxr-x 110 xy xy  12K May 28 19:22 boost/

Если вас интересует, как использовать локально установленный Boost, вы можете увидеть этот вопрос. Как мне заставить CMake найти мою альтернативную установку Boost? .

Вот мой вывод:

cmake_minimum_required(VERSION 3.15)

project(TryOuts LANGUAGES CXX)

find_package(Boost QUIET REQUIRED COMPONENTS program_options)

if(NOT Boost_FOUND)
    message(FATAL_ERROR "Boost Not found")
endif()

add_executable(helloworld main.cpp)

target_link_libraries(helloworld PUBLIC Boost::program_options)