Псевдоним команды в vim

Vim мой любимый текстовый редактор, когда я программирую, и поэтому я всегда сталкиваюсь с особенно раздражающей проблемой.

Часто, когда мне нужно быстро сохранить буфер и перейти к другой задаче, я обычно выполняю

:w

Тем не менее, мне - как кажется, более 50% времени - всегда удается извлечь из этого выгоду :w. Естественно, vim кричит на меня, потому что Wэто неверная команда

E492: Not an editor command: W

Мой вопрос, как один двоеточие-команд псевдонима в Vim . В частности, вы могли бы служить примером , как псевдоним Wдля w.

Мне известен процесс сопоставления ключей с определенными командами . К сожалению, это не то, что я ищу.

Чтобы оставить завершение без изменений, попробуйте использовать

cnoreabbrev W w

, он будет заменен Wв командной строке на w, но только если за ним не следует и не предшествует символ слова, поэтому :W<CR>он будет заменен на :w<CR>, но :Writeне будет. (Обратите внимание, что это влияет на любые совпадающие команды, в том числе те, которые вы не ожидаете, например, команда :saveas W Zбудет заменена :saveas w Z, поэтому будьте осторожны с этим.)

Обновить

Вот как бы я написал это сейчас :

cnoreabbrev <expr> W ((getcmdtype() is# ':' && getcmdline() is# 'W')?('w'):('W'))

Как функция:

fun! SetupCommandAlias(from, to)
  exec 'cnoreabbrev <expr> '.a:from
        \ .' ((getcmdtype() is# ":" && getcmdline() is# "'.a:from.'")'
        \ .'? ("'.a:to.'") : ("'.a:from.'"))'
endfun
call SetupCommandAlias("W","w")

Это проверяет, что тип команды :и команда W, так что это безопаснее, чем просто cnoreabbrev W w.

При дополнительном поиске я обнаружил, что кто-то задал почти тот же вопрос, что и я.

:command <AliasName> <string of command to be aliased>

сделает свое дело.

Помните, что, как указывает Ричо , команда пользователя должна начинаться с заглавной буквы.

Я считаю, что сопоставление ;ключа :было бы лучшим решением и сделало бы вас более продуктивным для ввода других команд.

nnoremap ; :
vnoremap ; :

Лучшее решение заключается в написании пользовательской функции для обработки сокращений, которые имеют место только в начале панели команд.

Для этого добавьте следующий файл vimrc или куда-либо еще.

" cabs - less stupidity                                                      {{{
fu! Single_quote(str)
  return "'" . substitute(copy(a:str), "'", "''", 'g') . "'"
endfu
fu! Cabbrev(key, value)
  exe printf('cabbrev <expr> %s (getcmdtype() == ":" && getcmdpos() <= %d) ? %s : %s',
    \ a:key, 1+len(a:key), Single_quote(a:value), Single_quote(a:key))
endfu
"}}}

" use this custom function for cabbrevations. This makes sure that they only
" apply in the beginning of a command. Else we might end up with stuff like
"   :%s/\vfoo/\v/\vbar/
" if we happen to move backwards in the pattern.

" For example:
call Cabbrev('W', 'w')

Несколько полезных сокращений из исходного материала, где я нашел этот материал:

call Cabbrev('/',   '/\v')
call Cabbrev('?',   '?\v')

call Cabbrev('s/',  's/\v')
call Cabbrev('%s/', '%s/\v')

call Cabbrev('s#',  's#\v')
call Cabbrev('%s#', '%s#\v')

call Cabbrev('s@',  's@\v')
call Cabbrev('%s@', '%s@\v')

call Cabbrev('s!',  's!\v')
call Cabbrev('%s!', '%s!\v')

call Cabbrev('s%',  's%\v')
call Cabbrev('%s%', '%s%\v')

call Cabbrev("'<,'>s/", "'<,'>s/\v")
call Cabbrev("'<,'>s#", "'<,'>s#\v")
call Cabbrev("'<,'>s@", "'<,'>s@\v")
call Cabbrev("'<,'>s!", "'<,'>s!\v")

Может быть, вы хотите отобразить одну из ваших функциональных клавиш (F1..F12) на: w? Затем поместите это в ваш .vimrc:

noremap  <f1> :w<return>
inoremap <f1> <c-o>:w<return>

(Ctrl-O в режиме вставки временно переключается в нормальный режим).

Предположим, вы хотите добавить псевдоним для команды tabnew в gvim. Вы можете просто ввести следующую команду в свой файл .vimrc (если не в домашней папке, чем создать)

cabbrev t tabnew

Самым безопасным и простым является плагин, такой как cmdalias.vim или мои последние vim-псевдонимы, которые учитывают

• предшествующие пробелы или модификаторы, такие как :sil(ent)(!)или :redi(r),
• модификаторы диапазона, такие как '<,'>для текущего визуального выбора,
• экранировать специальные символы, такие как кавычки, и
• проверьте, является ли выбранный псевдоним допустимым сокращением командной строки.