Как удалить несколько буферов в Vim?

Предполагая, что у меня есть несколько файлов, открытых как буферы в Vim. Файлы есть *.cpp, *.hа некоторые есть *.xml. Я хочу закрыть все файлы XML с помощью:bd *.xml . Однако Vim не позволяет этого (E93: более одного совпадения ...).

Есть какой-либо способ сделать это?

PS Я знаю, что это :bd file1 file2 file3работает. Так что я могу как - то оценивать *.xmlс file1.xml file2.xml file3.xml?

Вы можете использовать <C-a>для завершения всех матчей. Поэтому, если вы наберете, :bd *.xmlа затем нажмете <C-a>, vim завершит команду до :bd file1.xml file2.xml file3.xml.

:3,5bd[elete]   

Удалит диапазон буфера от 3 до 5.

Вы также можете использовать альтернативно:

    :.,$-bd[elete]    " to delete buffers from the current one to last but one
    :%bd[elete]       " to delete all buffers

Вы можете использовать это.

:exe 'bd '. join(filter(map(copy(range(1, bufnr('$'))), 'bufname(v:val)'), 'v:val =~ "\.xml$"'), ' ')

Его должно быть довольно легко добавить в команду.

function! s:BDExt(ext)
  let buffers = filter(range(1, bufnr('$')), 'buflisted(v:val) && bufname(v:val) =~ "\.'.a:ext.'$"')
  if empty(buffers) |throw "no *.".a:ext." buffer" | endif
  exe 'bd '.join(buffers, ' ')
endfunction

command! -nargs=1 BDExt :call s:BDExt(<f-args>)

Попробуйте сценарий ниже. Пример для «txt», при необходимости измените его, например, на «xml». Модифицированные буферы не удаляются. Нажмите \ bd, чтобы удалить буферы.

map <Leader>bd :bufdo call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   if (matchstr(bufname("%"), ".".a:strExt."$") == ".".a:strExt )
      if (! &modified)
         bd
      endif
   endif
endfunction

[Edit] То же самое без: bufdo (по просьбе Люка Эрмитта, см. Комментарий ниже)

map <Leader>bd :call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   let s:bufNr = bufnr("$")
   while s:bufNr > 0
       if buflisted(s:bufNr)
           if (matchstr(bufname(s:bufNr), ".".a:strExt."$") == ".".a:strExt )
              if getbufvar(s:bufNr, '&modified') == 0
                 execute "bd ".s:bufNr
              endif
           endif
       endif
       let s:bufNr = s:bufNr-1
   endwhile
endfunction

Мне тоже все время требовалась эта функция. Это решение, которое у меня есть в моем vimrc.

function! GetBufferList()
    return filter(range(1,bufnr('$')), 'buflisted(v:val)')
endfunction

function! GetMatchingBuffers(pattern)
    return filter(GetBufferList(), 'bufname(v:val) =~ a:pattern')
endfunction

function! WipeMatchingBuffers(pattern)
    let l:matchList = GetMatchingBuffers(a:pattern)

    let l:count = len(l:matchList)
    if l:count < 1
        echo 'No buffers found matching pattern ' . a:pattern
        return
    endif

    if l:count == 1
        let l:suffix = ''
    else
        let l:suffix = 's'
    endif

    exec 'bw ' . join(l:matchList, ' ')

    echo 'Wiped ' . l:count . ' buffer' . l:suffix . '.'
endfunction

command! -nargs=1 BW call WipeMatchingBuffers('<args>')

Теперь я могу просто сделать :BW regex(например, :BW \.cpp$и стереть все совпадающие буферы, которые соответствуют этому шаблону в их имени пути.

Если вы хотите удалить , а не вытирать, вы , конечно , можете заменить exec 'bw ' . join(l:matchList, ' ')сexec 'bd ' . join(l:matchList, ' ')

Очень просто: используйте :bd[elete]команду. Например, :bd[elete] buf#1 buf#5 buf#3удалит буферы 1, 3 и 5.

TABбудет выполнять автозаполнение только одного файла, начиная с версии Vim 7.4.282, которая
используется <c-a>для автозаполнения всех файлов.

Вы можете просто использовать:

bd filetype

тогда просто используйте <c-a> чтобы облегчить завершение всех открытых файлов указанного типа.

например, у вас 1.xml, 2.xml, 3.xml и 4.xml, вы можете:

bd xml

затем нажмите <c-a>

vim выполнит автозаполнение для вас следующим образом:

bd 1.xml 2.xml 3.xml 4.xml

вы можете просто нажать Enter, чтобы завершить команду.

если вы внесли изменения в один из файлов, упомянутых выше, не забудьте сделать:

bd! xml