Perl
Я решил быть немного антиконкурентным и показать, как вы обычно кодируете такую проблему на Perl.
В конце также есть 46 (всего) кодовая запись для гольфа.
Все эти первые три примера начинаются с этого заголовка.
#! /usr/bin/env perl
use Modern::Perl;
# which is the same as these three lines:
# use 5.10.0;
# use strict;
# use warnings;
while( <> ){
chomp;
last unless $_;
Collatz( $_ );
}
Простая рекурсивная версия
use Sub::Call::Recur;
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
say $n;
given( $n ){
when( 1 ){}
when( $_ % 2 != 0 ){ # odd
recur( 3 * $n + 1 );
}
default{ # even
recur( $n / 2 );
}
}
}
Простая итеративная версия
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
say $n;
while( $n > 1 ){
if( $n % 2 ){ # odd
$n = 3 * $n + 1;
} else { #even
$n = $n / 2;
}
say $n;
}
}
Оптимизированная итеративная версия
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
#
state @next;
$next[1] //= 0; # sets $next[1] to 0 if it is undefined
#
# fill out @next until we get to a value we've already worked on
until( defined $next[$n] ){
say $n;
#
if( $n % 2 ){ # odd
$next[$n] = 3 * $n + 1;
} else { # even
$next[$n] = $n / 2;
}
#
$n = $next[$n];
}
say $n;
# finish running until we get to 1
say $n while $n = $next[$n];
}
Теперь я покажу, как бы вы сделали этот последний пример с версией Perl до v5.10.0.
#! /usr/bin/env perl
use strict;
use warnings;
while( <> ){
chomp;
last unless $_;
Collatz( $_ );
}
{
my @next = (0,0); # essentially the same as a state variable
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
# fill out @next until we get to a value we've already worked on
until( $n == 1 or defined $next[$n] ){
print $n, "\n";
if( $n % 2 ){ # odd
$next[$n] = 3 * $n + 1;
} else { # even
$next[$n] = $n / 2;
}
$n = $next[$n];
}
print $n, "\n";
# finish running until we get to 1
print $n, "\n" while $n = $next[$n];
}
}
Контрольный показатель
Во-первых, ввод-вывод всегда будет медленной частью. Так что, если вы действительно протестировали их как есть, вы должны получить примерно одинаковую скорость для каждого из них.
Затем, чтобы проверить это, я открыл дескриптор файла для /dev/null( $null) и отредактировал каждый, say $nчтобы вместо этого читать say {$null} $n. Это сделано для уменьшения зависимости от ввода-вывода.
#! /usr/bin/env perl
use Modern::Perl;
use autodie;
open our $null, '>', '/dev/null';
use Benchmark qw':all';
cmpthese( -10,
{
Recursive => sub{ Collatz_r( 31 ) },
Iterative => sub{ Collatz_i( 31 ) },
Optimized => sub{ Collatz_o( 31 ) },
});
sub Collatz_r{
...
say {$null} $n;
...
}
sub Collatz_i{
...
say {$null} $n;
...
}
sub Collatz_o{
...
say {$null} $n;
...
}
После 10 запусков, вот типичный результат:
Скорость рекурсивной итеративной оптимизации
Рекурсивный 1715 / с - -27% -46%
Итеративная 2336 / с 36% - -27%
Оптимизировано 3187 / с 86% 36% -
Наконец, настоящий код-гольф:
perl -nlE'say;say$_=$_%2?3*$_+1:$_/2while$_>1'
46 символов всего
Если вам не нужно печатать начальное значение, вы можете удалить еще 5 символов.
perl -nE'say$_=$_%2?3*$_+1:$_/2while$_>1'
41 символ всего
31 символ для фактической части кода, но код не будет работать без -nпереключателя. Поэтому я включаю в свой счет весь пример.