Может ли vim отслеживать изменения файла в реальном времени

Мой вопрос аналогичен тому, как отслеживать текстовый файл в реальном времени, но я хочу сделать это в vim. Я знаю, что могу читать открытый файл использования tail -f sample.xmlфайла, и когда новый контент будет записан в файл, он также запишет новый контент на мой экран. Могу ли я сделать так, чтобы vim автоматически заполнял новые данные при обновлении файла?

Ты можешь :set autoread так, чтобы vim читал файл при его изменении. Однако (в зависимости от вашей платформы) вы должны сосредоточиться на ней.

Из справки:

Если было обнаружено, что файл был изменен вне Vim, но не был изменен внутри Vim, автоматически прочтите его снова. Когда файл был удален, этого не происходит.

Не знаю об автомате, но вы можете ввести:

:e!

перезагрузить файл

Поместите следующее в свой .vimrc :

"проверка один раз после 4 секунд бездействия в нормальном режиме
установить автоматическое чтение                                                                                                                                                                                    
au CursorHold * checktime                                                                                                                                                                       

как @flukus сказал в комментарии к предыдущему ответу, вы можете call feedkeys["lh"](он перемещает курсор вправо и обратно влево, что обычно не вредит при просмотре файла журнала)

Итак, если вы объедините оставшуюся часть ответа, у вас есть oneliner, который вы можете запустить из ex (whithin vim) при необходимости:

:set autoread | au CursorHold * checktime | call feedkeys("lh")

(если вы хотите перейти (почти) к концу файла, просто используйте «G» вместо «lh» с клавишами подачи)

Объяснение:
- autoread : читает файл при изменении извне (но он не работает сам по себе, нет внутреннего таймера или чего-то подобного. Он будет читать файл только тогда, когда vim выполняет действие, например команду в ex :!
- CursorHold * checktime : когда курсор не перемещается пользователем в течение времени, указанного в 'updatetime' (которое по умолчанию составляет 4000 миллисекунд), выполняется checktime, который проверяет наличие изменений извне файла
- вызовите feedkeys («lh») : курсор перемещается один раз вправо и назад влево. а затем ничего не происходит (... это означает, что CursorHold срабатывает, что означает, что у нас есть цикл )

Дополнительно вы можете :set syntax=logtalkраскрасить журнал

Чтобы остановить прокрутку при использовании call feedkeys("G"), выполните :set noautoread- теперь vim сообщит, что файл был изменен, и спросит, хочет ли кто-то прочитать изменения или нет)

(Есть ли у этого побочные эффекты?)

Изменить: я вижу один побочный эффект: если использовать «G» в качестве клавиши подачи, он будет прокручивать вниз каждый текущий открытый буфер ?! Таким образом, невозможно работать в левом буфере разделенного окна, когда правый буфер автоматически прокручивает файл журнала вниз.

Вставьте это в свой .vimrc, и он должен работать как босс. (Взято с: http://vim.wikia.com/wiki/Have_Vim_check_automatically_if_the_file_has_changed_external )

" Function to Watch for changes if buffer changed on disk
function! WatchForChanges(bufname, ...)
  " Figure out which options are in effect
  if a:bufname == '*'
    let id = 'WatchForChanges'.'AnyBuffer'
    " If you try to do checktime *, you'll get E93: More than one match for * is given
    let bufspec = ''
  else
    if bufnr(a:bufname) == -1
      echoerr "Buffer " . a:bufname . " doesn't exist"
      return
    end
    let id = 'WatchForChanges'.bufnr(a:bufname)
    let bufspec = a:bufname
  end
  if len(a:000) == 0
    let options = {}
  else
    if type(a:1) == type({})
      let options = a:1
    else
      echoerr "Argument must be a Dict"
    end
  end
  let autoread    = has_key(options, 'autoread')    ? options['autoread']    : 0
  let toggle      = has_key(options, 'toggle')      ? options['toggle']      : 0
  let disable     = has_key(options, 'disable')     ? options['disable']     : 0
  let more_events = has_key(options, 'more_events') ? options['more_events'] : 1
  let while_in_this_buffer_only = has_key(options, 'while_in_this_buffer_only') ? options['while_in_this_buffer_only'] : 0
  if while_in_this_buffer_only
    let event_bufspec = a:bufname
  else
    let event_bufspec = '*'
  end
  let reg_saved = @"
  "let autoread_saved = &autoread
  let msg = "\n"
  " Check to see if the autocommand already exists
  redir @"
    silent! exec 'au '.id
  redir END
  let l:defined = (@" !~ 'E216: No such group or event:')
  " If not yet defined...
  if !l:defined
    if l:autoread
      let msg = msg . 'Autoread enabled - '
      if a:bufname == '*'
        set autoread
      else
        setlocal autoread
      end
    end
    silent! exec 'augroup '.id
      if a:bufname != '*'
        "exec "au BufDelete    ".a:bufname . " :silent! au! ".id . " | silent! augroup! ".id
        "exec "au BufDelete    ".a:bufname . " :echomsg 'Removing autocommands for ".id."' | au! ".id . " | augroup! ".id
        exec "au BufDelete    ".a:bufname . " execute 'au! ".id."' | execute 'augroup! ".id."'"
      end
        exec "au BufEnter     ".event_bufspec . " :checktime ".bufspec
        exec "au CursorHold   ".event_bufspec . " :checktime ".bufspec
        exec "au CursorHoldI  ".event_bufspec . " :checktime ".bufspec
      " The following events might slow things down so we provide a way to disable them...
      " vim docs warn:
      "   Careful: Don't do anything that the user does
      "   not expect or that is slow.
      if more_events
        exec "au CursorMoved  ".event_bufspec . " :checktime ".bufspec
        exec "au CursorMovedI ".event_bufspec . " :checktime ".bufspec
      end
    augroup END
    let msg = msg . 'Now watching ' . bufspec . ' for external updates...'
  end
  " If they want to disable it, or it is defined and they want to toggle it,
  if l:disable || (l:toggle && l:defined)
    if l:autoread
      let msg = msg . 'Autoread disabled - '
      if a:bufname == '*'
        set noautoread
      else
        setlocal noautoread
      end
    end
    " Using an autogroup allows us to remove it easily with the following
    " command. If we do not use an autogroup, we cannot remove this
    " single :checktime command
    " augroup! checkforupdates
    silent! exec 'au! '.id
    silent! exec 'augroup! '.id
    let msg = msg . 'No longer watching ' . bufspec . ' for external updates.'
  elseif l:defined
    let msg = msg . 'Already watching ' . bufspec . ' for external updates'
  end
  echo msg
  let @"=reg_saved
endfunction

let autoreadargs={'autoread':1}
execute WatchForChanges("*",autoreadargs)

Tail Bundle должен делать то, что вы хотите. Обратите внимание, сам не использовал.

Если unix + neovim

:term tail -f <filename>

Очевидно, это не сработает для всех, но я так делаю.

Также есть плагин:

https://github.com/djoshea/vim-autoread

Это был единственный способ заставить эту работу работать в OSX.

VIM предупредит вас, когда файл был обновлен, чтобы вы не перезаписали изменения, сделанные с момента его открытия. В этот момент вам будет предложено перезагрузить файл.