Я добавил notepad++.exeв свой путь в среде переменные.

Теперь в командной строке notepad++.exe filename.txtоткрывается filename.txt. Но я хочу сделать просто, np filename.txtчтобы открыть файл.

Я пытался использовать DOSKEY np=notepad++. Но это просто вывод на первый план уже открытого Notepad ++ без открытия файла. Как я могу сделать это открыть файл?

Спасибо.

Чтобы добавить к ответу Джоша,

Вы можете сделать псевдоним (ы) постоянным с помощью следующих шагов:

1. Создайте файл .bat или .cmd с вашими DOSKEYкомандами.
2. Запустите regedit и перейдите к HKEY_CURRENT_USER\Software\Microsoft\Command Processor

3. Добавьте запись String Value с именем AutoRunи полным путем к вашему файлу .bat / .cmd.

   Например, %USERPROFILE%\alias.cmdзамена начального сегмента пути %USERPROFILE%полезна для синхронизации между несколькими компьютерами.

Таким образом, при каждом запуске cmd загружаются псевдонимы.

Для Windows 10 добавьте запись HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processorвместо.

Для полноты, вот шаблон для иллюстрации того, какие псевдонимы могут оказаться полезными.

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

• Обратите внимание, что $*синтаксис работает после строки каталога, а также исполняемого файла, который принимает аргументы. Таким образом, в приведенном выше примере пользовательская команда dropbox researchуказывает на тот же каталог, что и research.
• Как отметил Rivenfall, хорошей идеей будет включить команду, которая позволяет удобно редактировать alias.cmdфайл. Смотри aliasвыше. Если вы находитесь в сеансе cmd, введите, cmdчтобы перезапустить cmd и перезагрузить alias.cmdфайл.

Когда я искал в интернете ответ на вопрос, каким-то образом дискуссии были либо сосредоточены только на постоянстве, либо только на использовании DOSKEY. Я надеюсь, что кому-то будет полезно, если эти два аспекта будут здесь вместе!

Вот .regфайл, который поможет вам установить alias.cmd. Теперь он установлен в качестве примера для папки dropbox, как предложено выше.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

Для однопользовательских приложений, выше будет делать. Тем не менее, существуют ситуации, когда необходимо проверить, alias.cmdсуществует ли сначала в разделе реестра. Смотрите пример ниже.

В C:\Users\Public\init.cmdфайловом хостинге возможны межпользовательские конфигурации:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

Раздел реестра должен быть обновлен соответственно C:\Users\Public\init.cmdили, используя .regфайл:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

Вам нужно передать параметры, попробуйте это:

doskey np=notepad++.exe $*

Редактировать (отвечая на комментарий Ромонова) В: Есть ли какой-нибудь способ, которым я могу запомнить командную строку, чтобы мне не приходилось запускать ее каждый раз, когда я открываю новую командную строку?

doskey текстовая команда, которая интерпретируется командным процессором (например, cmd.exe), она не может знать, как изменить состояние в каком-либо другом процессе (особенно в том, который еще не запущен).

Люди, которые используют doskeyдля настройки своих начальных сред командной оболочки, обычно используют /Kопцию (часто с помощью ярлыка) для запуска командного файла, который выполняет все общие настройки (например, задает заголовок окна, цвета и т. Д.).

cmd.exe /K env.cmd

env.cmd:

title "Foo Bar"
doskey np=notepad++.exe $*
...

Если вы просто собираетесь выполнить несколько простых команд, вы можете выполнить следующие шаги:

1. Создайте папку с именем C: \ Aliases
2. Добавьте C: \ Aliases к своему пути (чтобы любые файлы в нем были найдены каждый раз)
3. Создайте файл .bat в C: \ Aliases для каждого из псевдонимов, которые вы хотите

Может быть излишним, но в отличие от (в противном случае превосходного) ответа от @Argyll, это решает проблему этой загрузки каждый раз.

Например, у меня есть файл с именем dig2.bat со следующим:

@echo off
echo.
dig +noall +answer %1

Ваш файл np будет иметь следующее:

@echo off
echo.
notepad++.exe %1

Затем просто добавьте папку C: \ Aliases в переменную окружения PATH. Если у вас уже открыты CMD или PowerShell, вам нужно будет перезапустить их.

FWIW, у меня есть около 20 псевдонимов (отдельные файлы .bat) в моем каталоге C: \ Aliases - я просто создаю новые по мере необходимости. Может быть, не самое лучшее, но работает нормально.

ОБНОВЛЕНИЕ : по отличному предложению от пользователя @Mav, даже лучше использовать % *, а не % 1 , поэтому вы можете передать команде несколько файлов, например:

@echo off
echo.
notepad++.exe %*

Таким образом, вы можете сделать это:

np c:\temp\abc.txt c:\temp\def.txt c:\temp\ghi.txt

и он откроет все 3 файла.

В качестве альтернативы вы можете использовать, cmderкоторый позволяет добавлять псевдонимы, как Linux:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

Учитывая, что вы добавили notepad ++. Exe в переменную PATH, это очень просто. Создайте файл в вашей папке System32 np.batс именем следующего кода:

@echo off
call notepad++.exe %*

В %*прохожу по всем аргументам вы даете npкоманду к notepad++.exeкоманде.

РЕДАКТИРОВАТЬ: Вам понадобится доступ администратора для сохранения файлов в папку System32, что было немного неудобно для меня. Я просто создал файл в другом месте и вручную переместил его в System32.

Кроме того, вы можете создать alias.cmd в вашем пути (например, C: \ Windows) с помощью команды

@echo %2 %3 %4 %5 %6 > %windir%\%1.cmd

Как только вы это сделаете, вы можете сделать что-то вроде этого:

alias nameOfYourAlias commands to run 

И после этого вы можете ввести в командной строке

nameOfYourAlias 

это выполнит

commands to run 

НО лучший способ для меня - просто добавить путь к программе.

setx PATH "%PATH%;%ProgramFiles%\Sublime Text 3" /M 

И теперь я управляю возвышенным как

subl index.html

Консольные псевдонимы в Windows 10

Чтобы определить псевдоним консоли, используйте Doskey.exeдля создания макроса или используйтеAddConsoleAlias функцию.

DOSKEY

doskey test=cd \a_very_long_path\test

Чтобы также передать параметры, добавьте $*в конце:doskey short=longname $*

AddConsoleAlias

AddConsoleAlias( TEXT("test"), 
                 TEXT("cd \\<a_very_long_path>\\test"), 
                 TEXT("cmd.exe"));

Более подробная информация здесь Console Aliases , Doskey , Parameters

Вы хотите создать псевдоним, просто набрав:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

И используйте псевдоним следующим образом:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

Просто добавьте следующий alias.batфайл к вашему пути. Он просто создает дополнительные командные файлы в том же каталоге, что и сам.

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

Пример этого пакетного файла называется kgs.bat :

@echo off 
echo. 
kubectl get svc %* 

На самом деле, я пойду к вам лучше и расскажу о небольшой технике, которую я использовал с тех пор, как программировал на Amiga. В любой новой системе, которую вы используете, будь то персональная или профессиональная, первый шаг - создать две папки: C:\BINи C:\BATCH. Затем измените ваш путь, чтобы поместить оба в начале в порядкеC:\BATCH;C:\BIN;[rest of path] .

Сделав это, если у вас есть несколько устаревших утилит, к которым вам нужен доступ, просто скопируйте их в C:\BINпапку, и они будут на вашем пути. Чтобы временно переопределить эти назначения, вы можете добавить пакетный файл с тем же именем, что и исполняемый файл, кC:\BATCH папку, и путь найдет его перед файлом в C: \ BIN. Он должен охватывать все, что вам может понадобиться.

Конечно, в наши дни канонически правильным способом сделать это было бы создание символического перехода к файлу, но применяется тот же принцип. Также есть небольшой дополнительный бонус. Если вы хотите поместить что-то в систему, что конфликтует с чем-то, уже находящимся в пути, размещение этого в папке C:\BINили C:\Batchбудет просто заменять оригинал - позволяя вам переопределить вещи временно или постоянно, или переименовать вещи в имена, которые вы более комфортно с - без фактического изменения оригинала.

Расширение на ответ Рорихвитта .

Преимущество использования файлов .cmd перед DOSKEY заключается в том, что эти «псевдонимы» затем доступны в других оболочках, таких как PowerShell или WSL (подсистема Windows для Linux).

Единственный недостаток использования этих команд в bash заключается в том, что для этого может потребоваться немного больше настройки, поскольку вам может потребоваться выполнить некоторые манипуляции с путями перед вызовом своего «псевдонима».

например, у меня есть vs.cmd, который является моим «псевдонимом» для редактирования файла в Visual Studio

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

Который запускает VS (в данном случае VS2012 - но настраивается по вкусу), используя мой «обычный» проект, в котором не указан файл, но когда ему дан файл, он будет пытаться присоединиться к работающему VS, открывающему этот файл «в этом проекте», вместо новый экземпляр VS.

Для использования этого из bash я добавляю дополнительный уровень косвенности, так как «vs Myfile» не всегда работает

alias vs='/usr/bin/run_visual_studio.sh'

Который корректирует пути перед вызовом vs.cmd

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

Таким образом, я могу просто

vs SomeFile.txt

В командной строке, Power Shell или bash, и он открывается в моей работающей Visual Studio для редактирования (что просто избавляет мой бедный мозг от необходимости иметь дело с командами VI или некоторыми другими, когда я часами редактировал в VS).

Это решение не является подходящим, но в некоторых случаях служит цели.

Сначала создайте папку и добавьте ее в системный путь. Перейдите к исполняемому файлу любой программы, для которой вы хотите создать псевдоним. Щелкните правой кнопкой мыши и отправьте на рабочий стол (Создать ярлык). Переименуйте ярлык в любое удобное псевдоним. Теперь возьмите ярлык и поместите в вашу папку.

В командной строке вы можете напрямую ввести имя ярлыка и открыть программу. Но из командной строки вам нужно добавить .lnk и нажать Enter, программа будет открыта.

Естественно, я не успокоюсь, пока не найду самое удобное решение из всех. Объединяя очень много ответов и тем в обширном Интернете, вот что вы можете получить.

• Загружается автоматически с каждым экземпляром cmd
• Не требуется ключевое слово DOSKEYдля псевдонимов

Обратите внимание, что это в значительной степени основано на ответе и комментариях Аргайлла , обязательно прочитайте его, чтобы понять концепции.

Как это работает?

1) создать файл макроса с псевдонимами (или файл bat / cmd для запуска других программ)
2) зарегистрировать его в реестре для запуска на каждом экземпляре cmd
  - вы также можете запускать его с помощью ярлыка, только если вы хотите

Это все

;==============================================================================
;= This file is registered via registry to auto load with each instance of cmd.
;================================ general info ================================
;= https://stackoverflow.com/a/59978163/985454  -  how to set it up?
;= https://gist.github.com/postcog/5c8c13f7f66330b493b8  -  example doskey macrofile
;========================= loading with cmd shortcut ==========================
;= create a cmd link with the following target :
;= %comspec% /k "(doskey /macrofile=%userprofile%\cmd\aliases.mac)"

alias=subl %USERPROFILE%\cmd\aliases.mac
hosts=runas /noprofile /savecred /user:QWERTY-XPS9370\administrator "subl C:\Windows\System32\drivers\etc\hosts" > NUL

ls=ls --color=auto $*
ll=ls -l --color=auto $*
la=ls -la --color=auto $*
grep=grep --color

~=cd %USERPROFILE%
cdr=cd c:\repos
cdd=cd c:\repos\dixons
cds=cd c:\repos\stekkie
cdu=cd c:\repos\uplus
cduo=cd c:\repos\uplus\oxbridge-fe
cdus=cd c:\repos\uplus\stratus

;============================= :end ============================
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';'
;= rem * macro. We're using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

Теперь у вас есть две возможности:
а) зарегистрировать только макрофайл;
б) использовать обычный cmd/batфайл для запуска произвольных команд.
Переименуйте ту, которую вы хотите Autorun.

  Autorun    REG_SZ    doskey /macrofile=%userprofile%\cmd\aliases.mac
  Autorun_    REG_SZ    %USERPROFILE%\cmd\env.cmd

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"Autorun"="doskey /macrofile=%userprofile%\\cmd\\aliases.mac"
"Autorun_"="%USERPROFILE%\\cmd\\env.cmd"

:: This file is registered via registry to auto load with each instance of cmd.
:: https://stackoverflow.com/a/59978163/985454

@echo off
doskey /macrofile=%userprofile%\cmd\aliases.mac

:: put other commands here

Так как у вас уже есть notepad++.exeна вашем пути. Создайте ярлык в этой папке с именем npи укажите его notepad++.exe.

Во-первых, вы можете создать файл с именем np.cmd и поместить его в папку, которая находится в списке поиска PATH. Затем отредактируйте файл np.cmd, как показано ниже:

@echo off
notepad++.exe

Если вы хотите включить псевдонимы для каждого каталога / проекта , попробуйте следующее:

1. Сначала создайте пакетный файл, который будет искать файл с именем aliasesв текущем каталоге и инициализировать псевдонимы из него, давайте назовем егоmake-aliases.cmd

   @echo off
   if not exist aliases goto:eof
   echo [Loading aliases...]
   for /f "tokens=1* delims=^=" %%i in (aliases) do (
      echo   %%i ^<^=^> %%j
      doskey %%i=%%j
   )
   doskey aliases=doskey /macros
   echo   --------------------
   echo   aliases ^=^> list  all
   echo   alt+F10 ^=^> clear all
   echo [Done]
   

2. Затем создайте их aliasesтам , где они вам нужны, используя следующий формат:

   alias1 = command1
   alias2 = command2
   ...
   

   например:

   b = nmake
   c = nmake clean
   r = nmake rebuild
   

3. Затем добавьте местоположение make-aliases.cmdвашей %PATH%переменной, чтобы сделать ее общесистемной или просто храните ее в известном месте.

4. Заставьте это начаться автоматически с cmd.

   • Я бы определенно не советовал использовать HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRunдля этого, потому что некоторые инструменты разработки запускают скрипт автозапуска несколько раз за сеанс.

   • Если вы используете ConEmu вы могли бы пойти другим путем и запустить сценарий из задачи запуска ( Settings> Startup> Tasks), к примеру, я создал запись под названием {MSVC}:

     cmd.exe /k "vcvars64 && make-aliases",

     а затем зарегистрировал его в контекстном меню Проводника через Settings> Integration>с Command: {MSVC} -cur_console:n, так что теперь я могу правая кнопка мыши папку и запустить разработчик VS быстрый внутри него с моим aliasesзагружаются автоматически, если они оказались в этой папке.

     Без ConEmu вы можете просто создать ярлык для cmd.exeсоответствующей команды или просто make-aliasesкаждый раз запускать вручную.

Если вы случайно забыли псевдонимы, используете aliasesмакрос и, если что-то пойдет не так, просто сбросьте текущий сеанс, нажав Alt+ F10, что является встроенной командой cmd.

Использование doskey - верный способ сделать это, но оно сбрасывается, когда окно командной строки закрывается. Вам нужно добавить эту строку в нечто вроде .bashrc эквивалента. Итак, я сделал следующее:

1. Добавьте «C: \ Program Files (x86) \ Notepad ++» в системную переменную пути
2. Сделайте копию notepad ++. Exe (конечно, в той же папке) и переименуйте ее в np.exe

Работает просто отлично!