Перенаправление вывода из пакетного файла

Я создаю командный файл с несколькими простыми командами для сбора информации из системы. Пакетный файл содержит команды для получения времени, IP-информации, пользователей и т. Д.

Я собрал все команды в пакетный файл, и он запускается, но мне бы хотелось, чтобы пакетный файл при запуске выводил результаты в текстовый файл (журнал). Есть ли команда, которую я могу добавить в пакет?

Имейте в виду, что я не хочу запускать пакет из cmd, а затем перенаправлять вывод; Я хочу перенаправить вывод из пакета, если это возможно.

Простой наивный способ, который является медленным, потому что он открывает и позиционирует указатель файла на конец файла несколько раз.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Лучший способ - проще писать и быстрее, потому что файл открывается и позиционируется только один раз.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Еще один хороший и быстрый способ, который открывает и позиционирует файл только один раз

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Изменить 2020-04-17

Время от времени вы можете захотеть повторно записать два или более файлов. Вам также могут понадобиться разные сообщения на экране. По-прежнему можно сделать это эффективно, перенаправив на неопределенные дескрипторы вне блока или подпрограммы в скобках, а затем используя &нотацию для ссылки на уже открытые файлы.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Я решил использовать дескрипторы 9 и 8 в обратном порядке, потому что этот способ с большей вероятностью позволит избежать потенциального постоянного перенаправления из-за ошибки проектирования реализации перенаправления Microsoft при выполнении нескольких перенаправлений для одной и той же команды. Это маловероятно, но даже такой подход может выявить ошибку, если вы достаточно постараетесь. Если вы сделаете перенаправление, вы гарантированно избежите проблемы.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

если вы хотите перенаправлять как исходящие, так и ошибочные потоки

dir >> a.txt 2>&1

Я знаю, что это более старый пост, но кто-то наткнется на него в поиске Google, и также похоже, что некоторые вопросы, заданные OP в комментариях, не были конкретно рассмотрены. Кроме того, будьте осторожны со мной, так как это мой первый ответ, опубликованный на SO. :)

Чтобы перенаправить вывод в файл с использованием динамически сгенерированного имени файла, мой подход (читай: быстро и грязно) - это второе решение, предлагаемое @dbenham. Так, например, это:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Создаст файл, подобный тому, что вы видите на этом снимке экрана файла в целевом каталоге.

Это будет содержать этот вывод:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Также имейте в виду, что это решение зависит от локали, поэтому будьте осторожны, как и когда вы его используете.

echo some output >"your logfile"

или

(
 echo some output
 echo more output
)>"Your logfile"

должен заполнить счет.

Если вы хотите получить APPENDрезультат, используйте >>вместо >. >запустит новый файл журнала.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Есть небольшая классная программа, которую вы можете использовать для перенаправления вывода в файл и консоль.

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Добавьте эти две строки в верхнюю часть вашего командного файла, все stdout и stderr после будут перенаправлены в log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

Я использовал приведенную выше команду в своем командном файле, и она работает. В файле журнала он показывает результаты моей команды.

Это может не сработать в случае "токсичных" символов во вводе. Рассмотрение ввода, подобного этому, IsAnIn ^^^^ put - хороший способ понять, что происходит. Конечно, существует правило, согласно которому входная строка ДОЛЖНА быть внутри двойных кавычек, но я чувствую, что это правило является действительным правилом только в том случае, если значение входных данных находится в разделе NTFS (возможно, это правило для URL-адресов, которые я Я не уверен). Но это, конечно, не правило для произвольной входной строки (это «хорошая практика», но вы не можете рассчитывать по ней).

Добавление следующих строк в нижнюю часть вашего командного файла захватит все, как показано в окне CMD, и экспортирует в текстовый файл:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Он в основном выполняет выделение всего -> копирование в буфер обмена -> вставку в текстовый файл .