Разрешить абсолютный путь из относительного пути и / или имени файла

Есть ли способ в пакетном скрипте Windows вернуть абсолютный путь из значения, содержащего имя файла и / или относительный путь?

Дано:

"..\"
"..\somefile.txt"

Мне нужен абсолютный путь относительно командного файла.

Пример:

• «somefile.txt» находится в «C: \ Foo \»
• "test.bat" находится в "C: \ Foo \ Bar".
• Пользователь открывает окно команд в «C: \ Foo» и вызывает Bar\test.bat ..\somefile.txt
• В командном файле "C: \ Foo \ somefile.txt" будет получен из %1

В пакетных файлах, как и в стандартных программах на C, аргумент 0 содержит путь к текущему исполняемому сценарию. Вы можете использовать, %~dp0чтобы получить только часть пути 0-го аргумента (который является текущим сценарием) - этот путь всегда является полностью определенным путем.

Вы также можете получить полный путь к первому аргументу с помощью %~f1, но это дает путь в соответствии с текущим рабочим каталогом, что явно не то, что вам нужно.

Лично я часто использую %~dp0%~1идиому в моем пакетном файле, которая интерпретирует первый аргумент относительно пути исполняемого пакета. Однако у него есть недостаток: он с треском проваливается, если первый аргумент полностью квалифицирован.

Если вам нужно поддерживать как относительные, так и абсолютные пути, вы можете воспользоваться решением Фредерика Менеза : временно изменить текущий рабочий каталог.

Вот пример, который продемонстрирует каждый из этих методов:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Если вы сохраните его как c: \ temp \ example.bat и запустите его из c: \ Users \ Public как

c: \ Users \ Public> \ temp \ example.bat .. \ windows

... вы увидите следующий вывод:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

документацию для набора модификаторов, разрешенных для аргумента пакета, можно найти здесь: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/call

Сегодня утром я столкнулся с аналогичной потребностью: как преобразовать относительный путь в абсолютный путь внутри командного сценария Windows.

Следующие сделали свое дело:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

Большинство из этих ответов кажутся сумасшедшими из-за сложных и супер глючных, вот мой - он работает с любой переменной среды, нет %CD%или PUSHD/ POPDили for /fерунда - просто старые пакетные функции - Каталог и файл даже не должны существовать.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~f1
  EXIT /B

Не имея другого пакетного файла для передачи аргументов (и использования операторов аргументов), вы можете использовать FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

где iin %%~fiявляется переменной, определенной в /F %%i. например. если вы изменили это, /F %%aто последняя часть будет %%~fa.

Чтобы сделать то же самое прямо в командной строке (а не в командном файле), заменить %%на %...

Это поможет заполнить пробелы в ответе Эдриана Плиссона (который должен быть одобрен, как только он его отредактирует ;-):

вы также можете получить полный путь к первому аргументу, используя% ~ f1, но это дает путь в соответствии с текущим путем, что, очевидно, не то, что вам нужно.

к сожалению, я не знаю, как смешать 2 вместе ...

Можно справиться %0и %1аналогично:

• %~dpnx0для полностью определенного диска + путь + имя + расширение самого пакетного файла
  %~f0также достаточно;
• %~dpnx1для полностью определенного диска + путь + имя + расширение его первого аргумента [если это вообще имя файла],
  %~f1также достаточно;

%~f1будет работать независимо от того, как вы указали свой первый аргумент: с относительными путями или с абсолютными путями (если вы не укажете расширение файла при именовании %1, оно не будет добавлено, даже если вы используете %~dpnx1- однако.

Но как на самом деле вы бы назвали файл на другом диске в любом случае, если бы не указали эту полную информацию о пути в командной строке?

Однако %~p0, %~n0, %~nx0и %~x0может пригодиться, вы должны быть заинтересованы в пути (без Буква_диска), имя файла (без расширения), полное имя файла с расширением или расширение имени файла только. Но учтите, что while %~p1и %~n1будет работать, чтобы выяснить путь или имя первого аргумента, %~nx1и %~x1не будет добавлять + показывать расширение, если вы уже не использовали его в командной строке.

Вы также можете использовать пакетные функции для этого:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Небольшое улучшение отличного решения BrainSlugs83 . Обобщается, чтобы разрешить именование выходной переменной среды в вызове.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

Если запустить из C:\projectвывода:

C:\project\doc\build

Я не видел много решений этой проблемы. Некоторые решения используют обход каталога с использованием CD, а другие используют пакетные функции. Мои личные предпочтения были для пакетных функций и, в частности, для функции MakeAbsolute, предоставленной DosTips.

Функция имеет некоторые реальные преимущества, в первую очередь, в том, что она не меняет ваш текущий рабочий каталог, и во-вторых, что оцениваемые пути даже не должны существовать. Вы можете найти некоторые полезные советы о том , как использовать функцию здесь тоже.

Вот пример сценария и его результаты:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

И вывод:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

Надеюсь, это поможет ... Это, безусловно, помогло мне :) PS Еще раз спасибо DosTips! Ты жжешь!

Вы можете просто объединить их.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

это выглядит странно с \ .. \ в середине вашего пути, но это работает. Не нужно ничего сумасшедшего делать :)

В вашем примере из Bar \ test.bat DIR / B / S .. \ somefile.txt вернет полный путь.

PowerShell довольно распространен в наши дни, поэтому я часто использую его для быстрого вызова C #, поскольку в нем есть функции практически для всего:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

Это немного медленно, но полученную функциональность сложно превзойти, если не прибегнуть к реальному языку сценариев.

Решение Stijn работает с подпапками C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

Файлы Посмотреть все остальные ответы

Справочники

С ..быть вашим относительный путь, и если вы находитесь в данный момент D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (относительный путь)

возвращает абсолютный путь, например

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b