UltiSnips и YouCompleteMe

У меня есть пакеты ultisnips и youcompleteme, установленные на моем macvim. Проблема в том, что ultisnips не работает, потому что вкладка привязана к ycm. Я попытался поставить let g:UltiSnipsExpandTrigger = "<s-tab>"так, чтобы я мог вызвать завершение фрагмента с помощью shift-tab, но по неизвестной причине это не работает. Я мог бы использовать колпачки в качестве триггера, но пока не нашел способа сделать это.

Кто-нибудь из вас использует эти два дополнения вместе? Что я могу сделать, чтобы сдвиг табуляции работал? Можете ли вы порекомендовать другой ключ для запуска сниппетов?

Другой вариант - использовать плагин SuperTab:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Здесь YouCompleteMe привязан к другой комбинации Ctrln, но затем эта комбинация привязана к табуляции через SuperTab. UltiSnips и SuperTab отлично работают вместе, поэтому вы можете просто привязать UltiSnips к вкладке напрямую, и все будет работать.

Попробуйте это предложение на странице из системы отслеживания проблем YouCompleteMe. В вашем .vimrc:

let g:UltiSnipsExpandTrigger="<c-j>"

Хотя этот параметр заставляет раскрывающийся фрагмент использовать сопоставление по умолчанию для перехода вперед внутри фрагмента , он имитирует поведение TextMates, как указано в тегах справки UltiSnips.

Поскольку я сопоставил свою клавишу Caps Lock с Ctrl, это сопоставление работает довольно плавно.

скопируйте следующий код на свой vimrc и наслаждайтесь. Эта функция решает все проблемы между YCM и UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

у меня это в моем vimrc

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

это то, что я сделал с первой попытки, но я неправильно написал UltiSnips с Ultisnips ... ну, в конце концов, сработало!

Я лично решил не использовать <tab>YouCompleteMe, а перемещаться по нему вручную.

Итак, я добавил это в свой .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

который просто отключает tabключ для YCM. Вместо этого вы используете клавиши перемещения (стрелки или CTRL-N/ CTRL-P) и выбираете запись с помощью CR. UltiSnips по умолчанию работает с tab.

Просто собрал ответы Майклслек, Джои Лю и решения, которые я нашел в этой теме, и vimrc этого парня , теперь у меня есть это, которое решило почти все проблемы.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Хотя я знаю, что эта статья немного устарела, у меня есть собственная функция, которая немного более оптимизирована, чем приведенная выше:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Конечно, если вы просто сохраните настройки, которые предоставил Джои Лю, а затем просто воспользуетесь этой функцией, все будет работать идеально!

РЕДАКТИРОВАТЬ: Кроме того, я использую другую функцию для увеличения функциональности обратного перехода между YouCompleteMe и UltiSnips. Я покажу вам, что я имею в виду:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Затем просто поместите это в свой .vimrc:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Равно как let g:UltiSnipsJumpBackwardTrigger="<s-tab>"и ваш набор!

Я использую их оба вместе. По умолчанию привязок YouCompleteMe <Tab>и <Down>выбрать следующий пункт завершения , а также <S-Tab>и <Up>для выбора предыдущего пункта завершения. Вы можете изменить привязки YouCompleteMe с помощью параметров g: ycm_key_list_select_completion и g: ycm_key_list_previous_completion . Обратите внимание, что имена этих параметров были недавно изменены, когда параметр был изменен с одной строки на список строк.

Я установил плагин UltiSnips после плагина YouCompleteMe, поэтому я подумал, что они конфликтуют, но на самом деле у меня было кое-что более мешающее:

set paste

Обязательно удалите это, .vimrcесли оно есть.

Хотя в этом посте многие ответы работают нормально, я просто хочу сказать, что проблема вызвана конфликтом привязки ключей между YCM и UltiSnip, в то время как YCM по умолчанию поддерживает фрагменты UltiSnip, в <tab>качестве ключа выбора завершения используется триггер UltiSnip по умолчанию , поэтому Фрагменты UltiSnip не расширяются <tab>. Дайте им разные привязки клавиш, чтобы решить проблему, я лично использую <c-nи <c-p>для YCM, и для UltiSnip по умолчанию <tab>. Вы можете получить более подробную информацию с help youcompletemedoc в vim.

Основываясь на ответе Зигфрида, я использую следующее, что кажется более естественным:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

Я также использую c-hjklпривязки где-то еще (переключение с панели на другую), но это будет только в обычном режиме, поэтому нет проблем.

Я использую ;для расширения UltiSnips, для меня это так здорово

let g:UltiSnipsExpandTrigger = ";"

Я использую kj. Вот что есть у меня .vimrc:

let g:UltisnipsExpandTrigger="kj",

Редко случается, что я нахожу в нем слово kj. Если это так, я бы просто подождал пару секунд после ввода kи этого типа j.

Как упоминалось другими, сопоставление Cj с ultisnips отлично работает.
let g:UltiSnipsExpandTrigger="<c-j>"

Теперь, если вы пойдете немного дальше, установите xcape и используйте
xcape -e "Shift_L=Control_R|J"

Вы раскрываете всю мощь использования только клавиши Shift для utlitsnips.