Отключить все ограничения таблиц в Oracle

96

Как отключить все ограничения таблиц в Oracle с помощью одной команды? Это может быть либо одна таблица, список таблиц, либо все таблицы.

sql  oracle 
— себя
источник

Ответы:

148

Лучше избегать записи временных файлов спула. Используйте блок PL / SQL. Вы можете запустить это из SQL * Plus или поместить в пакет или процедуру. Присоединение к USER_TABLES необходимо, чтобы избежать ограничений просмотра.

Маловероятно, что вы действительно хотите отключить все ограничения (включая NOT NULL, первичные ключи и т. Д.). Вам следует подумать о том, чтобы поместить constraint_type в предложение WHERE.

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'ENABLED'
   AND NOT (t.iot_type IS NOT NULL AND c.constraint_type = 'P')
   ORDER BY c.constraint_type DESC)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" disable constraint ' || c.constraint_name);
  END LOOP;
END;
/

Снова включить ограничения немного сложнее - вам нужно включить ограничения первичного ключа, прежде чем вы сможете ссылаться на них в ограничении внешнего ключа. Это можно сделать с помощью ORDER BY для constraint_type. «P» = первичный ключ, «R» = внешний ключ.

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'DISABLED'
   ORDER BY c.constraint_type)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" enable constraint ' || c.constraint_name);
  END LOOP;
END;
/
— WW.
источник
2
Разве этот первый сегмент кода не попытается отключить первичные ключи до того, как он отключит внешние ключи?
— Дэвид Олдридж,
@David Я думаю, что столкнулся с этой проблемой с первым сегментом. Я решил это, добавив 'DESC' между 'ORDER BY c.constraint_type' и закрытием ')'
— AndreiM
@WW Моя признательность. Это просто избавило меня от необходимости писать оператор SQL для генерации операторов ограничений Enable и Disable.
— dave
1
Первичные ключи нельзя отключить для таблиц, организованных по индексу. Вы можете справиться с этим, добавив AND NOT (t.iot_type IS NOT NULL AND c.constraint_type = 'P')в первый сегмент кода.
— Эндрю Миллер
2
Предупреждение: если вы уже ОТКЛЮЧЕНЫ ограничения, все ограничения будут активированы с использованием этой процедуры PL / SQL. Вы должны отфильтровать эти ограничения по месту, чтобы убедиться, что они остаются отключенными.
— nachouve
11

Чтобы учесть зависимости между ограничениями: 

SET Serveroutput ON
BEGIN
    FOR c IN
    (SELECT c.owner,c.table_name,c.constraint_name
    FROM user_constraints c,user_tables t
    WHERE c.table_name=t.table_name
    AND c.status='ENABLED'
    ORDER BY c.constraint_type DESC,c.last_change DESC
    )
    LOOP
        FOR D IN
        (SELECT P.Table_Name Parent_Table,C1.Table_Name Child_Table,C1.Owner,P.Constraint_Name Parent_Constraint,
            c1.constraint_name Child_Constraint
        FROM user_constraints p
        JOIN user_constraints c1 ON(p.constraint_name=c1.r_constraint_name)
        WHERE(p.constraint_type='P'
        OR p.constraint_type='U')
        AND c1.constraint_type='R'
        AND p.table_name=UPPER(c.table_name)
        )
        LOOP
            dbms_output.put_line('. Disable the constraint ' || d.Child_Constraint ||' (on table '||d.owner || '.' ||
            d.Child_Table || ')') ;
            dbms_utility.exec_ddl_statement('alter table ' || d.owner || '.' ||d.Child_Table || ' disable constraint ' ||
            d.Child_Constraint) ;
        END LOOP;
    END LOOP;
END;
/
— Cyryl1972
источник
5

Это не отдельная команда, но вот как я это делаю. Следующий сценарий разработан для работы в SQL * Plus. Обратите внимание, я специально написал это, чтобы работать только в рамках текущей схемы.

set heading off

spool drop_constraints.out

select
    'alter table ' || 
    owner || '.' || 
    table_name || 
    ' disable constraint ' || -- or 'drop' if you want to permanently remove
    constraint_name || ';'
from
    user_constraints;

spool off

set heading on

@drop_constraints.out

Чтобы ограничить то, что вы отбрасываете, добавьте фильтр в оператор select: -

  • фильтр по constraint_type, чтобы удалить только определенные типы ограничений
  • фильтр по table_name, чтобы сделать это только для одной или нескольких таблиц.

Чтобы работать в более чем текущей схеме, измените оператор select, чтобы выбрать из all_constraints, а не user_constraints.

Примечание. По какой-то причине я не могу заставить подчеркивание НЕ действовать как курсив в предыдущем абзаце. Если кто-то знает, как это исправить, пожалуйста, отредактируйте этот ответ.

— Майк Макаллистер
источник
Если вы хотите ОТКЛЮЧИТЬ ограничения вместо их УДАЛЕНИЯ, просто отредактируйте приведенный выше оператор SELECT: 'drop constraint', чтобы читать 'disable constraint' HTH: o)
— Эндрю,
Да, это хорошее предложение - в будущем не стесняйтесь редактировать сообщение, чтобы добавить эту информацию. Вот почему мои сообщения доступны для редактирования вики сообщества.
— Майк МакАллистер,
5

Используйте следующий курсор, чтобы отключить все ограничения .. И изменить запрос для включения ограничений ...

DECLARE

cursor r1 is select * from user_constraints;
cursor r2 is select * from user_tables;

BEGIN
  FOR c1 IN r1
  loop
    for c2 in r2
    loop
       if c1.table_name = c2.table_name and c1.status = 'ENABLED' THEN
        dbms_utility.exec_ddl_statement('alter table ' || c1.owner || '.' || c1.table_name || ' disable constraint ' || c1.constraint_name);
       end if;
    end loop;
  END LOOP;
END;
/
— пользователь486360
источник
4

Это может быть написано в PL / SQL довольно просто на основе системного представления DBA / ALL / USER_CONSTRAINTS, но различные детали не так тривиальны, как кажется. Вы должны быть осторожны с порядком, в котором это делается, а также учитывать наличие уникальных индексов.

Порядок важен, потому что вы не можете удалить уникальный или первичный ключ, на который ссылается внешний ключ, и могут быть внешние ключи в таблицах в других схемах, которые ссылаются на первичные ключи в ваших собственных, поэтому, если у вас нет привилегии ALTER ANY TABLE, тогда вы не может отказаться от этих ПК и Великобритании. Кроме того, вы не можете переключить уникальный индекс на неуникальный индекс, поэтому вам придется отбросить его, чтобы снять ограничение (по этой причине почти всегда лучше реализовать уникальные ограничения как «реальное» ограничение, которое поддерживается не -уникальный указатель).

— Дэвид Олдридж
источник
0

Не похоже, что вы можете сделать это с помощью одной команды, но вот самое близкое к этому, что я смог найти.

— Адам Беллер
источник
0

Это еще один способ отключения ограничений (он пришел с https://asktom.oracle.com/pls/asktom/f?p=100:11:2402577774283132::::P11_QUESTION_ID:399218963817 )

WITH qry0 AS
       (SELECT    'ALTER TABLE '
               || child_tname
               || ' DISABLE CONSTRAINT '
               || child_cons_name
                 disable_fk
              ,   'ALTER TABLE '
               || parent_tname
               || ' DISABLE CONSTRAINT '
               || parent.parent_cons_name
                 disable_pk
          FROM (SELECT a.table_name child_tname
                      ,a.constraint_name child_cons_name
                      ,b.r_constraint_name parent_cons_name
                      ,LISTAGG ( column_name, ',') WITHIN GROUP (ORDER BY position) child_columns
                  FROM user_cons_columns a
                      ,user_constraints b
                 WHERE a.constraint_name = b.constraint_name AND b.constraint_type = 'R'
                GROUP BY a.table_name, a.constraint_name
                        ,b.r_constraint_name) child
              ,(SELECT a.constraint_name parent_cons_name
                      ,a.table_name parent_tname
                      ,LISTAGG ( column_name, ',') WITHIN GROUP (ORDER BY position) parent_columns
                  FROM user_cons_columns a
                      ,user_constraints b
                 WHERE a.constraint_name = b.constraint_name AND b.constraint_type IN ('P', 'U')
                GROUP BY a.table_name, a.constraint_name) parent
         WHERE child.parent_cons_name = parent.parent_cons_name
           AND (parent.parent_tname LIKE 'V2_%' OR child.child_tname LIKE 'V2_%'))
SELECT DISTINCT disable_pk
  FROM qry0
UNION
SELECT DISTINCT disable_fk
  FROM qry0;

работает как шарм

— Cyryl1972
источник
0

В сценарии "disable" предложение order by должно быть таким:

ORDER BY c.constraint_type DESC, c.last_change DESC

Цель этого пункта - отключить ограничения в правильном порядке.

— Кристиан Чапарро А.
источник
0 
SELECT 'ALTER TABLE '||substr(c.table_name,1,35)|| 
' DISABLE CONSTRAINT '||constraint_name||' ;' 
FROM user_constraints c, user_tables u 
WHERE c.table_name = u.table_name;

Этот оператор возвращает команды, которые отключают все ограничения, включая первичный ключ, внешние ключи и другие ограничения.

— Анкиредди Полу
источник
0

с курсором для цикла (пользователь = 'TRANEE', table = 'D')

declare
    constr all_constraints.constraint_name%TYPE;
begin
    for constr in
        (select constraint_name from all_constraints
        where table_name = 'D'
        and owner = 'TRANEE')
    loop
        execute immediate 'alter table D disable constraint '||constr.constraint_name;
    end loop;
end;
/

(Если вы измените disable на enable, вы можете включить все ограничения)

— диафол
источник
0

Вы можете выполнить все команды, возвращаемые следующим запросом:

выберите «ALTER TABLE» || substr (c.table_name, 1,35) || 'ОТКЛЮЧИТЬ ОГРАНИЧЕНИЕ' || имя_ограничения || ' ; ' from user_constraints c --where c.table_name = 'TABLE_NAME';

— Кристина Базар
источник
Используя наш сайт, вы подтверждаете, что прочитали и поняли нашу Политику в отношении файлов cookie и Политику конфиденциальности.
Licensed under cc by-sa 3.0 with attribution required.