В Windows cmd как запросить ввод пользователя и использовать результат в другой команде?

У меня есть файл Windows .bat, который я хотел бы принять от пользователя, а затем использовать результаты этого ввода как часть вызова дополнительных команд.

Например, я хотел бы принять идентификатор процесса от пользователя, а затем запустить jstack для этого идентификатора, поместив результаты вызова jstack в файл. Однако, когда я пытаюсь это сделать, это не работает.

Вот мой пример содержимого файла bat:

@echo off
set /p id=Enter ID: 
echo %id%
jstack > jstack.txt

и вот что появляется в jstack.txt:

Введите ID: завершить пакетное задание (Y / N)? 

Попробуй это:

@echo off
set /p id="Enter ID: "

Затем вы можете использовать %id%в качестве параметра для другого командного файла, как jstack %id%.

Например:

set /P id=Enter id: 
jstack %id% > jstack.txt

Синтаксис таков: set /p variable=[string]

Посетите http://commandwindows.com/batch.htm или http://www.robvanderwoude.com/userinput.php для более глубокого погружения в пользовательский ввод с различными версиями пакетных файлов ОС Windows.

После того, как вы установили свою переменную, вы можете использовать ее следующим образом.

@echo off
set /p UserInputPath=What Directory would you like?
cd C:\%UserInputPath%

обратите внимание на %VariableName%синтаксис

Я не уверен, так ли это для всех версий Windows, однако на машине с XP у меня должно быть следующее:

set /p Var1="Prompt String"

Без строки подсказки в кавычках я получаю различные результаты в зависимости от текста.

set /p choice= "Please Select one of the above options :" 
echo '%choice%'

Пространство после =очень важно.

@echo off
set /p input="Write something, it will be used in the command "echo""
echo %input%
pause

если я получу то, что вы хотите, это прекрасно работает. Вы также можете использовать% input% в других командах.

@echo off
echo Write something, it will be used in the command "echo"
set /p input=""
cls
echo %input%
pause 

@echo off
:start
set /p var1="Enter first number: "
pause

Для SETX нет задокументированного параметра / параметра приглашения, как для SET.

Если вам нужно запросить переменную окружения, которая выживет после перезагрузки, вы можете использовать SETX для ее хранения.

Переменная, созданная SETX, не будет использоваться, пока вы не перезапустите командную строку. Тем не менее, вы можете установить SETX для переменной, которая уже была SET, даже если она имеет то же имя.

Это работает для меня в Windows 8.1 Pro:

set /p UserInfo= "What is your name?  "
setx UserInfo "%UserInfo%"

(Кавычки вокруг существующей переменной необходимы.)

Эта процедура позволяет вам использовать временную переменную, созданную SET, во время текущего сеанса и позволит вам повторно использовать переменную, созданную SETX, после перезагрузки компьютера или перезапуска приглашения CMD.

(Отредактировано для правильного форматирования абзацев кода.)

У меня есть маленький cmd, который я использую при подготовке компьютера к клиентам: он вызывает пользователя для ввода и переименовывает компьютер в него.

@ECHO "remember to run this as admin."
@ECHO OFF
SET /P _inputname= Please enter an computername:
@ECHO Du intastede "%_inputname%"
@ECHO "The pc will restart after this"
pause
@ECHO OFF
wmic computersystem where name="%COMPUTERNAME%" call rename name="%_inputname%"

shutdown -r -f

Есть две возможности.

1. Вы забыли поставить %id%в jstackвызове.

   jstack %id% > jstack.txt
   

Таким образом, весь правильный пакетный файл должен быть:

@echo off
set /p id=Enter ID: 
echo %id%
jstack %id% > jstack.txt

И / или 2. Вы поместили его в код (и забыли сообщить нам вопрос), но когда вы запустили пакетный файл, вы нажали клавишу Enter вместо ввода идентификатора (скажем, 1234).

То, что происходит, является результатом этих двух ошибок: jstackпредполагается, что он вызывается с идентификатором, который вы ему предоставили.

Но в вашем случае (в соответствии с кодом, который вы указали в вопросе) вы назвали его без какой-либо переменной. Вы написали:

jstack > jstack.txt

Поэтому, когда вы работаете jstackбез переменных, выдается следующее:

Terminate batch file Y/N? 

Ваша вторая ошибка состоит в том, что вы нажали Enter вместо того значения , когда программа спрашивает вас: Enter ID:. Если бы вы в этот момент ввели идентификатор, скажем, 1234, %id%переменная стала бы этим значением, в нашем случае 1234. Но вы НЕ указали значение и вместо этого нажали Enter. Когда вы не даете переменной никакого значения, и если для этой переменной ранее не было установлено ничего, тогда переменная %id%устанавливается на приглашение setкоманды !! Так что теперь %id%установлено значение, Enter ID:которое было отображено на вашем экране в соответствии с запросом в командном файле ДО того, как вы вызвали jstack.

Но я подозреваю, что jstack %id% > jstack.txtу вас в коде командного файла был код %id(и он опущен по ошибке из вопроса), и что вы нажали ввод, не вводя идентификатор. Затем пакетная программа повторила идентификатор, который теперь является «Enter ID:», и затем запустилаjstack Enter ID: > jstack.txt

Jstack сам повторил ввод, обнаружил ошибку и попросил прекратить.
И все это было записано в файл jstack.txt.

Знаки доллара вокруг переменной не работают на моей машине Vista, но знаки процента работают. Также обратите внимание, что между строкой подсказки и вводом пользователя появится завершающий пробел в строке «set».

Просто добавил

set /p NetworkLocation= Enter name for network?

echo %NetworkLocation% >> netlist.txt

последовательность моего netsh пакетной работы. Теперь он показывает мне местоположение, на которое я отвечаю, как точку для этого образца. Я постоянно >> выводил файл, так что теперь я знаю, что такое «дом», «работа», «Starbucks» и т. Д. В поисках чистого воздуха я могу определить каналы с самым низким уровнем использования и есть ли 5 ​​или только все 2,4 МГц WLAN вокруг.

Просто чтобы сохранить значение по умолчанию для переменной. Нажмите Enter, чтобы использовать значение по умолчанию из последнего запуска вашего .bat:

@echo off
set /p Var1=<Var1.txt
set /p Var1="Enter new value ("%Var1%") "
echo %Var1%> Var1.txt

rem YourApp %Var1%

При первом запуске просто проигнорируйте сообщение об отсутствии файла с начальным значением переменной (или создайте Var1.txt вручную).