Как использовать структуру if - else в командном файле?

У меня есть вопрос о структуре if-else в командном файле. Каждая команда выполняется индивидуально, но я не смог безопасно использовать блоки if - else, поэтому эти части моей программы не работают. Как я могу заставить эти части работать? Спасибо.

IF %F%==1 IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )
ELSE IF %F%==1 IF %C%==0 (
    ::moving the file c to d
    move "%sourceFile%" "%destinationFile%"
    )

ELSE IF %F%==0 IF %C%==1 (
    ::copying a directory c from d, /s:  boş olanlar hariç, /e:boş olanlar dahil
    xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
    )
ELSE IF %F%==0 IF %C%==0 (
    ::moving a directory
    xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
    rd /s /q "%sourceMoveDirectory%"
    )

Ваш синтаксис неверен. Вы не можете использовать ELSE IF. Похоже, что вам все равно это не нужно. Просто используйте несколько IFутверждений:

IF %F%==1 IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )

IF %F%==1 IF %C%==0 (
    ::moving the file c to d
    move "%sourceFile%" "%destinationFile%"
    )

IF %F%==0 IF %C%==1 (
    ::copying a directory c from d, /s:  boş olanlar hariç, /e:boş olanlar dahil
    xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
    )

IF %F%==0 IF %C%==0 (
    ::moving a directory
    xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
    rd /s /q "%sourceMoveDirectory%"
    )

Отличная ссылка на пакетный файл: http://ss64.com/nt/if.html

Я думаю, что в вопросе и в некоторых ответах есть некоторая путаница относительно значения этого псевдокода в DOS: ЕСЛИ A ЕСЛИ BX ДАЛЕЕ Y. Это не означает IF (A и B) THEN X ELSE Y, но в Факт означает, ЕСЛИ А (ЕСЛИ В, ТО X, ИЛИ Y). Если проверка A не удалась, тогда он полностью игнорирует внутреннее if-else.

Как упоминалось в одном из ответов, в этом случае только один из тестов может быть успешным, поэтому «else» не требуется, но, конечно, это работает только в этом примере, это не общее решение для выполнения if-else.

Есть много способов обойти это. Вот несколько идей, все они довольно уродливы, но, эй, это (или, по крайней мере, было) DOS!

@echo off

set one=1
set two=2

REM Example 1

IF %one%_%two%==1_1 (
   echo Example 1 fails
) ELSE IF %one%_%two%==1_2 (
   echo Example 1 works correctly
) ELSE (
    echo Example 1 fails
)

REM Example 2

set test1result=0
set test2result=0

if %one%==1 if %two%==1 set test1result=1
if %one%==1 if %two%==2 set test2result=1

IF %test1result%==1 (
   echo Example 2 fails
) ELSE IF %test2result%==1 (
   echo Example 2 works correctly
) ELSE (
    echo Example 2 fails
)

REM Example 3

if %one%==1 if %two%==1 (
   echo Example 3 fails
   goto :endoftests
)
if %one%==1 if %two%==2 (
   echo Example 3 works correctly
   goto :endoftests
)
echo Example 3 fails
)
:endoftests

AFAIK, вы не можете делать if elseв пакетном режиме, как вы можете на других языках, он должен быть вложенным if.

Используя nested if, ваша партия будет выглядеть

IF %F%==1 IF %C%==1(
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    ) ELSE (
        IF %F%==1 IF %C%==0(
        ::moving the file c to d
        move "%sourceFile%" "%destinationFile%"
        ) ELSE (
            IF %F%==0 IF %C%==1(
            ::copying a directory c from d, /s:  boş olanlar hariç, /e:boş olanlar dahil
            xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
            ) ELSE (
                IF %F%==0 IF %C%==0(
                ::moving a directory
                xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
                rd /s /q "%sourceMoveDirectory%"
                )
            )
        )
    )

или, как предположил Джеймс, зацепите свои if, однако я думаю, что правильный синтаксис

IF %F%==1 IF %C%==1(
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )

Я считаю, что вы можете использовать что-то такое, как

if ___ (

do this

) else if ___ (

do this

)

Немного опоздал и, возможно, все еще хорош для сложных условий if, потому что я хотел бы добавить параметр "done", чтобы сохранить структуру if-then-else:

set done=0
if %F%==1 if %C%==0 (set done=1 & echo found F=1 and C=0: %F% + %C%)
if %F%==2 if %C%==0 (set done=1 & echo found F=2 and C=0: %F% + %C%)
if %F%==3 if %C%==0 (set done=1 & echo found F=3 and C=0: %F% + %C%)
if %done%==0 (echo do something)

IF...ELSE IF конструкции хорошо работают в пакетных файлах, особенно когда вы используете только одно условное выражение в каждой строке IF:

IF %F%==1 (
    ::copying the file c to d
    copy "%sourceFile%1" "%destinationFile1%"
) ELSE IF %F%==0 (
    ::moving the file e to f
    move "%sourceFile2%" "%destinationFile2%" )

В вашем примере вы используете IF...AND...IFконструкцию типа, где 2 условия должны выполняться одновременно. В этом случае вы все еще можете использовать IF...ELSE IFконструкцию, но с дополнительными скобками, чтобы избежать неопределенности для следующего условия ELSE:

IF %F%==1 (IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile1%" "%destinationFile1%" )
) ELSE IF %F%==1 (IF %C%==0 (
    ::moving the file e to f
    move "%sourceFile2%" "%destinationFile2%"))

Вышеуказанная конструкция эквивалентна:

IF %F%==1 (
    IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile1%" "%destinationFile1%"
    ) ELSE IF %C%==0 (
    ::moving the file e to f
    move "%sourceFile2%" "%destinationFile2%"))

Последовательность обработки пакетных команд зависит от порядка разбора CMD.exe . Просто убедитесь, что ваша конструкция соответствует этому логическому порядку, и, как правило, она будет работать. Если ваш пакетный скрипт обрабатывается Cmd.exe без ошибок, это означает, что это правильная (т.е. поддерживается вашей версией ОС Cmd.exe) конструкция, даже если кто-то сказал иначе.

Вот мой пример кода для if..else..if
которые делают следующее

Запрашивать у пользователя имя процесса

Если имя процесса недопустимо, то
оно пишется пользователю

Error : The Processor above doesn't seem to be exist 

если имя процесса - services, то
оно пишется пользователю

Error : You can't kill the Processor above 

если имя процесса является действительным, а не службами, то
оно пишется пользователю

процесс был убит с помощьюtaskill

так я назвал это Process killer.bat
Вот мой код:

@echo off

:Start
Rem preparing the batch  
cls
Title Processor Killer
Color 0B
Echo Type Processor name to kill It (Without ".exe")
set /p ProcessorTokill=%=%  

:tasklist
tasklist|find /i "%ProcessorTokill%.exe">nul & if errorlevel 1 (
REM check if the process name is invalid 
Cls 
Title %ProcessorTokill% Not Found
Color 0A
echo %ProcessorTokill%
echo Error : The Processor above doesn't seem to be exist    

) else if %ProcessorTokill%==services (
REM check if the process name is services and doesn't kill it
Cls 
Color 0c
Title Permission denied 
echo "%ProcessorTokill%.exe"
echo Error : You can't kill the Processor above 

) else (
REM if the process name is valid and not services
Cls 
Title %ProcessorTokill% Found
Color 0e
echo %ProcessorTokill% Found
ping localhost -n 2 -w 1000>nul
echo Killing %ProcessorTokill% ...
taskkill /f /im %ProcessorTokill%.exe /t>nul
echo %ProcessorTokill% Killed...
)

pause>nul



REM If else if Template
REM if thing1 (
REM Command here 2 ! 
REM ) else if thing2 (
REM command here 2 !
REM ) else (
REM command here 3 !
REM )

вот как я справился, если еще, если ситуация

if %env%==dev ( 
    echo "dev env selected selected"
) else (
    if %env%==prod (
        echo "prod env selected"
    )
)

Обратите внимание, что он не совпадает с блоком if-elseif, как другие языки программирования, такие как C ++ или Java, но он будет делать то, что вам нужно