Как активировать C ++ 11 в CMake?

Когда я пытаюсь запустить созданный CMake make-файл для компиляции моей программы, я получаю сообщение об ошибке

Диапазон, основанный на циклах, не поддерживается в режиме C ++ 98.

Я пытался добавить add_definitions(-std=c++0x)в мой CMakeLists.txt, но это не помогло.

Я тоже это попробовал:

if(CMAKE_COMPILER_IS_GNUCXX)
    add_definitions(-std=gnu++0x)
endif()

Когда я делаю g++ --version, я получаю:

g ++ (Ubuntu / Linaro 4.6.1-9ubuntu3) 4.6.1

Я тоже попробовал SET(CMAKE_CXX_FLAGS "-std=c++0x"), что тоже не работает.

Я не понимаю, как я могу активировать функции C ++ 11 с помощью CMake.

CMake 3.1 представил переменную CMAKE_CXX_STANDARD, которую вы можете использовать. Если вы знаете, что у вас всегда будет доступен CMake 3.1, вы можете просто написать это в своем файле CMakeLists.txt верхнего уровня или поместить его прямо перед тем, как будет определена любая новая цель:

set (CMAKE_CXX_STANDARD 11)

Если вам нужно поддерживать более старые версии CMake, вот макрос, который я придумал, который вы можете использовать:

macro(use_cxx11)
  if (CMAKE_VERSION VERSION_LESS "3.1")
    if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
      set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
    endif ()
  else ()
    set (CMAKE_CXX_STANDARD 11)
  endif ()
endmacro(use_cxx11)

Макрос поддерживает только GCC прямо сейчас, но он должен быть прост, чтобы распространить его на другие компиляторы.

Затем вы можете написать use_cxx11()в верхней части любого файла CMakeLists.txt, который определяет цель, которая использует C ++ 11.

CMake выпуск № 15943 для пользователей clang, ориентированных на macOS

Если вы используете CMake и clang для нацеливания на macOS, существует ошибка, которая может привести к тому, что эта CMAKE_CXX_STANDARDфункция просто не будет работать (не добавлять какие-либо флаги компилятора). Убедитесь, что вы делаете одну из следующих вещей:

• Используйте cmake_minimum_required, чтобы требовать CMake 3.0 или новее, или

• Установите для политики CMP0025 значение NEW с помощью следующего кода в верхней части файла CMakeLists.txt перед projectкомандой:

  # Fix behavior of CMAKE_CXX_STANDARD when targeting macOS.
  if (POLICY CMP0025)
    cmake_policy(SET CMP0025 NEW)
  endif ()

Команда CMake target_compile_features()используется для указания требуемой функции C ++ cxx_range_for. Затем CMake индуцирует использование стандарта C ++.

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
add_executable(foobar main.cc)
target_compile_features(foobar PRIVATE cxx_range_for)

Нет необходимости использовать add_definitions(-std=c++11)или изменять переменную CMake CMAKE_CXX_FLAGS, потому что CMake будет следить за тем, чтобы компилятор C ++ вызывался с соответствующими флагами командной строки.

Возможно, ваша программа на C ++ использует другие функции, кроме C ++ cxx_range_for. Глобальное свойство CMake CMAKE_CXX_KNOWN_FEATURESсодержит список функций C ++, которые вы можете выбрать.

Вместо использования target_compile_features()вы также можете явно указать стандарт C ++, установив свойства CMake CXX_STANDARD и CXX_STANDARD_REQUIREDдля вашей цели CMake.

Смотрите также мой более подробный ответ .

я использую

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
        message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()

Но если вы хотите поиграть C++11, g++ 4.6.1довольно старый. Попробуйте получить более новую g++версию.

Самый простой способ установить стандарт Cxx:

 set_property(TARGET tgt PROPERTY CXX_STANDARD 11)

Смотрите документацию CMake для более подробной информации.

Оказывается, SET(CMAKE_CXX_FLAGS "-std=c++0x")активирует многие функции C ++ 11. Причина, по которой это не сработало, заключалась в том, что заявление выглядело так:

set(CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

Следуя такому подходу, -std=c++0xфлаг как-то был перезаписан, и он не работал. Установка флагов одна за другой или использование метода списка работает.

list( APPEND CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

Самый простой способ:

add_compile_options(-std=c++11)

Для CMake 3.8 и новее вы можете использовать

target_compile_features(target PUBLIC cxx_std_11)

Это еще один способ включить поддержку C ++ 11,

ADD_DEFINITIONS(
    -std=c++11 # Or -std=c++0x
    # Other flags
)

Я встречал случаи, когда только этот метод работает, а другие методы не работают. Возможно, это как-то связано с последней версией CMake.

На современном CMake (> = 3.1) лучший способ установить глобальные требования:

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

Это означает: «Я хочу C ++ 11 для всех целей, это не обязательно, я не хочу использовать какие-либо расширения GNU или Microsoft». Начиная с C ++ 17, это ИМХО лучший способ.

Источник: Включение C ++ 11 и позже в CMake

Что работает для меня, это установить следующую строку в вашем CMakeLists.txt:

set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

Установка этой команды активирует функции C ++ 11 для компилятора, и после выполнения cmake ..команды вы сможете использовать ее range based for loopsв своем коде и скомпилировать его без каких-либо ошибок.

Я думаю, что только этих двух строк достаточно.

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

Если вы хотите всегда активировать последний стандарт C ++, вот мое расширение ответа Дэвида Грейсона в свете недавних (CMake 3.8 и CMake 3.11) добавлений значений 17 и 20 для CMAKE_CXX_STANDARD):

IF (CMAKE_VERSION VERSION_LESS "3.8")
    SET(CMAKE_CXX_STANDARD 14)
ELSEIF (CMAKE_VERSION VERSION_LESS "3.11")
    SET(CMAKE_CXX_STANDARD 17)
ELSE()
    SET(CMAKE_CXX_STANDARD 20)
ENDIF()

# Typically, you'll also want to turn off compiler-specific extensions:
SET(CMAKE_CXX_EXTENSIONS OFF)

(Используйте этот код вместо set (CMAKE_CXX_STANDARD 11)связанного ответа.)

Современный cmake предлагает более простые способы настройки компиляторов для использования конкретной версии C ++. Единственное, что нужно сделать, это установить соответствующие целевые свойства. Среди свойств, поддерживаемых cmake , есть те, которые используются для определения того, как настроить компиляторы для поддержки конкретной версии C ++:

• CXX_STANDARDустанавливает стандарт C ++, функции которого запрашиваются для создания цели. Установите это как 11цель C ++ 11.

• CXX_EXTENSIONS, логическое значение, указывающее, запрашиваются ли специфичные для компилятора расширения. Установка этого параметра Offотключает поддержку любого конкретного расширения компилятора.

Чтобы продемонстрировать, вот минимальный рабочий пример CMakeLists.txt.

cmake_minimum_required(VERSION 3.1)

project(testproject LANGUAGES CXX )

set(testproject_SOURCES
    main.c++
    )

add_executable(testproject ${testproject_SOURCES})

set_target_properties(testproject
    PROPERTIES
    CXX_STANDARD 11
    CXX_EXTENSIONS off
    )

OS X и Homebrew LLVM связаны с:

Не забудьте вызвать cmake_minimum_required (VERSION 3.3) и project () после него!

Или CMake вставит project()неявно перед строкой 1, вызывая проблемы с обнаружением версии Clang и, возможно, другие виды проблем. Вот связанная проблема .