Правильное использование транзакций в SQL Server

236

У меня есть 2 команды, и обе они должны быть выполнены правильно, или ни одна из них не выполнена. Я думаю, что мне нужна транзакция, но я не знаю, как правильно ее использовать.

В чем проблема со следующим скриптом?

BEGIN TRANSACTION [Tran1]

INSERT INTO [Test].[dbo].[T1]
    ([Title], [AVG])
VALUES ('Tidd130', 130), ('Tidd230', 230)

UPDATE [Test].[dbo].[T1]
  SET [Title] = N'az2' ,[AVG] = 1
  WHERE [dbo].[T1].[Title] = N'az'

COMMIT TRANSACTION [Tran1]
GO

Команда INSERTвыполнена, но у UPDATEкоманды есть проблема.

Как я могу реализовать это для отката обеих команд, если какая-либо из них имеет ошибку в выполнении?

— Сейед
источник

513

Добавьте блок try / catch, если транзакция завершится успешно, изменения будут зафиксированы, если транзакция не удалась, откат транзакции:

BEGIN TRANSACTION [Tran1]

  BEGIN TRY

      INSERT INTO [Test].[dbo].[T1] ([Title], [AVG])
      VALUES ('Tidd130', 130), ('Tidd230', 230)

      UPDATE [Test].[dbo].[T1]
      SET [Title] = N'az2' ,[AVG] = 1
      WHERE [dbo].[T1].[Title] = N'az'

      COMMIT TRANSACTION [Tran1]

  END TRY

  BEGIN CATCH

      ROLLBACK TRANSACTION [Tran1]

  END CATCH

— Даррен
источник

1

Не должны BEGIN TRANSACTION [Tran1]быть помещены внутрь TRY? Во всяком случае - очень простой и элегантный кусок кода.

— Петр Наврот

4

@PiotrNawrot Нет, если создание транзакции не удалось, нет необходимости откатывать ее в перехвате.

— Монсеньор

114

В начале хранимой процедуры необходимо установить SET XACT_ABORT ON, чтобы Sql Server дал команду автоматически откатить транзакцию в случае ошибки. Если он опущен или имеет значение OFF, необходимо проверять @@ ERROR после каждого оператора или использовать блок отката TRY ... CATCH .

— Никола Марковинович
источник

2

Другими словами, ваша транзакция не является атомарной, если вы сначала не установили XACT_ABORT ON.

— утра

Трудно увидеть с подчеркиванием URL, но есть подчеркиваниеXACT_ABORT

— BurnsBA

32

Легкий подход:

CREATE TABLE T
(
    C [nvarchar](100) NOT NULL UNIQUE,
);

SET XACT_ABORT ON -- Turns on rollback if T-SQL statement raises a run-time error.
SELECT * FROM T; -- Check before.
BEGIN TRAN
    INSERT INTO T VALUES ('A');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('C');
COMMIT TRAN
SELECT * FROM T; -- Check after.
DELETE T;

— Богдана
источник