Как я могу немедленно покинуть Ediff, не набирая 'y'?

Когда я бросаю курить, qменя спрашивают, действительно ли я хочу бросить. Я бы предпочел, чтобы это немедленно прекратилось. Там нет ничего очевидного при настройке . Существует решение здесь , который , кажется , на работу, пересматривая qключ, но я не уверен в деталях , как работает функция. Какой самый простой способ заставить бросить курить означает «бросить курить»?

Вы можете посоветовать, ediff-quitчтобы он динамически связывался y-or-n-pс возвращаемой функцией t.

(defun disable-y-or-n-p (orig-fun &rest args)
  (cl-letf (((symbol-function 'y-or-n-p) (lambda (prompt) t)))
    (apply orig-fun args)))

(advice-add 'ediff-quit :around #'disable-y-or-n-p)

Это более надежно, чтобы пересмотреть изменения, чем переопределить ediff-quit.

К сожалению, я думаю, вам нужно либо перепривязать q, либо настроить источник ediff-quit. Как видно в источнике ediff-quitподсказка всегда бывает.

(defun ediff-quit (reverse-default-keep-variants)
  "Finish an Ediff session and exit Ediff.
Unselects the selected difference, if any, restores the read-only and modified
flags of the compared file buffers, kills Ediff buffers for this session
\(but not buffers A, B, C\).

If `ediff-keep-variants' is nil, the user will be asked whether the buffers
containing the variants should be removed \(if they haven't been modified\).
If it is t, they will be preserved unconditionally.  A prefix argument,
temporarily reverses the meaning of this variable."
  (interactive "P")
  (ediff-barf-if-not-control-buffer)
  (let ((ctl-buf (current-buffer))
    (ctl-frm (selected-frame))
    (minibuffer-auto-raise t))
    (if (y-or-n-p (format "Quit this Ediff session%s? "
              (if (ediff-buffer-live-p ediff-meta-buffer)
                  " & show containing session group" "")))
    (progn
      (message "")
      (set-buffer ctl-buf)
      (ediff-really-quit reverse-default-keep-variants))
      (select-frame ctl-frm)
      (raise-frame ctl-frm)
      (message ""))))

Я бы посоветовал переопределить ediff-quitв вашем .emacsи отправить патч к источнику, добавив переменную настройки.

Помните, что источник реализации в emacs всегда находится в нескольких нажатиях клавиш. Предполагая, что источники elisp установлены, введите C-h f, введите имя функции и перейдите по ссылке, где оно определено.

Я использую следующую повторную привязку q в ediff. Если какой-либо из буферов изменен, он спрашивает, должны ли они быть сохранены, тогда он просто выходит. Если никакие буферы не изменены, он просто выходит.

(add-hook 'ediff-startup-hook
          (lambda ()
            (local-set-key (kbd"q") 'my-ediff-quit)))

(defun my-ediff-quit ()
  "If any of the ediff buffers have been modified, ask if changes
should be saved. Then quit ediff normally, without asking for
confirmation"
  (interactive)
  (ediff-barf-if-not-control-buffer)
  (let* ((buf-a ediff-buffer-A)
         (buf-b ediff-buffer-B)
         (buf-c ediff-buffer-C)
         (ctl-buf (current-buffer))
         (modified (remove-if-not 'buffer-modified-p
                                  (list buf-a buf-b buf-c))))
    (let ((save (if modified (yes-or-no-p "Save changes?")nil)))
      (loop for buf in modified do
            (progn
              (set-buffer buf)
              (if save
                  (save-buffer)
                (set-buffer-modified-p nil))))
      (set-buffer ctl-buf)
      (ediff-really-quit nil))))