Как мне наследовать от prog-mode, при этом поддерживая старый emacsen?

Я пишу основной режим для языка программирования, но я хочу поддерживать более старые версии Emacs. prog-modeотносительно новый. Я хочу унаследовать, prog-modeесли он определен, но все же сделать что-то разумное в противном случае.

Какой лучший подход? Должен ли я использовать defalias prog-modeболее старый Emacsen, или это будет мешать другим режимам, если они будут делать то же самое?

За счет дополнительной привязки символов верхнего уровня, есть очень аккуратное решение, которое позволяет избежать повторения define-derived-modeформы:

(defalias 'my-fancy-parent-mode
  (if (fboundp 'prog-mode) 'prog-mode 'fundamental-mode))

(define-derived-mode my-fancy-mode my-fancy-parent-mode
   ...)

Работает нормально в любом Emacs> = 23. Я придумал это haml-modeпару лет назад IIRC, и, похоже, он распространился оттуда на несколько других основных режимов. Главное, что define-derived-modeмакрос делает с символом родительского режима, - это генерирует код, который вызывает его функцию: в этом смысле defaliasновая переменная в точности эквивалентна псевдонимной функции.

Одно предостережение в том, что это может сбить с толку derived-mode-p, поэтому код, который проверяет, является ли ваш режим полученным, prog-modeможет работать некорректно. На практике я не сталкивался с какими-либо проблемами: для такого кода более привычно подключаться prog-mode-hook, который все еще запускается.

(Как указывает Йорген в комментариях, он define-derived-modeтакже использует mode-classсвойство из символа родительского режима и defaliasне будет копировать его. На момент написания этого свойства, кажется, его использовали только дляspecial-mode .)

Обновление: в эти дни я бы просто предложил требовать как минимум Emacs 24, так как старые версии давно устарели.

tl; dr: Используйте ifи свою собственную функцию инициализации:

(if (fboundp 'prog-mode)
    (define-derived-mode your-cool-mode prog-mode "Cool"
      "Docstring"
      (your-cool--init))
  (define-derived-mode your-cool-mode nil "Cool"
    "Docstring"
    (your-cool--init)))

Затем выполните инициализацию всего режима в your-cool-init.

Более длинное объяснение:

Проблема в том, что официальным способом написания производного основного режима является использование define-derived-modeмакроса:

(define-derived-mode your-cool-mode prog-mode ...)

На старшем Emacsen (до 24) это ломается когда prog-mode. И вы не можете использовать его (if (fboundp 'prog-mode) ...)там, потому что макрос ожидает буквальный символ и процитирует его для вас в расширении.

define-derived-modeиспользует родителя множеством способов. Вам нужно будет скопировать все из них в своем собственном определении режима, чтобы использовать их, и это утомительно и подвержено ошибкам.

Таким образом, единственный способ - использовать два разных define-derived-modeутверждения, в зависимости от того, prog-modeсуществует или нет. Это оставляет вас с проблемой написания вашего кода инициализации дважды. Что, конечно, плохо, поэтому вы извлекаете это в свою собственную функцию, как описано выше.

(Лучшее решение - это, конечно, отказаться от поддержки 23.x и использовать лексическую область видимости. Но я думаю, что вы уже рассмотрели и отказались от этой опции. :-))

Я думаю, что использование тестирования fboundpимеет больше смысла.

(if (fboundp 'prog-mode)
    ...
   ...)

Вы можете определить макрос-обертку, define-derived-modeкоторый оценивает его аргументы.

(defmacro define-derived-mode* (child parent name &optional docstring &rest body)
  (macroexpand `(define-derived-mode ,(eval child) ,(eval parent) ,(eval name)
                                     ,(eval docstring) . ,body)))
(define-derived-mode* 'toy-mode
  (if (fboundp 'prog-mode) 'prog-mode 'fundamental-mode)
  "Toy"
  "Major mode for my favorite toy language"
  (toy-mode-setup))

(Предупреждение: только минимально проверено.)