Как я могу быстро переключаться между файлом и буфером * scratch * с одинаковым основным режимом?

Время от времени, работая над кодом, полезно быстро открыть буфер «нуля», чтобы вставить фрагмент из этого файла кода.

Если я работаю над сценарием Perl, я хотел бы быстро открыть буфер * scratch * с помощью in cperl-mode. Также было бы неплохо быстро вернуться к буферу кода, в котором я изначально работал.

Будет удобно привязать приведенную ниже функцию к привязке клавиш по вашему выбору. Если вы в данный момент работаете с FILEбуфером, вызов нижеприведенной функции переключит между FILEвызванным * специфичным для основного режима буфером * scratch * *scratch-MAJOR-MODE*и FILEбуфером.

Учитывая рассматриваемый пример, если я работаю над скриптом Perl myperl.pl, вызываемым эта функция переключается между myperl.plи *scratch-cperl-mode*.

(defun modi/switch-to-scratch-and-back (&optional arg)
  "Toggle between *scratch-MODE* buffer and the current buffer.
If a scratch buffer does not exist, create it with the major mode set to that
of the buffer from where this function is called.

        COMMAND -> Open/switch to a scratch buffer in the current buffer's major mode
    C-0 COMMAND -> Open/switch to a scratch buffer in `fundamental-mode'
    C-u COMMAND -> Open/switch to a scratch buffer in `org-mode'
C-u C-u COMMAND -> Open/switch to a scratch buffer in `emacs-elisp-mode'

Even if the current major mode is a read-only mode (derived from `special-mode'
or `dired-mode'), we would want to be able to write in the scratch buffer. So
the scratch major mode is set to `org-mode' for such cases.

Return the scratch buffer opened."
  (interactive "p")
  (if (and (or (null arg)               ; no prefix
               (= arg 1))
           (string-match-p "\\*scratch" (buffer-name)))
      (switch-to-buffer (other-buffer))
    (let* ((mode-str (cl-case arg
                       (0  "fundamental-mode") ; C-0
                       (4  "org-mode") ; C-u
                       (16 "emacs-lisp-mode") ; C-u C-u
                       ;; If the major mode turns out to be a `special-mode'
                       ;; derived mode, a read-only mode like `help-mode', open
                       ;; an `org-mode' scratch buffer instead.
                       (t (if (or (derived-mode-p 'special-mode) ; no prefix
                                  (derived-mode-p 'dired-mode))
                              "org-mode"
                            (format "%s" major-mode)))))
           (buf (get-buffer-create (concat "*scratch-" mode-str "*"))))
      (switch-to-buffer buf)
      (funcall (intern mode-str))   ; http://stackoverflow.com/a/7539787/1219634
      buf)))