Показать номер строки при ошибке

Скажем, что Emacs выдает ошибку, которую я не понимаю. Или, возможно, ошибка говорит: «Значение символа как переменной - void: mode», но modesв моем коде встречается много символов , поэтому мне нужен некоторый контекст. Можно ли настроить Emacs для указания номера строки кода lisp, чтобы я мог знать, какой код вызывает ошибку?

Я попытался сделать (setq stack-trace-on-error '(buffer-read-only))и запустил исполняющий код, чтобы получить трассировку стека. Нет трассировки стека либо.

Я также попытался вызвать edebug-defunсвою функцию и пройти через нее. Только когда я выхожу из функции, появляется ошибка.

(Я на самом деле не так интересуюсь причиной конкретной ошибки, с которой я сталкиваюсь в настоящее время, поскольку я занимаюсь разработкой общих навыков отладки для elisp. Пожалуйста, посоветуйте, как я могу подсвечивать номер строки, или sexp, или трассировку стека из ошибка.)

Emacs обеспечивает хорошее количество средств отладки , включая M-x toggle-debug-on-error, M-x toggle-debug-on-quit, отлаживать на сигнал (который может быть использован, посылая USR2в Emacs извне), debug-on-entry(из функции), debug-on-message(при виде конкретных регулярное выражение матч сообщения) и , наконец, debugв качестве альтернативы чтобы оснастить функцию с C-u C-M-x.

И то, debugи другое edebugпредлагает достаточно функций для проверки состояния Emacs при оценке кода, который вас интересует, нажмите eи введите выражение.

Однако, хотя edebugпереходит к месту в инструментальной функции и, следовательно, дает вам подсказку, где искать (что довольно глупо, поскольку вы уже знаете, что именно вы инструментировали), это debugвообще не делается. Я выполнил небольшой хак, обнаружив, что всякий раз, когда debugоценивается буфер, он выдает значение точки, связанной с ошибкой; другими словами, использование этой информации в буфере может дать вам номер строки в обратном следе!

(with-eval-after-load 'debug
  (defun debugger-setup-buffer (debugger-args)
    "Initialize the `*Backtrace*' buffer for entry to the debugger.
That buffer should be current already."
    (setq buffer-read-only nil)
    (erase-buffer)
    (set-buffer-multibyte t)        ;Why was it nil ?  -stef
    (setq buffer-undo-list t)
    (let ((standard-output (current-buffer))
          (print-escape-newlines t)
          (print-level 8)
          (print-length 50))
      (backtrace))
    (goto-char (point-min))
    (delete-region (point)
                   (progn
                     (search-forward "\n  debug(")
                     (forward-line (if (eq (car debugger-args) 'debug)
                                       2    ; Remove implement-debug-on-entry frame.
                                     1))
                     (point)))
    (insert "Debugger entered")
    ;; lambda is for debug-on-call when a function call is next.
    ;; debug is for debug-on-entry function called.
    (pcase (car debugger-args)
      ((or `lambda `debug)
       (insert "--entering a function:\n"))
      ;; Exiting a function.
      (`exit
       (insert "--returning value: ")
       (setq debugger-value (nth 1 debugger-args))
       (prin1 debugger-value (current-buffer))
       (insert ?\n)
       (delete-char 1)
       (insert ? )
       (beginning-of-line))
      ;; Debugger entered for an error.
      (`error
       (insert "--Lisp error: ")
       (prin1 (nth 1 debugger-args) (current-buffer))
       (insert ?\n))
      ;; debug-on-call, when the next thing is an eval.
      (`t
       (insert "--beginning evaluation of function call form:\n"))
      ;; User calls debug directly.
      (_
       (insert ": ")
       (prin1 (if (eq (car debugger-args) 'nil)
                  (cdr debugger-args) debugger-args)
              (current-buffer))
       (insert ?\n)))
    ;; After any frame that uses eval-buffer,
    ;; insert a line that states the buffer position it's reading at.
    (save-excursion
      (let ((tem eval-buffer-list))
        (while (and tem
                    (re-search-forward "^  eval-\\(buffer\\|region\\)(" nil t))
          (beginning-of-line)
          (insert (format "Error at line %d in %s: "
                          (with-current-buffer (car tem)
                            (line-number-at-pos (point)))
                          (with-current-buffer (car tem)
                            (buffer-name))))
          (pop tem))))
    (debugger-make-xrefs)))

При этом следует ответить на оригинальный вопрос в названии. Что касается вашей проблемы с получением обратного следа, то у меня нет полезных идей.

Может быть, потому что сейчас 2018, но в моем случае мне нужно было только включить отладку, как предложил васамаса: Mx toggle-debug-on-error

После этого Mx eval-buffer в моем неисправном файле Elisp предоставил контекст, указав позицию ошибки, например: Debugger entered--Lisp error: (invalid-read-syntax ")") eval-buffer() ; Reading at buffer position 523 [....]

Mx goto-char переходит в позицию ошибки: M-x goto-char 523

Я расширил ответ Васамасы, включив в него дополнительную информацию:

(save-excursion
  (let ((tem eval-buffer-list))
    (while (and tem
                (re-search-forward "^  eval-\\(buffer\\|region\\)(" nil t))
      (beginning-of-line)
      (insert (apply 'format "Error at line %d, column %d (point %d) in %s\n"
                     (with-current-buffer (car tem)
                       (list (line-number-at-pos (point))
                             (current-column)
                             (point)
                             (buffer-name)))))
      (pop tem))))