Скажем, у меня есть код elisp вроде:

(+ 2 3▮(+ 3
          4))

Есть ли способ автоматически сделать отступ в сексе после курсора, когда я добавляю или удаляю символы?

Поэтому после нажатия SPC 4 SPCя бы автоматически получил:

(+ 2 3 4 ▮(+ 3
             4))

Я могу сделать это руководство, позвонив, mark-sexpа затем indent-region. Есть ли лучшие способы сделать это?

Вместо mark-sexp+ indent-regionвы можете нажать C-M-q. Это позвонит indent-pp-sexp. Не автоматически, но немного лучше, чем вызывать две команды.

Или, если вы используете paredit-mode, нажмите M-q. Это переопределяет все определение функции, в котором вы находитесь.

Агрессивный режим отступа

Поскольку некоторые люди просили об этом, я превратил этот ответ в пакет .

Если у вас настроен Melpa, вы можете установить его с

M-x package-install RET aggressive-indent

См. Readme для всех опций, но самый простой способ включить его:

(add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)

Старый ответ

Следующее делает авто-отступ только для буферов elisp. Он также имеет преимущество работы, когда вы стираете или дергаете вещи (вместо того, чтобы просто печатать). Это легко добавить и в другие режимы.

Эта функция будет делать отступ для любого s-выражения, внутри которого находится точка. Вы можете привязать его к клавише, если хотите, но сначала смотрите ниже.

(require 'cl-lib)

(defun endless/indent-defun ()
  "Indent current defun.
Do nothing if mark is active (to avoid deactivating it), or if
buffer is not modified (to avoid creating accidental
modifications)."
  (interactive)
  (ignore-errors
    (unless (or (region-active-p)
                buffer-read-only
                (null (buffer-modified-p)))
      (let ((l (save-excursion (beginning-of-defun 1) (point)))
            (r (save-excursion (end-of-defun 1) (point))))
        (cl-letf (((symbol-function 'message) #'ignore))
          (indent-region l r))))))

Этот хук сделает так, что эта функция будет запускаться после того, как вы что-нибудь напечатаете, но только в буферах elisp. Это должно держать все всегда с отступом.

(add-hook
 'emacs-lisp-mode-hook
 (lambda ()
   (add-hook 'post-command-hook
             #'endless/indent-defun nil 'local)))

Попытайся! Это работает замечательно хорошо.

Кроме того, следуя предложению @ holocronweaver в комментариях, вы можете использовать что-то вроде следующего для c-подобных языков:

(define-key c++-mode-map ";"
  (lambda () (interactive)
    (insert ";")
    (endless/indent-defun)))

Я не знаю о ранее существовавшем решении, но вы можете использовать это, post-self-insert-hookчтобы выполнить это самостоятельно:

(defun my-indent-next-sexp ()
  (interactive)
  (mark-sexp)
  (indent-region))

(add-hook 'post-self-insert-hook 'my-indent-next-sexp)

Я бы беспокоился о потенциальных проблемах с производительностью.

Вы можете попробовать режим el-fly-indent-mode , который более хорош, чем aggressive-indent-modeпри работе с Elisp.