Скрыть * окно компиляции *

20

Досадно видеть, что окно компиляции появляется, когда оно успешно. Как удалить это автоматически?

Я хочу видеть это, хотя, если это не успешно.

window compilation

11

Несколько лет назад на IRC-канале #emacs я получил этот фрагмент кода, который использовал всегда. Значение «2 сек» устанавливает время, в течение которого окно успешной компиляции остается видимым.

; from enberg on #emacs
(setq compilation-finish-function
  (lambda (buf str)
    (if (null (string-match ".*exited abnormally.*" str))
        ;;no errors, make the compilation window go away in a few seconds
        (progn
          (run-at-time
           "2 sec" nil 'delete-windows-on
           (get-buffer-create "*compilation*"))
          (message "No Compilation Errors!")))))

— shapr
источник

14

Глядя быстро на код (в библиотеке compile.el), вы сможете просто убить или скрыть отображаемый буфер, используя функцию на крючке compilation-finish-functions. Для этого используйте что-то вроде этого:

 (add-hook 'compilation-finish-functions (lambda (buf strg) (kill-buffer buf))

Если вы не хотите уничтожать буфер, используйте что-то вроде этого:

 (add-hook 'compilation-finish-functions
           (lambda (buf strg)
             (let ((win  (get-buffer-window buf 'visible)))
               (when win (delete-window win)))))

В общем, вы можете себе представить, что для чего-то подобного, вероятно, уже имеется зацепка, поэтому вы можете легко прикрепить код на столь значимое место в процессе обработки. Небольшой просмотр кода или использование M-x aproposобычно быстро сообщит вам. Имена крючков обычно заканчиваются на -hookили -functions.

— Нарисовалась
источник

2

Эта тема также актуальна, если кто-то заинтересован:

/programming/11043004/emacs-compile-buffer-auto-close

Авторство относится к первоначальному автору jpkotta . Вот его ответ:

Я использую следующее для компиляции. Он сохраняет буфер компиляции, если есть предупреждения или ошибки, и скрывает его в противном случае (через 1 секунду).
(defun bury-compile-buffer-if-successful (buffer string)
  "Bury a compilation buffer if succeeded without warnings "
  (if (and
       (string-match "compilation" (buffer-name buffer))
       (string-match "finished" string)
       (not
        (with-current-buffer buffer
          (search-forward "warning" nil t))))
      (run-with-timer 1 nil
                      (lambda (buf)
                        (bury-buffer buf)
                        (switch-to-prev-buffer (get-buffer-window buf) 'kill))
                      buffer)))
(add-hook 'compilation-finish-functions 'bury-compile-buffer-if-successful)

— Сварненду Бисвас
источник

1

Пожалуйста , не размещайте ответ, который состоит только из ссылки . Включите основные части ответа в свой пост, чтобы ваш пост отвечал на вопрос. Предоставить ссылку в качестве источника и для получения дополнительной информации. Для получения дополнительной информации, пожалуйста, прочитайте наши рекомендации по написанию ответов .

— Жиль "ТАК - перестань быть злым"

Обновил мой ответ.

— Swarnendu Biswas

Обратите внимание, что можно цитировать чужой ответ из Stack Exchange , но вы должны предоставить правильную атрибуцию , включая имя автора.

— Жиль "ТАК - перестань быть злым"

1

У меня есть этот фрагмент в моем .emacs.d:

    (defcustom compilation-auto-quit-window-delay 1
      "Time in seconds before auto closing the window."
      :group 'compilation
      :type 'number)  

    (defun compilation-auto-quit-window-finish-function (buffer status)
      "Quit the *compilation* window if it went well."
      (let ((window (get-buffer-window buffer)))
        (when (and (equal status "finished\n")
                   (compilation-went-super-p))
          (run-with-timer
              (or compilation-auto-quit-window-delay 0) nil
            (lambda nil
              (when (and (window-live-p window)
                         (eq (window-buffer window)
                             buffer)
                         (not (eq (selected-window)
                                  window)))
                (save-selected-window
                  (quit-window nil window))))))))

    (define-minor-mode compilation-auto-quit-window
      "Automatically close the *compilation* window if it went well."
      :global t
      (cond (compilation-auto-quit-window
             (add-hook 'compilation-finish-functions
                       'compilation-auto-quit-window-finish-function))
            (t
             (remove-hook 'compilation-finish-functions
                          'compilation-auto-quit-window-finish-function))))

    (defun compilation-went-super-p (&optional buffer)
      "Return t, if no gotoable output appeared."
      (with-current-buffer (or buffer (current-buffer))
        (save-excursion
          (goto-char (point-min))
          (let (;; (compilation-skip-threshold 1)
                )
            (not (ignore-errors
                   (compilation-next-error 1)
                   t))))))

— politza
источник