Можно ли добавить шаблоны, отличные от # + BEGIN_ # + END_, в org-structure-template-alist?

Я заметил, что org-structure-template-alist изменился (я использую org-mode версии 9.2) для автоматического расширения до #+BEGIN_<some block tag> #+END_<some block tag>. Интересно, возможно ли добавить различные виды шаблонов. Например, :PROPERTIES:<some properties>:END:шаблон.

Это возможно, или я должен обратиться к другой упаковке, как yasnippets?

ОБНОВИТЬ:

Не заметил, что Org Mode 9.2 изменил механизм расширения шаблона, где org-structure-template-alistтолько для блоков, определенных "#+BEGIN_"и "#+END_". И запись вроде ("p" ":PROPERTIES:?:END:")больше не принимается.

Как упомянуто в приведенной выше ссылке, другой «сложный» шаблон может быть определен функцией tempo-define-template, и org-tempo должен быть загружен ( (require 'org-tempo)). На самом деле записи org-structure-template-alist преобразуются в org-tempo-tagsvia tempo-define-templateby org-tempo, и по org-tempo-tagsумолчанию:

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

Для вашего случая вы можете определить шаблон следующим образом:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

Ниже ответ работает только для версии в режиме Org до 9.2

Да, вы могли бы добавить запись к этому как это:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Затем в org-файле вы набираете <pи TAB, он расширяется до свойства и оставляет точку в позиции ?.

И вы можете найти более подробную информацию в документации по переменной, набрав C-h v org-structure-template-alist RET.

Частота, с которой они вносят несовместимые изменения в настройку режима org, действительно жаль.

Следующий код возвращает старые шаблоны структуры org-mode до версии 9.2. Эта функция org-complete-expand-structure-templateявляется чистой копией версии 9.1 и org-try-structure-completionслегка измененной версией версии 9.1. (Я добавил проверку типа там.)

После установки этого кода вы можете просто
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
снова использовать старый шаблон .

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))