Редактирование файлов с одним предложением на строку

Немного предыстории.

Я пытаюсь контролировать версии своих латексных документов, и эффективность этой инициативы значительно повысилась бы, если бы я использовал подход, состоящий из одного предложения на строку .

Например, вот как будут выглядеть мои документы.

Some text here.
New stencence on the same paragraph.
Some more text, still on the same paragraph.

This is another paragraph.

Мой вопрос прост.
Как много из этого я могу автоматизировать / улучшить с помощью Emacs?

Следующие два момента - это то, что я имею в виду.

1. Мои предложения длинные , поэтому мне нужно переносить строки, не заполняя их. То есть очень длинное предложение должно отображаться в нескольких строках на моем экране, но оно должно быть одной строкой в файле «.tex» . Желательно, чтобы это было сделано так, чтобы не оборачивать уравнения.

   visual-line-modeоборачивает на ширину окна, это слишком широко. Мне нужно что-то, что оборачивает строки и ограничивает их ширину до 80 символов. Точно так же, как fill-paragraphобычно, но без разрыва строк в файле.

2. Я могу вручную разбить строку после каждого предложения, но было бы весьма предпочтительно, если бы я мог настроить fill-paragraph(или, может быть, даже auto-fill-mode) поставить также одно предложение в каждой строке.

Если вы просто хотите что-то похожее, visual-line-modeно настраиваемое, вы можете попробовать longlines-modeименно то, что я использую для большей части моей прозы. longlines-modeпереносит текст аналогично visual-line-modeширине, настроенной с помощью fill-column.

Вот скриншот с fill-columnустановленным на 70(окно на самом деле расширяется еще больше вправо).

Настройка fill-paragraphбыла бы аккуратной, но я не уверен, как это сделать. Вместо этого, вот разумный временный взлом: настройте своего .персонажа в режиме TeX, вставив новую строку. Это просто включает повторное связывание в любом подходящем режиме:

(defun my-electric-dot ()
  (interactive)
  (insert ".\n"))
(defun my-tex-hook ()
  (local-set-key (kbd ".") 'my-electric-dot))
(add-hook 'TeX-mode-hook 'my-tex-hook)

Для (1) я бы использовал увеличенное поле, чтобы visual-line-modeобводить строки по желанию fill-column. Это повлияет как на текстовые строки, так и на уравнения.

Что касается (2), можно определить пользовательскую команду заполнения, которая будет связана M-qи правильно заполнить абзацы. Мне еще не удалось написать команду с правильным поведением для автозаполнения.

Оборачивание всего этого в второстепенном режиме может выглядеть следующим образом. Это не очень красивый код, но он должен работать в большинстве случаев. (У меня была unfill-paragraphфункция в моем init.elдовольно долгое время, не замечая проблем).

(define-minor-mode ospl-mode
  "One Sentence Per Line"
  :init-value nil
  :lighter " ospl"
  :keymap (let ((map (make-sparse-keymap)))
            (define-key map (kbd "M-q") 'ospl/fill-paragraph)
            map)

  (if ospl-mode
      (progn
        (visual-line-mode 1)
        (setq right-margin-width (- (window-body-width) fill-column)))
    (visual-line-mode -1)
    (setq right-margin-width 0))

  ;; Account for new margin width
  (set-window-buffer (selected-window) (current-buffer)))


(defun ospl/unfill-paragraph ()
  "Unfill the paragraph at point.

This repeatedly calls `join-line' until the whole paragraph does
not contain hard line breaks any more."
  (interactive)
  (forward-paragraph 1)
  (forward-paragraph -1)
  (while (looking-at paragraph-start)
    (forward-line 1))
  (let ((beg (point)))
    (forward-paragraph 1)
    (backward-char 1)
    (while (> (point) beg)
      (join-line)
      (beginning-of-line))))


(defun ospl/fill-paragraph ()
  "Fill the current paragraph until there is one sentence per line.

This unfills the paragraph, and places hard line breaks after each sentence."
  (interactive)
  (save-excursion
    (fill-paragraph)         ; takes care of putting 2 spaces if needed
    (ospl/unfill-paragraph)  ; remove hard line breaks

    ;; insert line breaks again
    (let ((end-of-paragraph (make-marker)))
      (save-excursion
        (forward-paragraph)
        (backward-sentence)
        (forward-sentence)
        (set-marker end-of-paragraph (point)))
      (forward-sentence) 
      (while (< (point) end-of-paragraph)
        (just-one-space)
        (delete-backward-char 1)
        (newline)
        (forward-sentence))
      (set-marker end-of-paragraph nil)))) 

Будут ли ваши проблемы с управлением версиями избегаться / решаться, если вы используете git diff --color-words или latexdiff? Тогда вы можете посмотреть на измененные слова.

Один из способов улучшить это, который я использовал (иногда) в течение нескольких лет, - это отображать предложения с разрывами строк как текущие друг за другом, складывая разрывы строк, используя возможности tex-fold(часть AUCTeX).

Это означает, что это

Lorem ipsum dolor sit amet, consectetur adipiscing elit.
Mauris pellentesque fringilla justo, quis dapibus velit tincidunt quis?
Quisque varius ligula arcu, ut imperdiet risus maximus nec.

складывается в

Lorem ipsum dolor sit amet, consectetur adipiscing elit⁎ Mauris pellentesque fringilla justo, quis dapibus velit tincidunt quis❓  Quisque varius ligula arcu, ut imperdiet risus maximus nec⁎

Я недавно соединил это как второстепенный режим в пакете. Возможно, кто-то еще найдет это полезным: https://github.com/andersjohansson/tex-fold-linebreaks