Как получить необработанные данные для повестки дня в режиме организации без представления повестки дня?

Вопрос: Как я могу org-modeвернуть необработанные данные для представления повестки дня, фактически не создавая представление повестки дня?

Я хотел бы получить доступ к моей повестке дня на любой день. Однако я не хочу создавать представление повестки дня как таковое. Вместо этого я хочу org-modeсобрать и отсортировать все элементы, которые будут включены в представление повестки дня на этот день, и вернуть их (в идеале в виде списка) для дальнейшей проверки и манипулирования.

Я предполагал, что org-agenda-listэто будет то место, с которого можно начать. Однако эта функция является запутанным зверем и, кажется, смешивает процессы сбора, сортировки и отображения. Таким образом, я предполагаю (надеюсь?), Что я просто где-то пропустил соответствующую функцию, которая обеспечивает функциональность, которая мне нужна.

Ниже приводится сокращенный примером того , как для извлечения данных , который идет в *Org Agenda*буфер , когда обычно с помощью функции org-agenda-list, с org-agenda-entry-typesтакими , как :deadline, :scheduled, :timestamp, sexp, :deadline*, и :scheduled*. Диапазон дат - beginи end- должен быть в григорианском формате списка - например, '(6 1 2015). Настраиваемые параметры привязки позволяют org-agenda-prefix-formatи org-agenda-entry-types. Функция возвращает результат в формате списка.

(require 'calendar)
(require 'org)
(require 'org-agenda)
(require 'cl)

;; Portions of following code were extracted from:
;;   https://github.com/kiwanami/emacs-calfw written by Masashi Sakurai
;; Said code has been modified by @lawlist hereinbelow.
;;
(defun org-get-entries-fn (begin end)
"Return org schedule items between BEGIN and END.
USAGE:  (org-get-entries-fn '(6 1 2015) '(12 31 2020))"
  (unless
      (and
        (calendar-date-is-valid-p begin)
        (calendar-date-is-valid-p end))
    (let ((debug-on-quit nil))
      (signal 'quit '("One or both of your Gregorian dates are invalid."))))
  (let* (
      result
      (org-agenda-buffer nil) ;; prevent error from `org-compile-prefix-format'
      ;; The variable `org-agenda-only-exact-dates' is apparently not operational.
      (org-scheduled-past-days 0) ;; avoid duplicate entries for overdue items
      (org-agenda-prefix-format "• ")
      (org-agenda-entry-types '(:scheduled))
      (date-after
        (lambda (date num)
          "Return the date after NUM days from DATE."
          (calendar-gregorian-from-absolute
           (+ (calendar-absolute-from-gregorian date) num))))
      (enumerate-days
        (lambda (begin end)
          "Enumerate date objects between BEGIN and END."
          (when (> (calendar-absolute-from-gregorian begin)
                   (calendar-absolute-from-gregorian end))
            (error "Invalid period : %S - %S" begin end))
          (let ((d begin) ret (cont t))
            (while cont
              (push (copy-sequence d) ret)
              (setq cont (not (equal d end)))
              (setq d (funcall date-after d 1)))
            (nreverse ret)))) )
    (org-compile-prefix-format nil)
    (setq result
      (loop for date in (funcall enumerate-days begin end) append
        (loop for file in (org-agenda-files nil 'ifmode) append
          (progn
            (org-check-agenda-file file)
            (apply 'org-agenda-get-day-entries file date org-agenda-entry-types)))))
    result))