Хорошие методы для настройки сигналов тревоги (аудио + видео), запускаемых событиями в режиме орг?


35

Я хотел бы, чтобы аварийные сигналы были отключены на основе событий режима org, связанных с определенным временем (или временем начала). В идеале они должны быть аудио и визуальными и могут быть настроены в некоторой степени. Я имел обыкновение использовать Sauron, но я больше не могу заставить его работать с событиями в режиме org (или уведомлениями по электронной почте). Каковы другие хорошие методы?

(Мне особенно интересно, чтобы уведомление отображалось не только на экране с помощью демона уведомлений, но и в режиме озвучивания (преобразование текста в речь). Я работаю в Linux.)



@ Константин - мне кажется, это совсем по-другому. Я не прошу инструменты для этого, а скорее готовые решения, которые уже существуют. Кроме того, на самом деле меня интересуют не тревоги для DEADLINE, а события, связанные со временем (началом).
emacsomancer

ХОРОШО; Я отредактировал мой комментарий. (Я думаю, что мы оба согласны, что ваш вопрос связан с тем, с которым я связан.)
Константин


2
Если у вас есть встроенная система appt, чтобы импортировать встречи из файлов org-повестки дня, используя функцию org-agenda-to-appt. Затем вы можете настроить, appt-disp-window-functionчтобы уведомить вас так, как вы хотите (что может включать в себя вызов внешних программ).
Икбал Ансари

Ответы:


15

Я вполне доволен системой, которую я использую, которая делает (я думаю) именно то, что вы хотите. Он состоит из двух частей: части Emacs, которая использует appt.el для составления расписания напоминаний, и небольшой программы-оболочки (я использую Linux), которая создает всплывающее окно + звуковое уведомление. Здесь я делюсь кодом для обеих частей.

А) Код в ~ / .emacs.d / init.el

(require 'appt)
(appt-activate t)

(setq appt-message-warning-time 5) ; Show notification 5 minutes before event
(setq appt-display-interval appt-message-warning-time) ; Disable multiple reminders
(setq appt-display-mode-line nil)

; Use appointment data from org-mode
(defun my-org-agenda-to-appt ()
  (interactive)
  (setq appt-time-msg-list nil)
  (org-agenda-to-appt))

; Update alarms when...
; (1) ... Starting Emacs
(my-org-agenda-to-appt)

; (2) ... Everyday at 12:05am (useful in case you keep Emacs always on)
(run-at-time "12:05am" (* 24 3600) 'my-org-agenda-to-appt)

; (3) ... When TODO.txt is saved
(add-hook 'after-save-hook
          '(lambda ()
             (if (string= (buffer-file-name) (concat (getenv "HOME") "/ideas/TODO.txt"))
                 (my-org-agenda-to-appt))))

; Display appointments as a window manager notification
(setq appt-disp-window-function 'my-appt-display)
(setq appt-delete-window-function (lambda () t))

(setq my-appt-notification-app (concat (getenv "HOME") "/bin/appt-notification"))

(defun my-appt-display (min-to-app new-time msg)
  (if (atom min-to-app)
    (start-process "my-appt-notification-app" nil my-appt-notification-app min-to-app msg)
  (dolist (i (number-sequence 0 (1- (length min-to-app))))
    (start-process "my-appt-notification-app" nil my-appt-notification-app (nth i min-to-app) (nth i msg)))))

Б) Код в ~ / bin / appt-уведомлении

#!/bin/sh

TIME="$1"
MSG="$2"

notify-send -t 0 "<br>Appointment in $TIME minutes:<br>$MSG<br>"
play "~/bin/alarm.wav"

Для получения голосовых уведомлений вы можете заменить последнюю строку (play) на следующую:

espeak "Appointment in $TIME minutes: $MSG"

Я добавил случай для автоматического обновления приложений при выходе из org-повестки дня: ; (4) ... Quitting org-agenda. (advice-add 'org-agenda-quit :after #'hw-org-agenda-to-appt)
holocronweaver

Примечание: обновление около полуночи важно для сов, поскольку org-agenda-to-apptсоздает только приложения для текущего дня.
Холокронотка

+1 Это здорово. Спасибо, что поделились. Я немного изменил это, чтобы использовать alert.el . Один вопрос, однако: вам когда-нибудь удавалось заставить его работать со свойством org "APPT_WARNTIME", чтобы установить настраиваемое время предупреждения для каждого события? Я не могу заставить его работать.
Джозеф Р.

11

Вы можете использовать уведомления в Emacs> 24:

(require 'notifications)

(notifications-notify :title "Achtung!"
                      :body (format "You have an appointment in %d minutes" 10)
                      :app-name "Emacs: Org"
                      :sound-name "alarm-clock-elapsed")

13
Это кажется очень полезным. Вы знаете, как его интегрировать org-mode?
erikstokes

2

Вот что я в итоге придумал:

;;; org-to-appt

;; based on http://emacs-fu.blogspot.nl/2009/11/showing-pop-ups.html
(defun talky-popup (title msg &optional icon sound)  
  "Show a popup if we're on X, or echo it otherwise; TITLE is the title
of the message, MSG is the context. Optionally, you can provide an ICON and
a sound to be played"

  (interactive)
  ;;verbal warning



  (shell-command
   ;;  (concat "espeak -v mb-en1 -k5 -s125 " "'" title " " msg "'" " --stdout | paplay") ;; use local espeak
   (concat "echo " "'" title "'" " " "'" msg "'" " |text-to-speech en-gb")  ;; use remote Google voices
    ;; text-to-speech is from https://github.com/taylorchu/speech-to-text-text-to-speech
   )
  (if (eq window-system 'x)
    (shell-command (concat "notify-send -u critical -t 1800000  " 

                     (if icon (concat "-i " icon) "")
                     " '" title "' '" msg "'"))
    ;; text only version

    (message (concat title ": " msg))))

;; the appointment notification facility
(setq
  appt-message-warning-time 15 ;; warn 15 min in advance

  appt-display-mode-line t     ;; show in the modeline
  appt-display-format 'window) ;; use our func
(appt-activate 1)              ;; active appt (appointment notification)
(display-time)                 ;; time display is required for this...

 ;; update appt each time agenda opened

(add-hook 'org-finalize-agenda-hook 'org-agenda-to-appt)

;; our little façade-function for talky-popup
 (defun talky-appt-display (min-to-app new-time msg)
    (talky-popup (format "In %s minute(s):" min-to-app) msg 
  ;;    "/usr/share/icons/gnome/32x32/status/appointment-soon.png"   ;; optional icon

  ;;    "/usr/share/sounds/ubuntu/stereo/phone-incoming-call.ogg"    ;; optional sound

        ))
  (setq appt-disp-window-function (function talky-appt-display))

Это не отличается от настройки скарамуша.

Используя наш сайт, вы подтверждаете, что прочитали и поняли нашу Политику в отношении файлов cookie и Политику конфиденциальности.
Licensed under cc by-sa 3.0 with attribution required.