make `delete-duplicate-lines` игнорирует пустые строки и определенные слова

Я редактирую текст в режиме org, несколько строк повторяются, так как они являются частью разных файлов из одной темы.

Я хочу использовать delete-duplicate-linesдля удаления повторяющихся строк, однако команда также удаляет пустые строки, чего я не хочу (иначе у меня не было бы абзацев!). Я хочу игнорировать некоторые слова, которые существуют отдельно в строках, например, «Возобновить» , это повторяется много раз в тексте, но я хочу сохранить его, так как это необходимо.

text-editing

— shackra
источник

Игнорирование пустых строк

Вы можете сказать, delete-duplicate-linesчтобы игнорировать пустые строки, вызывая его через

C-u C-u C-u M-x delete-duplicate-lines RET

Если вы не хотите нажимать так C-uмного раз при вызове delete-duplicate-lines, вы можете заключить его в произвольную команду и связать эту команду с последовательностью клавиш по вашему выбору:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Игнорирование строк, соответствующих регулярному выражению

Что касается второй части вашего вопроса, я не думаю, что вы можете достичь того, что вы хотите, используя встроенную версию delete-duplicate-lines. Однако вы можете использовать модифицированную версию команды (которая также содержит пустые строки по умолчанию):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Эта версия delete-duplicate-linesпредложит вам регулярное выражение и сохранит все строки, которые соответствуют регулярному выражению. Например, чтобы сохранить все строки, состоящие из слова, которое Resumeвы бы сделали:

M-x delete-duplicate-lines RET ^Resume$ RET

— itsjeyd
источник