Есть ли лучший способ обработки многострочных строк документации в elisp?

Я ненавижу способ, которым elisp (не уверен, что LISP вообще) обрабатывает многострочные строки документов.

(defun foo ()
  "This is
a multi
liner
docstring"
  (do-stuff))

Я действительно хочу, чтобы я мог сделать что-то вроде

(defun foo ()
  (eval-when-compile 
    (concat
      "This is\n"
       "a multi\n"
       "line\n"
       "docstring"))
  (do-stuff))

так что отступ был последовательным.

К сожалению, eval-when-compile не выполняет эту работу.

У кого-нибудь есть идеи?

Конечно, my-defunмакрос - это простой выход. Но более простое решение будет

(advice-add 'eval-when-compile :filter-return
            (lambda (exp)
              (if (and (eq 'quote (car-safe exp))
                       (stringp (cadr exp)))
                  (cadr exp)
                exp)))

Что должно заставить ваш трюк работать, по крайней мере, во всех случаях, когда функция расширяется макросом до ее фактического определения, что должно включать основные варианты использования (например, если она загружена из файла, если она скомпилирована байтом, или если она определена) через M-C-x).

Тем не менее, это не исправит весь существующий код, поэтому, возможно, лучший ответ будет выглядеть примерно так:

;; -*- lexical-binding:t -*-

(defun my-shift-docstrings (orig ppss)
  (let ((face (funcall orig ppss)))
    (when (eq face 'font-lock-doc-face)
      (save-excursion
        (let ((start (point)))
          (parse-partial-sexp (point) (point-max) nil nil ppss 'syntax-table)
          (while (search-backward "\n" start t)
            (put-text-property (point) (1+ (point)) 'display
                               (propertize "\n  " 'cursor 0))))))
    face))

(add-hook 'emacs-lisp-mode-hook
          (lambda ()
            (font-lock-mode 1)
            (push 'display font-lock-extra-managed-props)
            (add-function :around (local 'font-lock-syntactic-face-function)
                          #'my-shift-docstrings)))

который должен просто сдвигать строки документации на 2 пробела, но только на стороне дисплея, не затрагивая фактическое содержимое буфера.

Вы можете использовать макрос как это:

(defmacro my-defun (name arglist &rest forms)
  "Like `defun', but concatenates strings."
  (declare (indent defun))
  (let (doc-lines)
    (while (and (stringp (car-safe forms))
                (> (length forms) 1))
      (setq doc-lines
            (append doc-lines (list (pop forms)))))
    `(defun ,name ,arglist
       ,(mapconcat #'identity doc-lines "\n")
       ,@forms)))

Затем вы можете определить свои функции следующим образом:

(my-defun test (a)
  "Description"
  "asodksad"
  "ok"
  (interactive)
  (+ 1 a))

Тем не менее, я настоятельно рекомендую не идти против стандартов для такой предельной выгоды. «Нерегулярный отступ», который беспокоит вас, - это всего лишь 2 столбца, не говоря уже о том, что он помогает выделить первую строку документации, которая является более важной.

Я видел пакеты, которые определяют строки документации, как это:

(defun my-function (x y) "
this is my docstring
that lines always lines up
across multiple lines."
  (+ x y))

Поместите первую цитату в первую строку, затем начните текст в следующей строке, чтобы они все выстроились в линию. Это определенно не стандарт, но вы не единственный, кто это делает.