Как написать прозрачную «сквозную» функцию-обертку?

То, что я подразумеваю под «прозрачной« проходной »функцией-оберткой», - это функция, давайте назовем ее wrapper, которая возвращает результат передачи всех своих аргументов какой-то другой функции, давайте назовем ее wrappee.

Как это делается в Emacs Lisp?

NB: Идеальная wrapperфункция агностик о в wrappeeподписи функции в; то есть он ничего не знает о количестве, позициях, именах и т. д. wrappeeаргументов России; он просто передает все свои аргументы wrappee, как если бы wrappeeон был первоначально вызван. (Однако нет необходимости связываться со стеком вызовов, чтобы заменить вызов на wrapperвызов wrappee.)

Я разместил частичный ответ на мой вопрос:

(defun wrapper (&rest args) (apply 'wrappee args))

Это работает только тогда, когда неwrappee является интерактивным. Очевидно, способ, которым интерактивные функции получают свои аргументы, представляет собой «канал», отличный от того, что описывается в заклинании. Поэтому мне по-прежнему нужен равноагностический аналог сигнатуры для случая, когда есть интерактивная функция.(&rest args)wrappee(&rest args)wrappee

(Этот вопрос был мотивирован проблемой, описанной в этом предыдущем вопросе .)

В случае, если необходимо дальнейшее разъяснение того, что я запрашиваю, ниже приведены несколько примеров, показывающих эквиваленты Python и JavaScript того, что мне нужно.

В Python пара стандартных способов реализации такой оболочки показана ниже:

def wrapper(*args, **kwargs):
    return wrappee(*args, **kwargs)

# or

wrapper = lambda *args, **kwargs: wrappee(*args, **kwargs)

(Здесь *argsозначает «все позиционные аргументы» и **kwargs«все ключевые аргументы».)

Эквивалент JavaScript будет примерно таким:

function wrapper () { return wrappee.apply(this, arguments); }

// or

wrapper = function () { return wrappee.apply(this, arguments); }

Для справки , я не согласен, что этот вопрос является дубликатом Как применить mapcar к функции с несколькими аргументами . Я затрудняюсь объяснить, почему, поскольку эти два вопроса кажутся мне совершенно разными. Это все равно, что спросить: «Объясните, почему яблоко не следует считать эквивалентом апельсина». Простой вопрос настолько сумасшедший, что можно сомневаться в том, что кто-то может придумать ответ, который удовлетворил бы того, кто его спрашивал.

Конечно, это возможно, включая interactiveспецификацию. Мы имеем дело здесь с elisp ! (Лисп - это язык, где наиболее важными конструкциями являются списки. Вызываемые формы - это просто списки. Поэтому вы можете создавать их по своему усмотрению.)

Приложение: Вы хотите добавить некоторые функции к некоторым функциям автоматически. Расширенным функциям должны быть присвоены новые имена, чтобы они defadviceне применялись.

Во-первых, версия, которая в точности соответствует вашим целям. Мы устанавливаем функцию cell ( fset) символа wrapperсо всей необходимой информацией wrappeeи добавляем наш дополнительный материал.

Это работает для обоих wrappeeопределений. Первая версия wrappeeявляется интерактивной, вторая - нет.

(defun wrappee (num str)
  "Nontrivial wrappee."
  (interactive "nNumber:\nsString:")
  (message "The number is %d.\nThe string is \"%s\"." num str))

(defun wrappee (num str)
  "Noninteractive wrappee."
  (message "The number is %d.\nThe string is \"%s\"." num str))

(fset 'wrapper (list 'lambda
             '(&rest args)
             (concat (documentation 'wrappee t) "\n Wrapper does something more.")
             (interactive-form 'wrappee)
             '(prog1 (apply 'wrappee args)
            (message "Wrapper does something more."))))

Но удобнее определить макрос, который создает расширенные функции. При этом мы можем даже указать имена функций впоследствии. (Хорошо для автоматической версии.)

После выполнения кода ниже вы можете звонить в wrapper-interactiveинтерактивном и wrapper-non-interactiveнеинтерактивном режиме.

(defmacro make-wrapper (wrappee wrapper)
  "Create a WRAPPER (a symbol) for WRAPPEE (also a symbol)."
  (let ((arglist (make-symbol "arglist")))
  `(defun ,wrapper (&rest ,arglist)
     ,(concat (documentation wrappee) "\n But I do something more.")
     ,(interactive-form wrappee)
     (prog1 (apply (quote ,wrappee) ,arglist)
       (message "Wrapper %S does something more." (quote ,wrapper))))))

(defun wrappee-interactive (num str)
  "That is the doc string of wrappee-interactive."
  (interactive "nNumber:\nsString:")
  (message "The number is %d.\nThe string is \"%s\"." num str))

(defun wrappee-non-interactive (format &rest arglist)
  "That is the doc string of wrappee-non-interactive."
  (apply 'message format arglist))

(make-wrapper wrappee-interactive wrapper-interactive)
(make-wrapper wrappee-non-interactive wrapper-non-interactive)
;; test of the non-interactive part:
(wrapper-non-interactive "Number: %d, String: %s" 1 "test")

Обратите внимание, до сих пор я не нашел способ передачи форм объявлений, но это также должно быть возможно.

Мне пришлось решить очень похожую проблему nadvice.el, поэтому вот решение (которое использует некоторый код из nadvice.el):

(defun wrapper (&rest args)
  (interactive (advice-eval-interactive-spec
                (cadr (interactive-form #'wrappee))))
  (apply #'wrappee args))

По сравнению с другими решениями, опубликованными до сих пор, у этого есть преимущество правильной работы, если wrappeeего переопределить с другой интерактивной спецификацией (то есть он не будет продолжать использовать старую спецификацию).

Конечно, если вы хотите, чтобы ваша оболочка была действительно прозрачной, вы можете сделать это проще:

(defalias 'wrapper #'wrappee)

редактировать: ответ Тобиаса лучше, чем это, так как он получает точную интерактивную форму и строку документации обернутой функции.

Комбинируя ответы Аарона Харриса и Кджо, вы можете использовать что-то вроде:

(defmacro my-make-wrapper (fn &optional name)
  "Return a wrapper function for FN defined as symbol NAME."
  `(defalias ',(or (eval name)
                   (intern (concat "my-" (symbol-name (eval fn)) "-wrapper")))
     (lambda (&rest args)
       ,(format "Generic wrapper for %s."
                (if (symbolp (eval fn))
                    (concat "`" (symbol-name (eval fn)) "'")
                  fn))
       (interactive)
       (if (called-interactively-p 'any)
           (call-interactively ,fn)
         (apply ,fn args)))))

Применение:

(my-make-wrapper 'find-file 'wrapper-func)

Вызовите упаковщик с одним из:

(wrapper-func "~/.emacs.d/init.el")

M-x wrapper-func