сделать `previous-buffer` и` next-buffer`, чтобы игнорировать некоторые буферы

10

в Helm я игнорирую показ некоторых буферов при использовании C-x b, я ищу способ сделать команды previous-bufferи next-bufferвести себя одинаково, игнорируя некоторые буферы.

buffers

— shackra
источник

8

Вот два способа:

Если вы посмотрите на определение функции switch-to-next-buffer(в библиотеке window.el), то увидите, что она фильтрует буферы по предикату (если есть), который является значением параметра кадра buffer-predicate. Эта функция используется next-buffer.

Вы можете установить этот параметр кадра в предикат, который фильтрует, как вы хотите.
Вы можете просто посоветовать функцию switch-to-next-bufferфильтровать так, как вы хотите. Вы по существу замените его определение почти таким же определением, но отфильтруете его так, как хотите.

Аналогично для switch-to-previous-buffer.

— Нарисовалась
источник

7

(defvar my-skippable-buffers '("*Messages*" "*scratch*" "*Help*")
  "Buffer names ignored by `my-next-buffer' and `my-previous-buffer'.")

(defun my-change-buffer (change-buffer)
  "Call CHANGE-BUFFER until current buffer is not in `my-skippable-buffers'."
  (let ((initial (current-buffer)))
    (funcall change-buffer)
    (let ((first-change (current-buffer)))
      (catch 'loop
        (while (member (buffer-name) my-skippable-buffers)
          (funcall change-buffer)
          (when (eq (current-buffer) first-change)
            (switch-to-buffer initial)
            (throw 'loop t)))))))

(defun my-next-buffer ()
  "Variant of `next-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'next-buffer))

(defun my-previous-buffer ()
  "Variant of `previous-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'previous-buffer))

(global-set-key [remap next-buffer] 'my-next-buffer)
(global-set-key [remap previous-buffer] 'my-previous-buffer)

— Phils
источник