Как перенести два аргумента функции в Python?

Как я могу поменять два аргумента при вызове функции Python?

Если я поставлю pointпространство между этими двумя аргументами:

self.assertEqual(json.loads(some.data), json_data)

и тогда M-t( transpose-words) я получаю:

self.assertEqual(json.loads(some.json), data_data)

С другой стороны, с CMt ( transpose-sexps) я получаю:

self.assertEqual(json.loadsjson_data, (some.data))

Что я хочу это:

self.assertEqual(json_data, json.loads(some.data))

Есть команда, которая сделает это?

Это то, что я тоже хотел иметь в течение долгого времени, и здесь я нашел некоторую мотивацию для работы над этим. Это, вероятно, не очень надежно, но с первой попытки это, кажется, покрывает случаи, которые я пытался:

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

Я использую вариант, transpose-sexpsкоторый ищет случай, который вы описываете, и переносит вещи через запятую, или просто делает обычные transpose-sexps. Он также оставляет курсор на месте, а не перетаскивает его вперед, что немного отличается, но мне лично нравится.

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

В режимах, которые используют SMIE, transpose-sexpдолжен корректно работать для этого случая. Они по-прежнему не будут работать, когда символ инфикса (он же «разделитель») не является ,(или ;), а является словом (например and).

Итак, я считаю, что команда для этого есть, transpose-sexpи когда она не работает правильно, я рассматриваю это как ошибку (но ошибка, которая может быть сложной и / или требует времени для исправления и имеет низкий приоритет, поэтому не задержи дыхание). Способ исправить это - установить forward-sexp-functionфункцию, которая будет знать, что «после того, как я вижу запятую, я просто перебираю весь аргумент».